thrmcondz.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE thrmcondz(PSANDZ,PWSATZ,PCONDDRY,PCONDSLD)
!   ###############################################################
!!****  *THRMCONDZ*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates soil thermal conductivity components
!     using sand fraction and model constants in
!     order to calculate the thermal conductivity
!     following the method of Johansen (1975) as recommended
!     by Farouki (1986) parameterized for SVAT schemes
!     following Peters-Lidard et al. 1998 (JAS). This is
!     used in explicit calculation of CG (soil thermal
!     inertia): it is an option. DEFAULT is method of
!     Noilhan and Planton (1989) (see SOIL.F90).
!              
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!    Peters-Lidard et al. 1998 (JAS)
!!      
!!    AUTHOR
!!    ------
!!
!!      A. Boone           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    25/03/99
!!                  18/02/00    2D for veritcal profiles
!!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_surf_par,   ONLY : xundef
USE modd_isba_par,   ONLY : xdrywght, xsphsoil, xcondqrtz, xcondoth1, xcondoth2
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL,   DIMENSION(:,:), INTENT(IN) :: PSANDZ     ! soil sand fraction (-)
REAL,   DIMENSION(:,:), INTENT(IN) :: PWSATZ     ! soil porosity (m3 m-3)
!
REAL,   DIMENSION(:,:), INTENT(OUT):: PCONDDRY  ! soil dry thermal conductivity
!                                                 (W m-1 K-1)
REAL,   DIMENSION(:,:), INTENT(OUT):: PCONDSLD  ! soil solids thermal
!                                                 conductivity (W m-1 K-1)
!
!*      0.2    declarations of local variables
!
REAL,    DIMENSION(SIZE(PSANDZ,1),SIZE(PSANDZ,2)) :: ZQUARTZ, ZGAMMAD
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-----------------------------------------------------------------
!
IF (lhook) CALL dr_hook('THRMCONDZ',0,zhook_handle)
zquartz(:,:)   = xundef
zgammad(:,:)   = xundef
pcondsld(:,:)  = xundef
pconddry(:,:)  = xundef
!
!
! Quartz content estimated from sand fraction:
!
WHERE(psandz(:,:)/=xundef)
!
   zquartz(:,:)   = 0.038 + 0.95*psandz(:,:)
!
! Note, ZGAMMAD (soil dry density) can be supplied from obs, but
! for mesoscale modeling, we use the following approximation
! from Peters-Lidard et al. 1998:
!
   zgammad(:,:)   = (1.0-pwsatz(:,:))*xdrywght
!
END WHERE
!
! Soil solids conductivity:
!
WHERE(zquartz >  0.20 .AND. psandz(:,:)/=xundef)
   pcondsld(:,:)  = (xcondqrtz**zquartz(:,:))*                        &
                    (xcondoth1**(1.0-zquartz(:,:)))  
END WHERE
WHERE(zquartz <= 0.20 .AND. psandz(:,:)/=xundef)
   pcondsld(:,:)  = (xcondqrtz**zquartz(:,:))*                        &
                    (xcondoth2**(1.0-zquartz(:,:)))  
ENDWHERE
!
! Soil dry conductivity:
!
WHERE(psandz(:,:)/=xundef)
   pconddry(:,:)     = (0.135*zgammad(:,:) + 64.7)/                   &
                         (xdrywght - 0.947*zgammad(:,:))  
END WHERE
IF (lhook) CALL dr_hook('THRMCONDZ',1,zhook_handle)
!
!
!
END SUBROUTINE thrmcondz