update_rad_sea.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE update_rad_sea(S,PZENITH,PTT,PDIR_ALB_ATMOS,PSCA_ALB_ATMOS,PEMIS_ATMOS,PTRAD,PU,PV)  
!     #######################################################################
!
!!****  *UPDATE_RAD_SEA * - update the radiative properties at time t+1 (see by the atmosphere) 
!                           in order to close the energy budget between surfex and the atmosphere
 
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    09/2009
!!      Modified    03/2011 : E. Bazile (MK10) albedo from Marat Khairoutdinov
!!      Modified    01/2014 : S. Senesi : handle fractional seaice
!!      Modified    02/2014 : split from update_rad_seawat.F90
!!      Modified    01/2015 : introduce interactive ocean surface albedo (R.Séférian)
!!------------------------------------------------------------------
!
USE modd_seaflux_n, ONLY : seaflux_t
!
USE modd_water_par, ONLY : xemiswat, xemiswatice, &
                           xalbwat, xalbsca_wat,  &
                           xalbseaice
!
USE modd_sfx_oasis, ONLY : lcpl_sea
!
USE modi_albedo_ta96
USE modi_albedo_mk10
USE modi_albedo_rs14
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(seaflux_t), INTENT(INOUT) :: S
!
REAL, DIMENSION(:),     INTENT(IN)   :: PZENITH   ! Zenithal angle at t+1
REAL,                   INTENT(IN)   :: PTT       ! Sea/ice transition temperature (different according to sea or inland water)
!
REAL, DIMENSION(:,:),   INTENT(OUT)  :: PDIR_ALB_ATMOS ! Direct albedo at t+1 for the atmosphere
REAL, DIMENSION(:,:),   INTENT(OUT)  :: PSCA_ALB_ATMOS ! Diffuse albedo at t+1 for the atmosphere
REAL, DIMENSION(:),     INTENT(OUT)  :: PEMIS_ATMOS    ! Emissivity at t+1 for the atmosphere
REAL, DIMENSION(:),     INTENT(OUT)  :: PTRAD          ! radiative temp at t+1 for the atmosphere
!
REAL, DIMENSION(:),     INTENT(IN)   , OPTIONAL :: PU        ! zonal wind (m/s)
REAL, DIMENSION(:),     INTENT(IN)   , OPTIONAL :: PV        ! meridian wind (m/s)
!
!*      0.2    declarations of local variables
!
INTEGER :: JSWB
REAL, DIMENSION(SIZE(PZENITH)) :: ZALBDIR
REAL, DIMENSION(SIZE(PZENITH)) :: ZALBSCA
REAL, DIMENSION(SIZE(PZENITH)) :: ZWIND
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('UPDATE_RAD_SEA',0,zhook_handle)
!
zalbdir(:) = 0.
zalbsca(:) = 0.
!
IF (s%CSEA_ALB=='TA96') THEN
!        
  zalbdir(:) = albedo_ta96(pzenith(:))
  zalbsca(:) = xalbsca_wat
!  
ELSEIF (s%CSEA_ALB=='MK10') THEN
!        
  zalbdir(:) = albedo_mk10(pzenith(:))
  zalbsca(:) = xalbsca_wat
!  
ELSEIF (s%CSEA_ALB=='RS14') THEN
!        
  IF (PRESENT(pu).AND.PRESENT(pv)) THEN
     zwind(:) = sqrt(pu(:)**2+pv(:)**2)
     CALL albedo_rs14(pzenith(:),zwind(:),zalbdir(:),zalbsca(:))
  ELSE
     zalbdir(:) = s%XDIR_ALB(:)
     zalbsca(:) = s%XSCA_ALB(:)
  ENDIF
!
ENDIF
!
IF(lcpl_sea)THEN !Earth System Model
!
!Sea and/or ice albedo already given by coupled seaice model
!Except for Taylor et al (1996) and MK10 formulation
!
  WHERE (s%XSST(:)>=ptt  )
    !* open water
    s%XEMIS   (:) = xemiswat
  ELSEWHERE
    !* sea ice
    s%XEMIS   (:) = xemiswatice
  END WHERE
  !
  IF (s%CSEA_ALB=='TA96' .OR. s%CSEA_ALB=='MK10' .OR. s%CSEA_ALB=='RS14') THEN
    !* Taylor et al 1996
    !* open water
    WHERE (s%XSST(:)>=ptt) s%XDIR_ALB(:) = zalbdir(:)
    WHERE (s%XSST(:)>=ptt) s%XSCA_ALB(:) = zalbsca(:)
  ENDIF
  !
ELSEIF(s%LHANDLE_SIC) THEN 
  ! Returned values are an average of open sea and seaice properties
  ! weighted by the seaice cover
  s%XEMIS   (:) = ( 1 - s%XSIC(:)) * xemiswat    + s%XSIC(:) * xemiswatice
  IF (s%CSEA_ALB=='UNIF') THEN
     s%XDIR_ALB(:) = ( 1 - s%XSIC(:)) * xalbwat     + s%XSIC(:) * s%XICE_ALB(:)
     s%XSCA_ALB(:) = ( 1 - s%XSIC(:)) * xalbwat     + s%XSIC(:) * s%XICE_ALB(:)
  ELSE IF (s%CSEA_ALB=='TA96' .OR. s%CSEA_ALB=='MK10' .OR. s%CSEA_ALB=='RS14') THEN
     s%XDIR_ALB(:) = ( 1 - s%XSIC(:)) * zalbdir(:) + s%XSIC(:) * s%XICE_ALB(:)
     s%XSCA_ALB(:) = ( 1 - s%XSIC(:)) * zalbsca(:) + s%XSIC(:) * s%XICE_ALB(:)
  ENDIF
ELSE
  !
  IF (s%CSEA_ALB=='UNIF') THEN
  !* uniform albedo
    WHERE (s%XSST(:)>=ptt  )
    !* open water
      s%XDIR_ALB  (:) = xalbwat
      s%XSCA_ALB  (:) = xalbwat
      s%XEMIS     (:) = xemiswat
    ELSEWHERE
    !* sea ice
      s%XDIR_ALB(:) = xalbseaice
      s%XSCA_ALB(:) = xalbseaice
      s%XEMIS   (:) = xemiswatice
    END WHERE
  !
  ELSE IF (s%CSEA_ALB=='TA96' .OR. s%CSEA_ALB=='MK10' .OR. s%CSEA_ALB=='RS14') THEN
    !* Taylor et al 1996
    !
    WHERE (s%XSST(:)>=ptt)
    !* open water
      s%XDIR_ALB  (:) = zalbdir(:)
      s%XSCA_ALB  (:) = zalbsca(:)
      s%XEMIS     (:) = xemiswat
    ELSEWHERE
    !* sea ice
      s%XDIR_ALB(:) = xalbseaice
      s%XSCA_ALB(:) = xalbseaice
      s%XEMIS   (:) = xemiswatice
    END WHERE
    !
  ENDIF
  !
ENDIF
!
!-------------------------------------------------------------------------------------
!
DO jswb=1,SIZE(pdir_alb_atmos,2)
  pdir_alb_atmos(:,jswb) = s%XDIR_ALB(:)
  psca_alb_atmos(:,jswb) = s%XSCA_ALB(:)
END DO
!
pemis_atmos(:) = s%XEMIS(:)
IF(s%LHANDLE_SIC) THEN 
   ptrad(:) = (((1 - s%XSIC(:)) * xemiswat    * s%XSST (:)**4 + &
                     s%XSIC(:)  * xemiswatice * s%XTICE(:)**4)/ &
              s%XEMIS(:)) ** 0.25
ELSE
   ptrad(:) = s%XSST (:)
END IF
!
IF (lhook) CALL dr_hook('UPDATE_RAD_SEA',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE update_rad_sea