snow_leaves_frac_meb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ##########################################################################
SUBROUTINE snow_leaves_frac_meb(PPSN, PPALPHAN,      &
                                          PWRVN,     &
                                          PTV,       &
                                          PCHIP,     &
                                          PLAIV,     &
                                          PWRVNMAX,  &
                                          PDELTAVN, PMELTVN )
!   ############################################################################
!
!!****  *SNOW_LEAVES_FRAC_MEB*  
!!
!!    PURPOSE
!!    -------
!
!     Calculate desnity, maximum snow load etc for intercepted snow
!     
!!**  METHOD
!!    ------
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      P. Samuelsson           * SMHI *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    02/2011
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_csts,     ONLY : xtt
!
USE modd_surf_par, ONLY : xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:), INTENT(IN)   :: PPSN, PPALPHAN
!                                     PPSN       =
!                                     PPALPHAN   = snow/canopy transition coefficient
!
REAL, DIMENSION(:), INTENT(IN)   :: PWRVN
!                                     PWRVN      = snow retained on the foliage
!
REAL, DIMENSION(:), INTENT(IN)   :: PLAIV
!                                     PLAIV      = canopy vegetation leaf area index
!
REAL, DIMENSION(:), INTENT(IN)   :: PCHIP, PTV
!                                     PCHIP      = view factor (for LW) 
!                                     PTV        = Canopy T (K)
!
REAL, DIMENSION(:), INTENT(OUT)  :: PWRVNMAX
!                                     PWRVNMAX   = maximum equivalent snow content
!                                                  in the canopy vegetation
!
REAL, DIMENSION(:), INTENT(OUT)  :: PDELTAVN
!                                     PDELTAVN   = fraction of the canopy foliage covered
!                                                  by intercepted snow
!
REAL, DIMENSION(:), INTENT(OUT)  :: PMELTVN
!                                     PMELTVN    = freeze/melt rate (kg m-2 s-1)
!
!*      0.2    declarations of local variables
!
!
REAL, DIMENSION(SIZE(PLAIV)) :: ZLAI,ZFCP,ZFRACVN, ZSNOWRHOV
!                                ZLAI      = weigthed leaf area index
!                                ZFCP      = snow interception factor
!                                ZFRACVN   = fraction of interception snow
!                                ZSNOWRHOV = density of snow intercepted by the canopy (kg m-3)
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*      0.3    declarations of local parameters
!
!  For intercepted snow density
!
REAL, PARAMETER             :: ZRHOVNPAR1    = 67.92      ! (kg/m3)
REAL, PARAMETER             :: ZRHOVNPAR2    = 51.25      ! (kg/m3)
REAL, PARAMETER             :: ZRHOVNPAR3    = 2.59       ! (K)
!
!  For intercepted maximum snow load
!
REAL, PARAMETER             :: ZWRVNMAXPAR1  = 6.3        ! (kg/m2)
REAL, PARAMETER             :: ZWRVNMAXPAR2  = 0.27       ! (-)
REAL, PARAMETER             :: ZWRVNMAXPAR3  = 46.        ! (kg/m3)

!  For intercepted snow evaporation efficiency
!
REAL, PARAMETER             :: ZDVNPAR1      = 0.89       ! (-)
REAL, PARAMETER             :: ZDVNPAR2      = -4.7       ! (-)
REAL, PARAMETER             :: ZDVNPAR3      = 0.45       ! (-)
REAL, PARAMETER             :: ZDVNPAR4      = 0.3        ! (-)
REAL, PARAMETER             :: ZMELTF        = 5.556e-6   ! Snow melt factor
REAL, PARAMETER             :: ZLAI_MIN      = 0.001      ! (m2 m-2) Below this (numerical) threshold, interception
                                                          ! by the canopy is not assumed to occur
                                                          ! as canopy essentially buried.
REAL, PARAMETER             :: ZRHOVN_TMAX   = 279.85403  ! (K) corresponds to a snow density of 
                                                          ! 750 kg m-3 (presumably the max).
                                                          ! Obtained by inverting the snow density Eq
                                                          ! for Tv below assuming a density of 750

!-------------------------------------------------------------------------------
!
!*      0.     Initialization
!               --------------
!
IF (lhook) CALL dr_hook('SNOW_LEAVES_FRAC_MEB',0,zhook_handle)
!
zsnowrhov(:)= zrhovnpar1
!
zfracvn(:)  = 0.0
zfcp(:)     = 0.0
!
pdeltavn(:) = 0.0
pmeltvn(:)  = 0.0
pwrvnmax(:) = 0.0
!
!
zlai(:)     = plaiv(:)*(1.-ppsn(:)+ppsn(:)*(1.-ppalphan(:)))
!
! If snow buries the vegetation canopy (i.e. ZLAI~=0), we do not need the following:
! 
WHERE(zlai(:) > zlai_min .AND. plaiv(:)/=xundef)
!
! Snow density
!
   zsnowrhov(:)= zrhovnpar1 + zrhovnpar2*exp( (min(zrhovn_tmax,ptv(:))-xtt)/zrhovnpar3)
!
! Intercepted maximum snow load
!
   pwrvnmax(:) = zwrvnmaxpar1*(zwrvnmaxpar2+zwrvnmaxpar3/zsnowrhov(:)) * zlai(:)
!
! Fraction of snow on vegetation canopy
!
   zfracvn(:)  = pwrvn(:)/pwrvnmax(:)
!
! Snow evaporation efficiency coefficient which corresponds to
! delta for intercepted water
!
   pdeltavn(:) = zdvnpar1*zfracvn(:)**zdvnpar4/( 1.+exp( zdvnpar2*( zfracvn(:) - zdvnpar3 ) ) )
!
! Melt rate (kg/m2/s)
!
   pmeltvn(:)  = zmeltf * ( ptv(:)-xtt ) * zfracvn(:)
!
END WHERE
!
IF (lhook) CALL dr_hook('SNOW_LEAVES_FRAC_MEB',1,zhook_handle)
!
END SUBROUTINE snow_leaves_frac_meb