trip_nearest.F90

Go to the documentation of this file.

!     #########
      SUBROUTINE trip_nearest(KNI,KCODE,PLON,PLAT,PFIELD)
!     #########################################################
!
!!**** *TRIP_NEAREST*
!!
!!    PURPOSE
!!    -------
!!
!!    Approximation : Pythagora theorem is used on an  
!!                    equirectangular projection for 
!!                    computing performance.
!!
!!    The points are all on only one grid (defined with the coordinates
!!    of all the points). The code to apply for each point is:
!!
!!    KCODE>0 : data point (with field valid for interpolation)
!!    KCODE=-1: point to ignore
!!    KCODE=0 : point to interpolate
!!
!!
!!
!!    METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    B. Decharme          Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/2016
!!    Modification
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_trip_par, ONLY : xundef, xrad, xpi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                 INTENT(IN)     :: KNI      ! 
INTEGER,DIMENSION(KNI),  INTENT(INOUT)  :: KCODE    ! code for each point
                                                    ! >0 point used for interpolation
                                                    !  0 point to interpolate
                                                    ! -1 point not used
REAL,   DIMENSION(KNI),  INTENT(IN)      :: PLON      ! x of each grid mesh.
REAL,   DIMENSION(KNI),  INTENT(IN)      :: PLAT      ! y of each grid mesh.
REAL,   DIMENSION(KNI),  INTENT(INOUT)   :: PFIELD  ! pgd field on grid mesh.
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER                               :: JD ! data point index
INTEGER                               :: JS ! loop counter on data points
INTEGER                               :: JL ! loop counter on points to initialize
!
REAL,   DIMENSION(KNI)                :: ZDIST   ! square distance between two interpolating and interpolated points
REAL,   DIMENSION(KNI)                :: ZNDIST  ! nearest square distances
REAL,   DIMENSION(KNI)                :: ZNVAL   ! corresponding field values
REAL,   DIMENSION(KNI)                :: ZLON
REAL,   DIMENSION(KNI)                :: ZLAT
REAL,   DIMENSION(KNI)                :: ZDLON
REAL                                  :: ZRAD
!
INTEGER                               :: ISCAN          ! number of points to scan
INTEGER, DIMENSION(KNI)               :: IINDEX       ! list of index to scan
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_NEAREST',0,zhook_handle)
!
zrad = xpi/180.
!
zlon(:) = plon(:)*zrad
zlat(:) = plat(:)*zrad
!
iindex(:) = 0
!
iscan = count(kcode(:)>0)
!
js = 0
DO jd=1,kni
  IF (kcode(jd)>0) THEN
    js = js+1
    iindex(js) = jd
  END IF
END DO
!
DO jl=1,kni
  !
  IF (kcode(jl)/=0) cycle
  !
  zndist(jl) = xundef
  znval(jl) = 0.0
  !
  DO js=1,iscan
    !
    jd = iindex(js)
    !
    zdlon(jl)= zlon(jd)-zlon(jl) 
    IF(zdlon(jl)>=xpi)zdlon(jl) = abs(2.0*xpi-zdlon(jl))

    zdist(jl)= (zdlon(jl)*cos(0.5*(zlat(jd)+zlat(jl))))**2 + (zlat(jd)-zlat(jl))**2    
    !
    IF ( zdist(jl)>zndist(jl) ) cycle
    !
    zndist(jl) = zdist(jl)
    znval(jl) = pfield(jd)
    !
  ENDDO
  !
  pfield(jl) = znval(jl)
  !
END DO
!
IF (lhook) CALL dr_hook('TRIP_NEAREST',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE trip_nearest