sufftp.F90

Go to the documentation of this file.

SUBROUTINE sufftp(KDLON,KFFTP0,LDODD)

!**** *SUFFTP*  - Initialize possible numbers for FFT's

!     Purpose.
!     --------
!           Initialize possible numbers for FFT's

!**   Interface.
!     ----------
!        *CALL* *SUFFTP(KDLON,KFFTP0)

!        Explicit arguments :
!        --------------------
!        LDODD : .TRUE. if odd numbers are allowed
!        KFFTP0(KDLON) 0 ---> possible for FFT
!                      1 ---> impossible for FFT

!        Implicit arguments :
!        --------------------

!     Method.
!     -------
!        See documentation

!     Externals.    none.
!     ----------

!     Reference.
!     ----------
!        ARPEGE documentation

!     Author.
!     -------
!        Philippe Courtier  *DMN*

!     Modifications.
!     --------------
!        Creation of cycle 4
!        R. El Khatib 15-May-2013 Option to allow or not odd numbers
!     ------------------------------------------------------------------


USE parkind1  ,ONLY : jpim     ,jprb
USE yomhook   ,ONLY : lhook,   dr_hook

IMPLICIT NONE

INTEGER(KIND=JPIM), INTENT(IN) :: KDLON
INTEGER(KIND=JPIM), INTENT(OUT) :: KFFTP0(kdlon)
LOGICAL, INTENT(IN) :: LDODD

INTEGER(KIND=JPIM) :: I2MAX, I3MAX, I5MAX, IMIN, IN, J, J2, J3, J5


REAL(KIND=JPRB) :: ZHOOK_HANDLE

!     ------------------------------------------------------------------

IF (lhook) CALL dr_hook('REDUCED_GRID',0,zhook_handle)

!*       1.    Initialize up to IMIN-1
!              --------------------

imin=16
IF(kdlon <= imin-1)THEN
  CALL abor1(' ERROR IN SUFFTP0 ')
ENDIF

DO j=1,imin-1
  kfftp0(j)=1
ENDDO

!     ------------------------------------------------------------------

!*       2.    Initialize from 16.
!              -------------------

i2max=int(log(REAL(kdlon,jprb))/log(2._JPRB))+1
i3max=int(log(REAL(kdlon,jprb))/log(3._JPRB))+1
i5max=int(log(REAL(kdlon,jprb))/log(5._JPRB))+1

DO j=imin,kdlon

  IF (.NOT.ldodd) THEN
    IF(mod(j,2) /= 0)THEN
      kfftp0(j)=1
      GOTO 202
    ENDIF
  ENDIF

  in=j
  DO j2=1,i2max
    IF(mod(in,2) == 0)THEN
      in=in/2
    ENDIF
  ENDDO

  DO j3=1,i3max
    IF(mod(in,3) == 0)THEN
      in=in/3
    ENDIF
  ENDDO

  DO j5=1,i5max
    IF(mod(in,5) == 0)THEN
      in=in/5
    ENDIF
  ENDDO

  IF(in /= 1)THEN
    kfftp0(j)=1
  ELSE
    kfftp0(j)=0
  ENDIF
  202 CONTINUE
ENDDO

! Memo :
! this is old stuff and is not used anymore, unfortunately some resolutions like T799 have been created like this !!
!  The possibility of 625 or 1250 points in the T426, TL639 grids
!   should be eliminated due to the radiation code (memo from Lars)      
!IF(KDLON >= 640) THEN
!  KFFTP0(625)=1
!  IF(KDLON >= 1250) THEN
!    KFFTP0(1250)=1
!  ENDIF
!ENDIF

IF (lhook) CALL dr_hook('REDUCED_GRID',1,zhook_handle)

END SUBROUTINE sufftp