sfx_oasis_send_ol.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#########
SUBROUTINE sfx_oasis_send_ol (F, IM, S, U, W, &
                              HPROGRAM,KI,PTIMEC,PSTEP_SURF)
!###########################################
!
!!****  *SFX_OASIS_SEND_OL* - Offline driver to send coupling fields
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2013
!!      B. Decharme 10/2016  bug surface/groundwater coupling
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
USE modd_off_surfex_n, ONLY : goto_model
!
USE modd_flake_n, ONLY : flake_t
USE modd_surfex_n, ONLY : isba_model_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_watflux_n, ONLY : watflux_t
!
USE modd_surf_par,   ONLY : xundef
!
USE modn_sfx_oasis,  ONLY : xtstep_cpl_land, &
                            xtstep_cpl_lake, &
                            xtstep_cpl_sea , &
                            lwater
!
USE modd_sfx_oasis,  ONLY : lcpl_land,lcpl_gw,       &
                            lcpl_flood,lcpl_calving, &
                            lcpl_lake,               &
                            lcpl_sea,lcpl_seaice
!
USE modi_get_sfx_land
USE modi_get_sfx_lake
USE modi_get_sfx_sea
!
USE modi_get_luout
USE modi_sfx_oasis_send
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
#ifdef AIX64
!$ USE OMP_LIB
#endif
!
IMPLICIT NONE
!
#ifndef AIX64
!$ INCLUDE 'omp_lib.h'
#endif
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(flake_t), INTENT(INOUT) :: F
TYPE(isba_model_t), INTENT(INOUT) :: IM
TYPE(seaflux_t), INTENT(INOUT) :: S
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(watflux_t), INTENT(INOUT) :: W
!
 CHARACTER(LEN=*),      INTENT(IN) :: HPROGRAM
INTEGER,               INTENT(IN) :: KI            ! number of points
REAL,                  INTENT(IN) :: PTIMEC        ! Cumulated run time step (s)
REAL,                  INTENT(IN) :: PSTEP_SURF    ! Model time step (s)
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(KI)   :: ZLAND_RUNOFF    ! Cumulated Surface runoff             (kg/m2)
REAL, DIMENSION(KI)   :: ZLAND_DRAIN     ! Cumulated Deep drainage              (kg/m2)
REAL, DIMENSION(KI)   :: ZLAND_CALVING   ! Cumulated Calving flux               (kg/m2)
REAL, DIMENSION(KI)   :: ZLAND_WATFLD    ! Cumulated net freshwater rate        (kg/m2)
!
REAL, DIMENSION(KI)   :: ZLAKE_EVAP  ! Cumulated Evaporation             (kg/m2)
REAL, DIMENSION(KI)   :: ZLAKE_RAIN  ! Cumulated Rainfall rate           (kg/m2)
REAL, DIMENSION(KI)   :: ZLAKE_SNOW  ! Cumulated Snowfall rate           (kg/m2)
REAL, DIMENSION(KI)   :: ZLAKE_WATF  ! Cumulated net freshwater rate     (kg/m2)
!
REAL, DIMENSION(KI)   :: ZSEA_FWSU  ! Cumulated zonal wind stress       (Pa.s)
REAL, DIMENSION(KI)   :: ZSEA_FWSV  ! Cumulated meridian wind stress    (Pa.s)
REAL, DIMENSION(KI)   :: ZSEA_HEAT  ! Cumulated Non solar net heat flux (J/m2)
REAL, DIMENSION(KI)   :: ZSEA_SNET  ! Cumulated Solar net heat flux     (J/m2)
REAL, DIMENSION(KI)   :: ZSEA_WIND  ! Cumulated 10m wind speed          (m)
REAL, DIMENSION(KI)   :: ZSEA_FWSM  ! Cumulated wind stress             (Pa.s)
REAL, DIMENSION(KI)   :: ZSEA_EVAP  ! Cumulated Evaporation             (kg/m2)
REAL, DIMENSION(KI)   :: ZSEA_RAIN  ! Cumulated Rainfall rate           (kg/m2)
REAL, DIMENSION(KI)   :: ZSEA_SNOW  ! Cumulated Snowfall rate           (kg/m2)
REAL, DIMENSION(KI)   :: ZSEA_WATF  ! Cumulated net freshwater rate     (kg/m2)
!
REAL, DIMENSION(KI)   :: ZSEAICE_HEAT ! Cumulated Sea-ice non solar net heat flux (J/m2)
REAL, DIMENSION(KI)   :: ZSEAICE_SNET ! Cumulated Sea-ice solar net heat flux     (J/m2)
REAL, DIMENSION(KI)   :: ZSEAICE_EVAP ! Cumulated Sea-ice sublimation             (kg/m2)
!
INTEGER               :: IDATE  ! current coupling time step (s)
INTEGER               :: ILUOUT
INTEGER               :: INKPROMA
!
LOGICAL               :: GSEND_LAND
LOGICAL               :: GSEND_LAKE
LOGICAL               :: GSEND_SEA
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_SEND_OL',0,zhook_handle)
!
!-------------------------------------------------------------------------------
!
!*       1.     Initialize proc by proc :
!               -------------------------
!
 CALL get_luout(hprogram,iluout)
!
idate = int(ptimec-pstep_surf)
!
gsend_land=(lcpl_land.AND.mod(ptimec,xtstep_cpl_land)==0.0)
gsend_lake=(lcpl_lake.AND.mod(ptimec,xtstep_cpl_lake)==0.0)
gsend_sea =(lcpl_sea .AND.mod(ptimec,xtstep_cpl_sea )==0.0)
!
!-------------------------------------------------------------------------------
!
IF(.NOT.(gsend_land.OR.gsend_lake.OR.gsend_sea))THEN
  IF (lhook) CALL dr_hook('SFX_OASIS_SEND_OL',1,zhook_handle)
  RETURN
ENDIF
!
!-------------------------------------------------------------------------------
!
IF(gsend_land)THEN
  zland_runoff(:) = xundef
  zland_drain(:) = xundef
  zland_calving(:) = xundef
  zland_watfld(:) = xundef  
ENDIF
!
IF(gsend_lake)THEN
  zlake_evap(:) = xundef
  zlake_rain(:) = xundef
  zlake_snow(:) = xundef
  zsea_watf(:) = xundef  
ENDIF
!
IF(gsend_sea)THEN
  zsea_fwsu(:) = xundef
  zsea_fwsv(:) = xundef
  zsea_heat(:) = xundef
  zsea_snet(:) = xundef
  zsea_wind(:) = xundef
  zsea_fwsm(:) = xundef
  zsea_evap(:) = xundef
  zsea_rain(:) = xundef
  zsea_snow(:) = xundef
  zsea_watf(:) = xundef
  !
  zseaice_heat(:) = xundef
  zseaice_snet(:) = xundef
  zseaice_evap(:) = xundef
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       2.     get local fields :
!               ------------------
!
IF(gsend_land)THEN
!
! * Get river output fields
!
  CALL get_sfx_land(im%O, im%S, u, &
                    lcpl_gw,lcpl_flood,lcpl_calving,  &
                    zland_runoff(:),zland_drain(:),&
                    zland_calving(:),zland_watfld(:))
!
ENDIF
!
IF(gsend_lake)THEN
!
! * Get output fields
!
  CALL get_sfx_lake(f, u, &
                    zlake_evap(:),zlake_rain(:), &
                    zlake_snow(:),zlake_watf(:) )
!
ENDIF
!
IF(gsend_sea)THEN
!
! * Get sea output fields
!
  CALL get_sfx_sea(s, u, w, &
                   lcpl_seaice,lwater,                                                                                    &
                   zsea_fwsu(:),zsea_fwsv(:),zsea_heat(:),&
                   zsea_snet(:),zsea_wind(:),zsea_fwsm(:),&
                   zsea_evap(:),zsea_rain(:),zsea_snow(:),&
                   zsea_watf(:),                                &
                   zseaice_heat(:),zseaice_snet(:),zseaice_evap(:) )
!
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       3.     Send fields to OASIS proc by proc:
!               ----------------------------------
!
  CALL sfx_oasis_send(iluout,ki,idate,gsend_land,gsend_lake,gsend_sea,      &
                      zland_runoff,zland_drain,zland_calving,zland_watfld,  &
                      zlake_evap,zlake_rain,zlake_snow,zlake_watf,          &
                      zsea_fwsu,zsea_fwsv,zsea_heat,zsea_snet,zsea_wind,    &
                      zsea_fwsm,zsea_evap,zsea_rain,zsea_snow,zsea_watf,    &
                      zseaice_heat,zseaice_snet,zseaice_evap                )                   
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_SEND_OL',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE sfx_oasis_send_ol