soilstress.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE soilstress( HISBA, PF2, KK, PK, PEK, PF2WGHT, PF5        )  
!     ####################################################################
!
!!****  *SOILSTRESS*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates the vegetation stress due to soil water
!         
!     
!!**  METHOD
!!    ------
!
!     Calculates the F2 coefficient.
!     
!
!!    EXTERNAL
!!    --------
!!
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!    none
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!    Noilhan and Planton (1989)
!!    Belair (1995)
!!      
!!    AUTHOR
!!    ------
!!
!!      S. Belair           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original      13/03/95 
!!     (P.Jabouille)  13/11/96    mininum value for ZF1
!!     (V. Masson)    28/08/98    add PF2 for Calvet (1998) CO2 computations
!!     (B. Decharme)     07/15    Suppress numerical adjustement for PF2 
!!     (B. Decharme)     01/17    Suppress soil/vegetation parameters modification
!!                                for DIF due to the presence of ice to ensure maximum
!!                                vegetation stress when soil ice is important. Indeed,
!!                                soil ice acts as drought events for vegetation stress
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_isba_n, ONLY : isba_k_t, isba_p_t, isba_pe_t
!
USE modd_isba_par,  ONLY : xdenom_min
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
 CHARACTER(LEN=*),     INTENT(IN)   :: HISBA   ! type of soil (Force-Restore OR Diffusion)
!                                             ! '2-L'
!                                             ! '3-L'
!                                             ! 'DIF'   ISBA-DF
!
REAL, DIMENSION(:), INTENT(OUT)  :: PF2      ! water stress coefficient
!
TYPE(isba_k_t), INTENT(INOUT) :: KK
TYPE(isba_p_t), INTENT(INOUT) :: PK
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
!
REAL, DIMENSION(:), INTENT(OUT)  :: PF5      ! water stress coefficient for Hv (based on F2):
!                                            ! Verify that Etv=>0 as F2=>0
!
REAL, DIMENSION(:,:), INTENT(OUT):: PF2WGHT  ! water stress coefficient profile (ISBA-DF)
!
!
!*      0.2    declarations of local variables
!
!
REAL, DIMENSION(SIZE(KK%XWFC,1)) ::  ZWFC_AVGZ, ZWSAT_AVGZ, ZWWILT_AVGZ
!                                  ZWFC_AVGZ   = field capacity averaged over entire soil column
!                                  ZWSAT_AVGZ  = porosity averaged over entire soil column
!                                  ZWWILT_AVGZ = wilting point averaged over entire soil column
!
REAL    :: ZROOTFRACN
!          ZROOTFRACN = Normalized root fraction weights
!
INTEGER :: INI, INL, JJ, JL, IDEPTH
!
!
!*      0.3    declarations of local parameters:
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!*       0.     Initialization of variables:
!               ----------------------------
!
IF (lhook) CALL dr_hook('SOILSTRESS',0,zhook_handle)
!
ini=SIZE(pek%XWG,1)
IF (SIZE(pk%NWG_LAYER)>0) THEN
  inl=maxval(pk%NWG_LAYER(:))
ELSE
  inl=0
ENDIF
!
pf2(:)      = 0.0
pf2wght(:,:)    = 0.0
!
zwfc_avgz(:)    = 0.
zwsat_avgz(:)   = 0.
zwwilt_avgz(:)  = 0.
!
!-------------------------------------------------------------------------------
!
!*       2.     THE 'PF2' FACTOR
!               ----------------
!               This factor takes into account the effect
!               of the water stress on the surface
!               resistance
!
! - For humid soils (> WFC), this factor does not
!   increase the stomatal resistance                                   
! - The stomatal resistance should be large
!   when the soil is very dry (< WILT)
!
IF(hisba =='DIF')THEN      
!
! If using the diffusion option, then calculate transpiration weights
! and the mean root-zone soil water stress factor F2:
!
!---------------------------------------------------------
! First layer
!---------------------------------------------------------
!
! Calculate the soil water stress factor for each layer:
  pf2wght(:,1) = (pek%XWG(:,1)-kk%XWWILT(:,1))/(kk%XWFC(:,1)-kk%XWWILT(:,1))
!
! Normalize the transpiration weights by root fraction:
  pf2wght(:,1) = pk%XROOTFRAC(:,1)*max(0.0,min(1.0,pf2wght(:,1)))
!
! Net soil water stress for entire root zone:
  pf2(:) = pf2wght(:,1)
!
!---------------------------------------------------------
! Other layers
!---------------------------------------------------------
!
  DO jl=2,inl
     DO jj=1,ini
!
      idepth=pk%NWG_LAYER(jj)
      IF(jl<=idepth)THEN
!
!       Calculate normalized root fraction weights:
        zrootfracn = pk%XROOTFRAC(jj,jl) - pk%XROOTFRAC(jj,jl-1)
!
!       Calculate the soil water stress factor for each layer:
        pf2wght(jj,jl) = (pek%XWG(jj,jl)-kk%XWWILT(jj,jl))/(kk%XWFC(jj,jl)-kk%XWWILT(jj,jl))
!
!       Normalize the transpiration weights by root fraction:
        pf2wght(jj,jl) = zrootfracn*max(0.0,min(1.0,pf2wght(jj,jl)))
!
!       Net soil water stress for entire root zone:
        pf2(jj)        = pf2(jj) + pf2wght(jj,jl)
!        
      ENDIF
!
     ENDDO
  ENDDO
!
ELSE
!
! When using the Force-Restore (FR) soil option, the soil properties
! are assumed to be homogeneous in the vertical. Therefore, simply
! use the properties for the uppermost soil layer when defining
! soil properties for local computations.
!
! Due to the presence of ice, modify soil parameters:
!
   zwsat_avgz(:)  = kk%XWSAT (:,1) - pek%XWGI(:,2)
   zwfc_avgz(:)   = kk%XWFC  (:,1)*zwsat_avgz(:)/kk%XWSAT(:,1)
   zwwilt_avgz(:) = kk%XWWILT(:,1)*zwsat_avgz(:)/kk%XWSAT(:,1)
!
! Compute the water stress factor:
!
   pf2(:) = (pek%XWG(:,2)-zwwilt_avgz(:))/(zwfc_avgz(:)-zwwilt_avgz(:))
   pf2(:) = max(0.0,min(1.0, pf2(:)))
!
!
ENDIF
!
! Function to cause Etv to approach 0 as F2 goes to 0:
!
pf5(:) = pf2(:)
!
IF (lhook) CALL dr_hook('SOILSTRESS',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE soilstress