wet_leaves_frac.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE wet_leaves_frac(PWRM, PVEG, PWRMAX_CF, PZ0, PLAI, PWRMAX, PDELTA)
!   ############################################################################
!
!!****  *WET_LEAVES_FRAC*  
!!
!!    PURPOSE
!!    -------
!
!     
!!**  METHOD
!!    ------
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      S. Belair           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    13/03/95 
!!      (A.Boone)    11/26/98 Option for PDELTA: forested vs default surface
!!      B. Decharme    2008  Add optional maximum value for the fraction of the foliage covered by intercepted water
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_surf_atm, ONLY : xdelta_max
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
REAL, DIMENSION(:), INTENT(IN)   :: PWRM
!                                     PWRM    = liquid water retained on the foliage
!                                               of the vegetation
!
REAL, DIMENSION(:), INTENT(IN)   :: PVEG, PWRMAX_CF, PLAI, PZ0
!                                     PVEG = vegetation fraction
!                                     PLAI = leaf area index
!                                     PWRMAX_CF = coefficient for maximum water interception 
!                                                 storage capacity on the vegetation (kg/m2)
!                                     PZ0  = roughness length
!
!
REAL, DIMENSION(:), INTENT(OUT)  :: PWRMAX
!                                     PWRMAX = maximum equivalent water content
!                                              in the vegetation canopy
!
REAL, DIMENSION(:), INTENT(OUT)  :: PDELTA
!                                     PDELTA = fraction of the foliage covered
!                                              by intercepted water
!
!
!
!*      0.2    declarations of local variables
!
!
!
REAL, DIMENSION(SIZE(PVEG)) :: ZCOEF,          &
!                                              ZCOEF = work array
                                 zwr,            &
!                                              Interception reservoir limited by WRMAX
                                 zdelta_low,     &
!                                              ZDELTA_LOW = fraction of the foliage covered
!                                              by intercepted water for low vegetation
                                 zdelta_high  
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!                                              ZDELTA_HIGH = fraction of the foliage covered
!                                              by intercepted water for high vegetation

!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('WET_LEAVES_FRAC',0,zhook_handle)
pdelta(:) = 0.
!
!*       2.     FRACTION OF THE FOLIAGE COVERED BY INTERCEPTED WATER (DELTA)
!               ------------------------------------------------------------
!
!                                         first calculate the maximum value of
!                                         equivalent water content in the 
!                                         vegetation canopy
!
pwrmax(:) = pwrmax_cf(:) * pveg(:) * plai(:) 
!
zwr(:) = min(pwrm(:),pwrmax(:))
!
WHERE (pveg(:)>0. .AND. pwrmax>0.)
!*                                        calculate 'DELTA'
!
!*       2.1    Low vegetation, Deardorff (1978) formulmation:
!               ---------------------------------------------
!       
  zdelta_low(:) = ( zwr(:)/pwrmax(:) )**(2./3.)
!
!*       2.2    High vegetation, Manzi (1993) formulmation:
!               ------------------------------------------
!
!                                           Manzi (1993) [see also Delire et al. JGR 1997]
!                                           The dynamic vegetation roughness length
!                                           is used to determine which formulation
!                                           for 'DELTA' is used. This formulation
!                                           was calibrated for ARME (tropical forrest)
!                                           and so is used for forest canopies. It
!                                           results in 'smeared' (time and amplitude)
!                                           evaporation from interception relative to
!                                           that using Deardorff (above).
!
  zcoef(:)  = 1. + 2.*plai(:)
!
  zdelta_high(:) =   zwr(:)/( (1.-zcoef(:))*zwr(:) + zcoef(:)*pwrmax(:) )
!
!
!*       2.3    Ponderation between low and high vegetation (min and max thresholds: z0 of 0.5m and 1m)
!               ------------------------------------------
!
  zcoef(:) = max(min(2.*pz0(:)-1. ,1.),0.)
!
  pdelta(:) = (1.-zcoef(:)) * zdelta_low(:) + zcoef(:) * zdelta_high(:)
!
END WHERE
!
pdelta(:) = min(xdelta_max,pdelta(:)) 
IF (lhook) CALL dr_hook('WET_LEAVES_FRAC',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE wet_leaves_frac