sso_beljaars04.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###########################################################################
SUBROUTINE sso_beljaars04 (USS, SB, KI, PSSO_STDEV, PFORC_U, PDFORC_UDU)
!     ###############################################################################
!
!!****  *SSO_BELJAARS04_n * - prepares forcing for canopy air model
!!
!!    SB%XURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2006
!!---------------------------------------------------------------
!
USE modd_canopy_n, ONLY : canopy_t
USE modd_sso_n, ONLY : sso_t
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(sso_t), INTENT(INOUT) :: USS
TYPE(canopy_t), INTENT(INOUT) :: SB
!
INTEGER,                  INTENT(IN)    :: KI        ! number of points
REAL, DIMENSION(KI),      INTENT(IN)    :: PSSO_STDEV! Subgrid scale orography standard dev. (m)
!
REAL, DIMENSION(KI,SB%NLVL), INTENT(INOUT)   :: PFORC_U   ! tendency of wind due to canopy drag   (m/s2)
REAL, DIMENSION(KI,SB%NLVL), INTENT(INOUT)   :: PDFORC_UDU! formal derivative of the tendency of
!                                                    ! wind due to canopy drag               (1/s)
!
!*      0.2    declarations of local variables
!
!
!* BERJLAARS et al 2004  constants
!
REAL, PARAMETER :: C_ALPHA   = 12.
REAL, PARAMETER :: C_BETA    = 1.
REAL, PARAMETER :: C_CMD     = 0.005
REAL, PARAMETER :: C_COR     = 0.6
REAL, PARAMETER :: C_IH      = 0.00102    !   (m-1)
REAL, PARAMETER :: C_KFLT    = 0.00035    !   (m-1)
REAL, PARAMETER :: C_K1      = 0.003      !   (m-1)
REAL, PARAMETER :: C_N1      = -1.9
REAL, PARAMETER :: C_N2      = -2.8
REAL            :: C_AVAR                 ! = C_K1**(C_N1-C_N2) / (C_IH * C_KFLT**C_N1)  
!                                         ! (unit: m^{1+C_N2}  =  m^-1.8)
!
INTEGER                  :: JL            ! loop counter on canopy heights
REAL, DIMENSION(KI,SB%NLVL) :: ZSSO_DRAG     ! drag due to subgrid-scale orogaphy
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!-------------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('SSO_BELJAARS04',0,zhook_handle)
!
!*      2.     Computations of wind tendency due to orographic drag
!              ----------------------------------------------------
!
c_avar    = c_k1**(c_n1-c_n2) / (c_ih * c_kflt**c_n1)   ! (unit: m^{1+C_N2}  =  m^-1.8)
!
!
!*      2.1    Drag coefficient in  drag force by subscale orography 
!              -----------------------------------------------------
!
! unit : m-1    (m^-1.8 . m ^2 . m^-1.2) 
!
zsso_drag = 0.
DO jl=1,sb%NLVL
  zsso_drag(:,jl) = uss%XCOEFBE * c_alpha * c_beta * c_cor * c_cmd * 2.109 * &
         exp( -(sb%XZ(:,jl)/1500.)**1.5) * c_avar * psso_stdev(:)**2 * sb%XZ(:,jl)**(-1.2)
END DO
!
!
!*      2.2    Impact on each SBL layer
!              ------------------------
!
! Ext = - Cdrag(z)  * u- * u-       (unit :  m s-2)   subscale orgraphy drag
!
pforc_u(:,:)    = pforc_u(:,:)    -       zsso_drag(:,:) * sb%XU(:,:)**2
!
pdforc_udu(:,:) = pdforc_udu(:,:) -  2. * zsso_drag(:,:) * sb%XU(:,:)
!
IF (lhook) CALL dr_hook('SSO_BELJAARS04',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE sso_beljaars04