treat_global_lake_depth.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE treat_global_lake_depth (DTCO, UG, U, USS, &
                                          HPROGRAM,PDEPTH,KSTATUS)
!     ##############################################################
!
!!**** *TREAT_GLOBAL_LAKE_DEPTH* monitor for averaging and interpolations of ISBA physiographic fields
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    S. Faroux        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    17/02/11
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_surfex_mpi, ONLY : nrank, npio
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
!
USE modd_surf_par,       ONLY : xundef
USE modd_pgd_grid,       ONLY : nl
USE modd_pgdwork,        ONLY : xall, nsize_all, xsumval, nsize
USE modd_data_lake,      ONLY : clakeldb, cstatusldb, ngraddepth_ldb, ngradstatus_ldb 
!
USE modi_get_luout
USE modi_treat_field
USE modi_pack_same_rank
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
USE modi_get_surf_mask_n
USE modi_get_type_dim_n
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
!
 CHARACTER(LEN=6),  INTENT(IN) :: HPROGRAM  ! Type of program
REAL, DIMENSION(:),INTENT(OUT):: PDEPTH    ! physiographic field
INTEGER, DIMENSION(:),INTENT(OUT):: KSTATUS   ! physiographic field
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER                        :: ILU    ! expected physical size of full surface array
INTEGER                        :: ILUOUT ! output listing logical unit
INTEGER, DIMENSION(:), POINTER :: IMASK  ! mask for packing from complete field to nature field
INTEGER                        :: IDIM   !
INTEGER                        :: JI
!
 CHARACTER(LEN=6)    :: YMASK
INTEGER, DIMENSION(NL) :: ISTATUS
REAL, DIMENSION(NL,1) :: ZDEPTH, ZSTATUS    ! physiographic field on full grid
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) CALL dr_hook('TREAT_GLOBAL_LAKE_DEPTH',0,zhook_handle)
zdepth(:,:) = xundef
zstatus(:,:) = xundef
!-------------------------------------------------------------------------------
!
!*    2.      Output listing logical unit
!             ---------------------------
!
 CALL get_luout(hprogram,iluout)
!
!-------------------------------------------------------------------------------
!
!*    4.      Averages the field
!             ------------------
!
ALLOCATE(nsize_all(u%NDIM_FULL,1))
ALLOCATE(xall(u%NDIM_FULL,ngraddepth_ldb,1))
!
nsize_all(:,:) = 0.
xall(:,:,:) = 0.
!
 CALL treat_field(ug, u, uss, &
                  hprogram,'SURF  ','DIRECT','A_LDBD', clakeldb,   &
                 'water depth         ',zdepth      ) 
!
DEALLOCATE(xsumval)
DEALLOCATE(nsize)
!
ALLOCATE(nsize_all(u%NDIM_FULL,1))
ALLOCATE(xall(u%NDIM_FULL,ngradstatus_ldb,1))
!
nsize_all(:,:) = 0.
xall(:,:,:) = 0.
!
 CALL treat_field(ug, u, uss, &
                  hprogram,'SURF  ','DIRECT','A_LDBS', cstatusldb,  &
                 'water status        ',zstatus             )
!
istatus = nint(zstatus(:,1))
!
DEALLOCATE(xsumval)
DEALLOCATE(nsize)
!
!-------------------------------------------------------------------------------
!
!*    5.      Consistancy check
!             ------------------
!
DO ji = 1, SIZE(zdepth,1)
  IF (u%XWATER(ji).GT.0.) THEN
    IF (istatus(ji).LE.2) zdepth(ji,1) = 10.
    IF (istatus(ji)==3.AND.zdepth(ji,1)==0.) zdepth(ji,1) = 10.
  ELSE
    zdepth(ji,1) = 0.
  ENDIF
ENDDO
!
!*    6.      Mask for the field
!             ------------------
!
ymask='WATER '
 CALL get_type_dim_n(dtco, u, &
                     ymask,idim)
IF (idim/=SIZE(pdepth) .OR. idim/=SIZE(kstatus)) THEN
   WRITE(iluout,*)'Wrong dimension of MASK: ',idim,SIZE(pdepth),SIZE(kstatus)
   CALL abor1_sfx('TREAT_GLOBAL_LAKE_DEPTH: WRONG DIMENSION OF MASK')
ENDIF

ALLOCATE(imask(idim))
ilu=0
 CALL get_surf_mask_n(dtco, u, &
                      ymask,idim,imask,ilu,iluout)
 CALL pack_same_rank(imask,zdepth(:,1),pdepth(:))
 CALL pack_same_rank(imask,istatus(:),kstatus(:))
DEALLOCATE(imask)
!
IF (lhook) CALL dr_hook('TREAT_GLOBAL_LAKE_DEPTH',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE treat_global_lake_depth