user_clock.F90

Go to the documentation of this file.

SUBROUTINE user_clock(PELAPSED_TIME,PELAPSED_TIME_SINCE,PVECTOR_CP,PTOTAL_CP)

!**** *USER_CLOCK* - interface to system dependent timer routines

!     Purpose.
!     --------
!        Returns elapsed and CP from the start of execution.
!        Elapsed time is made relative to the first call to USER_CLOCK.

!**   Interface.
!     ----------
!        ZTIME=USER_CLOCK(PELAPSED_TIME,PELAPSED_TIME_SINCE,
!                         PVECTOR_CP,PTOTAL_CP)

!        Explicit arguments: (All are optional arguments)
!                           PELAPSED_TIME=wall clock time (seconds)
!                           PELAPSED_TIME_SINCE=wall clock time (seconds)
!                             change from input value of this parameter
!                           PVECTOR_CP=CP vector time  (seconds)
!                           PTOTAL_CP=total CP time   (seconds)

!     Author.
!     -------
!        D.Dent      *ECMWF*

!     External References:
!     -------------------

!        TIMEF,CPTIME

!     Modifications.
!     --------------
!        Original  : 97-09-25
!      F. Vana  05-Mar-2015  Support for single precision
!     ----------------------------------------------------------


USE parkind1  ,ONLY : jprd, jpim

IMPLICIT NONE

REAL(KIND=JPRD),INTENT(OUT) :: pelapsed_time,pvector_cp,ptotal_cp
REAL(KIND=JPRD),INTENT(INOUT) :: PELAPSED_TIME_SINCE
OPTIONAL            pelapsed_time,pelapsed_time_since
OPTIONAL            pvector_cp,ptotal_cp
REAL(KIND=JPRD)      :: ZVECTOR_CP,ZTOTAL_CP,ZWALL
REAL(KIND=JPRD),EXTERNAL :: TIMEF


! === END OF INTERFACE BLOCK ===
IF(PRESENT(pelapsed_time).OR. PRESENT(pelapsed_time_since)) THEN

  zwall=timef()
!             TIMEF returns milliseconds since first call to TIMEF
  IF(PRESENT(pelapsed_time)) THEN
    pelapsed_time=zwall*1.0e-3_jprd
  ENDIF
  IF(PRESENT(pelapsed_time_since)) THEN
    pelapsed_time_since=zwall*1.0e-3_jprd - pelapsed_time_since
  ENDIF
ENDIF

IF( PRESENT(pvector_cp) .OR. PRESENT(ptotal_cp) ) THEN
  CALL cptime(zvector_cp,ztotal_cp)
ENDIF
IF( PRESENT(pvector_cp) ) THEN
  pvector_cp=zvector_cp
ENDIF
IF( PRESENT(ptotal_cp) ) THEN
  ptotal_cp=ztotal_cp
ENDIF

RETURN
END SUBROUTINE user_clock