sm10.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###############################################################################
SUBROUTINE sm10(PZ,PBLD_HEIGHT,PLAMBDA_F,PL)
!     ###############################################################################
!
!!****  *SM10* computes the shape for the mixing length according to Santiago and Martilli 2010
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    06/2010
!!---------------------------------------------------------------
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:,:), INTENT(IN)  :: PZ          ! canopy levels        (m)
REAL, DIMENSION(:),   INTENT(IN)  :: PBLD_HEIGHT ! building height      (m)
REAL, DIMENSION(:),   INTENT(IN)  :: PLAMBDA_F   ! frontal area density (-)
REAL, DIMENSION(:,:), INTENT(OUT) :: PL          ! base profile for mixing 
!                                                ! length computations  (m)
!
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PZ,1))           :: ZZ_CAN             ! mixing length generic profile in canopy
REAL, DIMENSION(SIZE(PZ,1),SIZE(PZ,2)):: ZZ_SURF            ! Mixing length generic profile at mid levels (near the surface)
REAL, DIMENSION(SIZE(PZ,1),SIZE(PZ,2)):: ZZ_ISBL            ! Mixing length generic profile at mid levels (in the inertial SBL)
REAL, DIMENSION(SIZE(PZ,1))           :: ZZ_BASE_ISBL       ! Mixing length generic at the base of the ISBL
REAL, DIMENSION(SIZE(PZ,1))           :: ZDISP_H            ! displacement height
REAL, PARAMETER                       :: ZALPHA_CAN = 1.12  ! value to compute lengths in the canyon

INTEGER                               :: JLAYER             ! vertical loop counter
INTEGER                               :: ILVL               ! number of layers
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!* Preliminaries:
IF (lhook) CALL dr_hook('SM10',0,zhook_handle)
ilvl = SIZE(pz,2)
!
!* Typical uniform value in the canopy (after Santiago and Martilli 2010)
!  Threshold at 3/4 of hte height of the building is added to avoid unphysical
!  values for large lambda_f.
!
zdisp_h(:) = min( plambda_f(:)**0.13 * pbld_height(:) , 0.75 * pbld_height )
zz_can(:)  = zalpha_can * (pbld_height(:) - zdisp_h(:))
!
!* Lengths near the surface (road, gardens)
zz_surf(:,:) = pz(:,:)
!
!* Lengths in the inertial sublayer (z/h>1.5)
DO jlayer=1,ilvl
  zz_isbl(:,jlayer) = max(zz_can(:), pz(:,jlayer) - zdisp_h(:))
END DO
! first point is used to compute the value at the base of the ISBL (z/h=1.5)
zz_base_isbl(:) = max(pz(:,1),  1.5 * pbld_height(:) )
!
!* Composition of all these mixing lengths
DO jlayer=1,ilvl
  WHERE (pz(:,jlayer)<=pbld_height(:))
!* inside canopy, lengths are equal to minimum between uniform value and value limited by the surface
    pl(:,jlayer) = min(zz_surf(:,jlayer), zz_can(:))
  END WHERE
  WHERE (pz(:,jlayer)>zz_base_isbl(:) )
!* in the inertial sublayer
    pl(:,jlayer) = zz_isbl(:,jlayer)
  END WHERE
  WHERE (pz(:,jlayer)>pbld_height(:) .AND. pz(:,jlayer)<=1.5*pbld_height(:))
!* in the transition sublayer
    pl(:,jlayer) = zz_can(:) + (zz_isbl(:,jlayer)-zz_can(:)) &
                               * (pz(:,jlayer)-pbld_height(:)) / (zz_base_isbl(:) - pbld_height(:))
  END WHERE
END DO
!
! check if mixing length scale increases with height
!
DO jlayer=2,ilvl
  pl(:,jlayer) = max(pl(:,jlayer-1),pl(:,jlayer))
END DO
IF (lhook) CALL dr_hook('SM10',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE sm10