write_diag_surf_atmn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #################################################################################
SUBROUTINE write_diag_surf_atm_n (YSC,HPROGRAM,HWRITE)
!     #################################################################################
!
!!****  *WRITE_DIAG_SURF_ATM_n * - Chooses the surface schemes for diagnostics writing
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!------------------------------------------------------------------
!
USE modd_surfex_mpi, ONLY : nrank, npio
!
USE modd_surfex_n, ONLY : surfex_t
!
USE modd_surf_conf,      ONLY : cprogname
!
USE modd_surf_par,       ONLY : xundef
!
USE modi_init_io_surf_n
USE modi_write_surf
USE modi_end_io_surf_n
!
USE modi_write_diag_nature_n 
USE modi_write_diag_sea_n 
USE modi_write_diag_inland_water_n 
USE modi_write_diag_town_n 
!
USE modi_write_diag_seb_surf_atm_n
!
USE modi_write_diag_ch_aggr_n
USE modi_write_diag_ch_snap_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(surfex_t), INTENT(INOUT) :: YSC
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=3),   INTENT(IN)  :: HWRITE    ! 'PGD' : only physiographic fields are written
!                                            ! 'ALL' : all fields are written
!
!
!*      0.2    declarations of local variables
!
 CHARACTER(LEN=100) :: YCOMMENT
INTEGER            :: IRESP
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('WRITE_DIAG_SURF_ATM_N',0,zhook_handle)
!
cprogname = hprogram
!
IF (ysc%U%NDIM_SEA    >0) CALL write_diag_sea_n(ysc%DTCO, ysc%DUO, ysc%U, ysc%SM, & 
                                                hprogram,hwrite)
IF (ysc%U%NDIM_WATER  >0) CALL write_diag_inland_water_n(ysc%DTCO, ysc%DUO, ysc%U, &
                                                         ysc%WM, ysc%FM, hprogram,hwrite)
IF (ysc%U%NDIM_NATURE >0) CALL write_diag_nature_n(ysc%DTCO, ysc%DUO, ysc%U, ysc%IM, &
                                                   ysc%NDST, hprogram,hwrite)
IF (ysc%U%NDIM_TOWN   >0) CALL write_diag_town_n(ysc%DTCO, ysc%DUO%CSELECT, ysc%U, ysc%TM, &
                                                 ysc%GDM, ysc%GRM, hprogram,hwrite)
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
! Writing
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
!
IF (ysc%DUO%XDIAG_TSTEP==xundef .OR. &
        abs(nint(ysc%U%TTIME%TIME/ysc%DUO%XDIAG_TSTEP)*ysc%DUO%XDIAG_TSTEP-ysc%U%TTIME%TIME)<1.e-3 ) THEN
  !
  IF (ysc%DUO%LFRAC) THEN
    CALL init_io_surf_n(ysc%DTCO, ysc%U, hprogram,'FULL  ','SURF  ','WRITE','SURF_ATM.OUT.nc')          
    ycomment = '(fraction)'
    CALL write_surf(ysc%DUO%CSELECT,hprogram,'FRAC_SEA   ',ysc%U%XSEA, iresp,hcomment=ycomment)
    CALL write_surf(ysc%DUO%CSELECT,hprogram,'FRAC_NATURE',ysc%U%XNATURE,iresp,hcomment=ycomment)
    CALL write_surf(ysc%DUO%CSELECT,hprogram,'FRAC_WATER ',ysc%U%XWATER, iresp,hcomment=ycomment)
    CALL write_surf(ysc%DUO%CSELECT,hprogram,'FRAC_TOWN  ',ysc%U%XTOWN, iresp,hcomment=ycomment)
    CALL end_io_surf_n(hprogram)
  END IF
  !
  IF (hwrite/='PGD'.AND.ysc%DUO%LDIAG_GRID) &
          CALL write_diag_seb_surf_atm_n(ysc%DTCO, ysc%DUO, ysc%DU, ysc%DUC, ysc%U, &
                                         ysc%UG%G%CGRID, hprogram)
  !
  IF (ysc%CHU%LCH_EMIS .AND. ysc%SV%NBEQ>0 .AND. ysc%CHU%LCH_SURF_EMIS) THEN
    IF (ysc%CHU%CCH_EMIS=='AGGR') THEN 
      CALL write_diag_ch_aggr_n(ysc%DTCO, ysc%DUO%CSELECT, ysc%U, ysc%CHE, hprogram)
    ELSE IF (ysc%CHU%CCH_EMIS=='SNAP') THEN
      CALL write_diag_ch_snap_n(ysc%DTCO, ysc%DUO%CSELECT, ysc%U, ysc%CHN, hprogram)
    END IF
  END IF
  !  
END IF
!
IF (lhook) CALL dr_hook('WRITE_DIAG_SURF_ATM_N',1,zhook_handle)
!
!--------------------------------------------------------------------------------------
!
END SUBROUTINE write_diag_surf_atm_n