tsz0.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE tsz0 (DTZ, PTIME, PTSTEP, KK, PEK )
!     ################################################################
!
!
!!****  *TSZ0*  
!!
!!    PURPOSE
!!    -------
!       This subroutine computes the surface fluxes when  the soil temperature,
!     humidity and rugisty length are prescribed. It uses these values and the 
!     atmospheric fields at the first level located at dz/2 to compute a
!     vertical gradient and a drag coefficient is computed according to a
!     stability index ( Richardson number )    
!     
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!      J. Stein           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original     25/01/96 
!!                   25/03/96 spatialize the input TS, WG, SST fields
!!                   22/05/96 correct igrid value for the rain rate
!!                   27/11/96 set realistic values for z0 fields on sea
!!      V.Masson     09/07/97 add directional z0 computations and RESA correction
!!      V.Masson     15/03/99 some computations are now done in GROUND_PARAMn
!!      V.Masson     04/01/00 all computations are now done in ISBA
!!      P. Le Moigne 03/2015  tsz0 time management
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_isba_n, ONLY : isba_k_t, isba_pe_t
!
USE modd_data_tsz0_n, ONLY : data_tsz0_t
!
USE modd_csts,       ONLY : xpi
USE modd_surf_par,   ONLY : xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!* general variables
!  -----------------
!
TYPE(isba_k_t), INTENT(INOUT) :: KK
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
!
TYPE(data_tsz0_t), INTENT(INOUT) :: DTZ
!
REAL,                   INTENT(IN)  :: PTIME      ! Current time
REAL,                   INTENT(IN)  :: PTSTEP     ! timestep of the integration
!
!
!*      0.2    declarations of local variables
!
!
!* local variables for Ts time interpolation
!   ----------------------------------------
!
REAL    :: ZA,ZTIMEP    ! weigths and instant for the temporal interpolation
INTEGER :: IHOURP       ! hourly data index for intant t +dt
INTEGER :: JPATCH       ! loop counter on patches
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! enter here the temporal variations of the soil fields increments
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
! prescribed values of the surface temperature increment over land (K)
REAL :: ZDTS_HOUR 
! prescribed values of the soil humidity increment at every hour (fraction)
REAL :: ZDHUGRD_HOUR              
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!*       1.     TEMPORAL INTERPOLATION OF THE SURFACE TEMPERATURES AT T+DT
!               ----------------------------------------------------------
!
IF (lhook) CALL dr_hook('TSZ0',0,zhook_handle)
!
IF (dtz%NTIME==25) THEN
   ztimep = mod(ptime+ptstep,86400.)  ! recover the time from O HTU
ELSE
   ztimep = ptime+ptstep              ! accumulated time since beginning of run
ENDIF
!
ihourp = int(ztimep/3600.)+1
!
IF (dtz%NTIME==1) THEN
  zdts_hour    = dtz%XDATA_DTS   (1)
  zdhugrd_hour = dtz%XDATA_DHUGRD(1)        
ELSE
  zdts_hour    = dtz%XDATA_DTS   (ihourp)
  zdhugrd_hour = dtz%XDATA_DHUGRD(ihourp)
ENDIF
!
! temporal interpolation of the surface temperature increment  over land at time t
za= zdts_hour /3600. * ptstep
WHERE (pek%XTG(:,:)/=xundef)
  pek%XTG(:,:)= pek%XTG(:,:) + za
END WHERE
!
! temporal interpolation of the soil humidity increment at time t
za= zdhugrd_hour /3600.* ptstep
WHERE (pek%XWG(:,:)/=xundef)
  pek%XWG(:,:)= acos( 1.                                                               &
      - 2.* min( 0.5 * (1. - cos( xpi * min(pek%XWG(:,:) /kk%XWFC(:,:),1.)  )) + za , 1.) &
            ) / xpi * kk%XWFC(:,:)  
END WHERE
!
IF (lhook) CALL dr_hook('TSZ0',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE tsz0