z0eff.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE z0eff (HSNOW_SCHEME, &
                      OMEB, PALFA, PZREF, PUREF, PZ0, PZ0REL, PPSN,             &
                      PPALPHAN,PZ0LITTER, PWSNOW, ISS, PFF, PZ0_FLOOD,          &
                      PZ0_O_Z0H, PZ0_WITH_SNOW, PZ0H_WITH_SNOW,PZ0EFF,          &
                      PZ0G_WITHOUT_SNOW,                                        &
                      PZ0_MEBV,PZ0H_MEBV,PZ0EFF_MEBV,                           &
                      PZ0_MEBN,PZ0H_MEBN,PZ0EFF_MEBN                            )

!   ############################################################################
!
!!****  *Z0EFF*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates the z0eff for momentum fluxes according to wind direction.
!         
!     
!!**  METHOD
!!    ------
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!    Mascart et al. (1995)
!!    Belair (1995)
!!      
!!    AUTHOR
!!    ------
!!
!!      S. Belair           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    13/03/95 
!!      (J.Stein)   15/11/95  use the potential temperature to compute Ri
!!                            and PVMOD instead of ZVMOD
!!      (P.Lacarrere)15/03/96 replace * PEXNS by / PEXNS
!!      (V.Masson)   22/12/97 computation of z0eff after snow treatment
!!      (V.Masson)   05/10/98 clear routine
!!      (A.Boone)    11/26/98 Option for PDELTA: forested vs default surface
!!      (V Masson)   12/07/01 new formulation for aggregation with snow z0
!!      (P.LeMoigne) 09/02/06 computation of z0h in presence of snow
!!      (B. Decharme)    2008 floodplains
!!      (P. Samuelsson) 10/2014 MEB
!!      P. LeMoigne  12/2014 EBA scheme update
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
USE modd_sso_n, ONLY : sso_t
!
USE modd_csts,     ONLY : xpi, xg
USE modd_snow_par, ONLY : xz0sn, xwcrn, xz0hsn
!
USE modi_subscale_z0eff
USE modd_surf_atm, ONLY : laldz0h
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
 CHARACTER(LEN=*), INTENT(IN) :: HSNOW_SCHEME
!
LOGICAL, INTENT(IN)             :: OMEB           ! True = patch with multi-energy balance 
!                                                 ! False = patch with classical ISBA
REAL, DIMENSION(:), INTENT(IN)  :: PALFA          ! wind direction from J axis (clockwise)
REAL, DIMENSION(:), INTENT(IN)  :: PZREF          ! height of atmospheric level
REAL, DIMENSION(:), INTENT(IN)  :: PUREF          ! reference height for wind
REAL, DIMENSION(:), INTENT(IN)  :: PZ0            ! vegetation roughness length
REAL, DIMENSION(:), INTENT(IN)  :: PZ0REL         ! 1d orographic roughness length
REAL, DIMENSION(:), INTENT(IN)  :: PPSN           ! fraction of snow
REAL, DIMENSION(:), INTENT(IN)  :: PPALPHAN       ! snow/canopy transition coefficient
TYPE(sso_t), INTENT(INOUT) :: ISS
REAL, DIMENSION(:), INTENT(IN)  :: PZ0_O_Z0H      ! ratio between heat and momentum z0
!
REAL, DIMENSION(:), INTENT(IN)  :: PFF            ! fraction of flood
REAL, DIMENSION(:), INTENT(IN)  :: PZ0_FLOOD      ! floodplains roughness length
!
! For multi-energy balance
REAL, DIMENSION(:), INTENT(IN)  :: PZ0LITTER      ! ground litter roughness length for MEB
!
REAL, DIMENSION(:), INTENT(IN)  :: PWSNOW         ! equivalent snow water content
!
REAL, DIMENSION(:), INTENT(OUT) :: PZ0_WITH_SNOW  ! vegetation z0 modified by snow
REAL, DIMENSION(:), INTENT(OUT) :: PZ0H_WITH_SNOW ! vegetation z0h modified by snow
REAL, DIMENSION(:), INTENT(OUT) :: PZ0EFF         ! effective z0
!
! For multi-energy balance
REAL, DIMENSION(:), INTENT(OUT) :: PZ0G_WITHOUT_SNOW  ! roughness length for momentum at snow-free canopy floor
!
REAL, DIMENSION(:), INTENT(OUT) :: PZ0_MEBV           ! roughness length for momentum over MEB vegetation part of patch
REAL, DIMENSION(:), INTENT(OUT) :: PZ0H_MEBV          ! roughness length for heat over MEB vegetation part of path
REAL, DIMENSION(:), INTENT(OUT) :: PZ0EFF_MEBV        ! roughness length for momentum over MEB vegetation part of patch
!                                                     ! eventually including orograhic roughness
REAL, DIMENSION(:), INTENT(OUT) :: PZ0_MEBN           ! roughness length for momentum over MEB snow part of patch
REAL, DIMENSION(:), INTENT(OUT) :: PZ0H_MEBN          ! roughness length for heat over MEB snow part of path
REAL, DIMENSION(:), INTENT(OUT) :: PZ0EFF_MEBN        ! roughness length for momentum over MEB snow part of patch
!
!
!
!*      0.2    declarations of local variables
!
!
!
REAL, DIMENSION(SIZE(PZ0EFF)) :: ZWORK, ZALFA,       &
                                   ZZ0EFFIP, ZZ0EFFIM, &
                                   ZZ0EFFJP, ZZ0EFFJM, &
                                   ZPFF
!                                              effective roughness length in 4
!                                              directions
REAL                          :: Z0CR, ZUZ0CN, ZALRCN1, ZALRCN2
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('Z0EFF',0,zhook_handle)
zalrcn1=1.e-02
zalrcn2=2.5e-03
z0cr = zalrcn1
zuz0cn=1./zalrcn2
zalfa(:) = palfa(:)
WHERE(zalfa(:)<=-xpi) zalfa = zalfa + 2.*xpi
WHERE(zalfa(:)>  xpi) zalfa = zalfa - 2.*xpi
!
! Initialisation of MEB roughness lengths
pz0g_without_snow=0.
pz0_mebv=0.
pz0h_mebv=0.
pz0eff_mebv=0.
pz0_mebn=0.
pz0h_mebn=0.
pz0eff_mebn=0.
!
!*       1.     GRID-AVERAGED ROUGHNESS LENGTHS
!               -------------------------------
!       (considering the effect of snow-flood-covered surfaces and orography)
!
!*       1.1    for heat
!               --------
!
pz0_with_snow(:)  = pz0(:)
pz0h_with_snow(:) = pz0(:) / pz0_o_z0h(:)
!
IF(hsnow_scheme=='EBA') THEN
!        
   WHERE (ppsn(:)>0.)
!
!!!!!Flooding scheme not implemented with this option 
      pz0_with_snow(:) = pz0_with_snow(:) + ( z0cr - pz0(:))* &
        pwsnow(:)/(pwsnow(:) + xwcrn*(1.0+zuz0cn*pz0(:)))  
!        
   END WHERE 


   IF (laldz0h) THEN  
     WHERE (ppsn(:)>0.)
         pz0h_with_snow(:) = pz0h_with_snow(:) + ( z0cr - pz0h_with_snow(:))* &
           pwsnow(:)/(pwsnow(:) + xwcrn*(1.0+zuz0cn*pz0h_with_snow(:)))   
     END WHERE  
  END IF   
    
!        
ELSE
!        
   WHERE (ppsn(:)>0..OR.pff(:)>0.)
!        
      zwork(:) =  (            ppsn(:) /(log(puref(:)/xz0sn       ))**2 ) &
                + (            pff(:) /(log(puref(:)/pz0_flood(:)))**2 ) &
                + ((1.-ppsn(:)-pff(:))/(log(puref(:)/pz0(:)      ))**2 )  
!
      pz0_with_snow(:) = puref(:) /exp( sqrt( 1./zwork(:) ) )
!
      zwork(:) =  (            ppsn(:) /(log(pzref(:)/xz0hsn                      ))**2 ) &
                + (            pff(:) /(log(pzref(:)/(pz0_flood(:)/ pz0_o_z0h(:))))**2 ) &
                + ((1.-ppsn(:)-pff(:))/(log(pzref(:)/(pz0(:)/pz0_o_z0h(:))       ))**2 )  
!
      pz0h_with_snow(:) = pzref(:) /exp( sqrt( 1./zwork(:) ) )
!
   END WHERE
!
ENDIF
!
! For multi-energy balance
IF(omeb)THEN

! roughness length for momentum at snow-free canopy floor
  pz0g_without_snow(:) = pz0litter
  WHERE (pff(:)>0.)
    zpff(:)=pff(:)/(1-ppsn(:)+1.e-6)
    zwork(:) =  (    zpff(:)  * log(pz0_flood(:)) )   &
              + ( (1.-zpff(:)) * log(pz0litter(:)) )
    pz0g_without_snow(:) = exp( zwork(:) )
  END WHERE
!
! roughness length for momentum over MEB vegetation part of patch
  pz0_mebv(:)  = pz0(:)
!
! roughness length for momentum over MEB snow part of patch
  zwork(:) =  (    ppalphan(:) /(log(puref(:)/xz0sn       ))**2 ) &
            + ((1.-ppalphan(:))/(log(puref(:)/pz0_mebv(:)      ))**2 )
  pz0_mebn(:) = puref(:) /exp( sqrt( 1./zwork(:) ) )
!

! roughness length for momentum over MEB total patch
  zwork(:) =  (    ppsn(:) /(log(puref(:)/pz0_mebn(:)  ))**2 ) &
            + ((1.-ppsn(:))/(log(puref(:)/pz0_mebv(:)  ))**2 )
  pz0_with_snow(:) = puref(:) /exp( sqrt( 1./zwork(:) ) )
!
! roughness length for heat over MEB vegetation part of path
  pz0h_mebv(:) = pz0_mebv(:)/pz0_o_z0h(:)
! for nordic forest, z0h=z0m according to M&#195;&#182;lder (tested in Hirlam):
!
! PZ0H_MEBV(:) = PZ0_MEBV(:)   
!
! roughness length for heat over MEB snow part of path
  zwork(:) =  (     ppalphan(:) /(log(pzref(:)/xz0hsn          ))**2 ) &
            + ( (1.-ppalphan(:))/(log(pzref(:)/pz0h_mebv(:)    ))**2 )
  pz0h_mebn(:) = pzref(:) /exp( sqrt( 1./zwork(:) ) )
!

! roughness length for heat over MEB total path
  zwork(:) =  (     ppsn(:) /(log(pzref(:)/pz0h_mebn(:)    ))**2 ) &
            + ( (1.-ppsn(:))/(log(pzref(:)/pz0h_mebv(:)    ))**2 )
  pz0h_with_snow(:) = pzref(:) /exp( sqrt( 1./zwork(:) ) )
!
ENDIF
!
!*       1.2    for momentum
!               ------------
!
!                                     In this particular case, we now use
!                                     the roughness length due to the coupled
!                                     effect of vegetation and topography
!                                     Snow and Flood effects are yet taken
!                                     into account through ZZ0EFF
!
pz0eff(:) = pz0_with_snow(:)
IF(omeb)THEN
  pz0eff_mebv(:) = pz0_mebv(:)
  pz0eff_mebn(:) = pz0_mebn(:)
ENDIF
!
IF (lhook) CALL dr_hook('Z0EFF',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE z0eff