update_rad_flake.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE update_rad_flake(F,PZENITH,PDIR_ALB_ATMOS,PSCA_ALB_ATMOS,PEMIS_ATMOS,PTRAD )  
!     #######################################################################
!
!!****  *UPDATE_RAD_FLAKE * - update the radiative properties at time t+1 (see by the atmosphere) 
!                           in order to close the energy budget between surfex and the atmosphere
 
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    04/2013
!!------------------------------------------------------------------
!
USE modd_flake_n, ONLY : flake_t
!
USE modd_water_par, ONLY : xalbsca_wat, xalbwat, xemiswat, xemiswatice
!
USE modd_flake_parameters , ONLY : h_snow_min_flk, h_ice_min_flk
!
USE modd_snow_par, ONLY : xemissn
!
USE modi_albedo_ta96
USE modi_albedo_mk10
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(flake_t), INTENT(INOUT) :: F
REAL, DIMENSION(:),     INTENT(IN)   :: PZENITH   ! Zenithal angle at t+1
REAL, DIMENSION(:,:),   INTENT(OUT)  :: PDIR_ALB_ATMOS ! Direct albedo at t+1 for the atmosphere
REAL, DIMENSION(:,:),   INTENT(OUT)  :: PSCA_ALB_ATMOS ! Diffuse albedo at t+1 for the atmosphere
REAL, DIMENSION(:),     INTENT(OUT)  :: PEMIS_ATMOS    ! Emissivity at t+1 for the atmosphere
REAL, DIMENSION(:),     INTENT(OUT)  :: PTRAD          ! radiative temp at t+1 for the atmosphere
!
!*      0.2    declarations of local variables
!
INTEGER :: JSWB
!
REAL, DIMENSION(SIZE(F%XTS)) :: ZALBDIR
REAL, DIMENSION(SIZE(F%XTS)) :: ZALBSCA
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('UPDATE_RAD_FLAKE',0,zhook_handle)
!
zalbdir(:) = 0.
zalbsca(:) = 0.
!
IF (f%CFLK_ALB=='TA96') THEN
  zalbdir(:) = albedo_ta96(pzenith(:))
  zalbsca(:) = xalbsca_wat
ELSEIF (f%CFLK_ALB=='MK10') THEN
  zalbdir(:) = albedo_mk10(pzenith(:))
  zalbsca(:) = xalbsca_wat
ELSE
  zalbdir(:) = xalbwat
  zalbsca(:) = xalbwat
ENDIF
!
WHERE (f%XH_SNOW(:)>=h_snow_min_flk)
!* snow
  f%XDIR_ALB  (:) = f%XSNOW_ALB(:)
  f%XSCA_ALB  (:) = f%XSNOW_ALB(:)
  f%XEMIS     (:) = xemissn
ELSEWHERE(f%XH_ICE(:)>=h_ice_min_flk)
!* ice
  f%XDIR_ALB(:) = f%XICE_ALB(:)
  f%XSCA_ALB(:) = f%XICE_ALB(:)
  f%XEMIS   (:) = xemiswatice
ELSEWHERE
!* open water
  f%XDIR_ALB  (:) = zalbdir(:)
  f%XSCA_ALB  (:) = zalbsca(:)
  f%XEMIS     (:) = xemiswat    
END WHERE
!
!-------------------------------------------------------------------------------------
!
DO jswb=1,SIZE(pdir_alb_atmos,2)
  pdir_alb_atmos(:,jswb) = f%XDIR_ALB(:)
  psca_alb_atmos(:,jswb) = f%XSCA_ALB(:)
END DO
!
pemis_atmos(:) = f%XEMIS(:)
ptrad(:) = f%XTS  (:)
!
IF (lhook) CALL dr_hook('UPDATE_RAD_FLAKE',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE update_rad_flake