sfx_oasis_prep.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#########
SUBROUTINE sfx_oasis_prep (IO, S, UG, U, HPROGRAM, KNPTS, KPARAL)
!###################################################
!
!!****  *SFX_OASIS_PREP* - Prepare grid areas and mask file for SFX-OASIS coupling
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2013
!!    10/2016 B. Decharme : bug surface/groundwater coupling 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_s_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_surf_par,       ONLY : xundef
!
USE modd_surfex_mpi, ONLY : nrank, npio
!
USE modn_sfx_oasis
USE modd_sfx_oasis
!
USE modi_gather_and_write_mpi
USE modi_get_luout
USE modi_abor1_sfx
USE modi_get_mesh_corner
USE modi_unpack_same_rank
USE modi_sfx_oasis_check
!
#ifdef CPLOASIS
USE mod_oasis
#endif
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(isba_s_t), INTENT(INOUT) :: S
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
 CHARACTER(LEN=6),        INTENT(IN) :: HPROGRAM    ! program calling surf. schemes
INTEGER,                 INTENT(IN) :: KNPTS  ! Number of grid point on this proc
INTEGER, DIMENSION(:),   INTENT(IN) :: KPARAL
!
!*       0.2   Declarations of local parameter
!              -------------------------------
!
INTEGER,           PARAMETER  :: INC = 4    ! Number of grid-cell corners
!
 CHARACTER(LEN=4),  PARAMETER  :: YSFX_LAND = 'slan'
 CHARACTER(LEN=4),  PARAMETER  :: YSFX_SEA  = 'ssea'
 CHARACTER(LEN=4),  PARAMETER  :: YSFX_LAKE = 'slak'
!
!*       0.3   Declarations of local variables
!              -------------------------------
!
REAL,    DIMENSION(U%NSIZE_FULL)       :: ZMASK_LAND ! land-sea mask for rrm coupling
REAL,    DIMENSION(U%NSIZE_FULL)       :: ZMASK_LAKE ! lake mask for ogcm coupling
REAL,    DIMENSION(U%NSIZE_FULL)       :: ZMASK_SEA  ! sea-land mask for ogcm coupling
!
REAL,    DIMENSION(U%NSIZE_FULL,1)     :: ZLON
REAL,    DIMENSION(U%NSIZE_FULL,1)     :: ZLAT
REAL,    DIMENSION(U%NSIZE_FULL,1)     :: ZAREA
INTEGER, DIMENSION(U%NSIZE_FULL,1)     :: IMASK
!
REAL,    DIMENSION(U%NSIZE_FULL,1,INC) :: ZCORNER_LON
REAL,    DIMENSION(U%NSIZE_FULL,1,INC) :: ZCORNER_LAT
!
REAL,    DIMENSION(U%NDIM_FULL)       :: ZMASK_LAND_TOT ! land-sea mask for rrm coupling
REAL,    DIMENSION(U%NDIM_FULL)       :: ZMASK_LAKE_TOT ! lake mask for ogcm coupling
REAL,    DIMENSION(U%NDIM_FULL)       :: ZMASK_SEA_TOT  ! sea-land mask for ogcm coupling
!
REAL,    DIMENSION(U%NDIM_FULL,1)     :: ZLON_TOT
REAL,    DIMENSION(U%NDIM_FULL,1)     :: ZLAT_TOT
REAL,    DIMENSION(U%NDIM_FULL,1)     :: ZAREA_TOT
INTEGER, DIMENSION(U%NDIM_FULL,1)     :: IMASK_TOT
!
REAL,    DIMENSION(U%NDIM_FULL,1,INC) :: ZCORNER_LON_TOT
REAL,    DIMENSION(U%NDIM_FULL,1,INC) :: ZCORNER_LAT_TOT
!
INTEGER, DIMENSION(2)          :: IVAR_SHAPE  ! indexes for the coupling field local dimension
!
INTEGER                        :: IPART_ID ! Local partition ID
INTEGER                        :: IERR     ! Error info
!
INTEGER                        :: ILUOUT, IFLAG
!
INTEGER                        :: JI, JC
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_PREP',0,zhook_handle)
!
!-------------------------------------------------------------------------------
#ifdef CPLOASIS
!-------------------------------------------------------------------------------
!
!
!*       0.     Initialize :
!               ------------
!
 CALL get_luout(hprogram,iluout)
!
 CALL sfx_oasis_check(io, u, iluout)
!
!-------------------------------------------------------------------------------
!
!*       1.     Define parallel partitions:
!               ---------------------------
!
 CALL oasis_def_partition(ipart_id,kparal(:),ierr)
!
IF(ierr/=oasis_ok)THEN
   WRITE(iluout,*)'SFX_OASIS_DEFINE: OASIS def partition problem, err = ',ierr
   CALL abor1_sfx('SFX_OASIS_DEFINE: OASIS def partition problem')
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       2.     Get grid definition :
!               ---------------------
!
 CALL get_mesh_corner(ug, iluout,zcorner_lat(:,1,:),zcorner_lon(:,1,:))
!
zlon(:,1)=ug%G%XLON(:)
zlat(:,1)=ug%G%XLAT(:)
!
!-------------------------------------------------------------------------------
!
!*       3.     Comput masks :
!               --------------
!
zmask_land(:) = u%XNATURE(:)+u%XTOWN(:)
zmask_sea(:) = u%XSEA   (:)
IF(u%CWATER=='FLAKE ')THEN
  zmask_lake(:) = u%XWATER (:)
ELSE
  zmask_lake(:) = xundef
ENDIF
IF(lcpl_sea.AND.lwater)THEN
  zmask_sea(:) = u%XSEA (:)+u%XWATER(:)
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       5.     Write grid definition :
!               -----------------------
!
!
!
IF (nrank==npio) CALL oasis_start_grids_writing(iflag)
!
!*       1.1    Grid definition for Land surface :
!               ----------------------------------
!
IF(lcpl_land)THEN  
  !
  zarea(:,1) = ug%G%XMESH_SIZE(:) * zmask_land(:)
  !0 = not masked ; 1 = masked
  WHERE(zarea(:,1)>0.0)
        imask(:,1) = 0
  ELSEWHERE
        imask(:,1) = 1
  ENDWHERE
  !
  CALL gather_and_write_mpi(zlon,zlon_tot)
  CALL gather_and_write_mpi(zlat,zlat_tot)
  CALL gather_and_write_mpi(zcorner_lon,zcorner_lon_tot)
  CALL gather_and_write_mpi(zcorner_lat,zcorner_lat_tot)
  CALL gather_and_write_mpi(zarea,zarea_tot)
  CALL gather_and_write_mpi(imask,imask_tot)
  !
  IF (nrank==npio) THEN
    CALL oasis_write_grid  (ysfx_land,u%NDIM_FULL,1,zlon_tot(:,:),zlat_tot(:,:))  
    CALL oasis_write_corner(ysfx_land,u%NDIM_FULL,1,inc,zcorner_lon_tot(:,:,:),zcorner_lat_tot(:,:,:))
    CALL oasis_write_area  (ysfx_land,u%NDIM_FULL,1,zarea_tot(:,:))
    CALL oasis_write_mask  (ysfx_land,u%NDIM_FULL,1,imask_tot(:,:))
  ENDIF
  !
ENDIF
!
!*       1.2    Grid definition for lake surface :
!               ----------------------------------
!
IF(lcpl_lake)THEN
  !
  zarea(:,1) = ug%G%XMESH_SIZE(:) * zmask_lake(:)
  !0 = not masked ; 1 = masked
  WHERE(zarea(:,1)>0.0)
        imask(:,1) = 0
  ELSEWHERE
        imask(:,1) = 1
  ENDWHERE
  !
  CALL gather_and_write_mpi(zlon,zlon_tot)
  CALL gather_and_write_mpi(zlat,zlat_tot)
  CALL gather_and_write_mpi(zcorner_lon,zcorner_lon_tot)
  CALL gather_and_write_mpi(zcorner_lat,zcorner_lat_tot)
  CALL gather_and_write_mpi(zarea,zarea_tot)
  CALL gather_and_write_mpi(imask,imask_tot)
  !
  IF (nrank==npio) THEN
    CALL oasis_write_grid  (ysfx_lake,u%NDIM_FULL,1,zlon_tot(:,:),zlat_tot(:,:))  
    CALL oasis_write_corner(ysfx_lake,u%NDIM_FULL,1,inc,zcorner_lon_tot(:,:,:),zcorner_lat_tot(:,:,:))
    CALL oasis_write_area  (ysfx_lake,u%NDIM_FULL,1,zarea_tot(:,:))
    CALL oasis_write_mask  (ysfx_lake,u%NDIM_FULL,1,imask_tot(:,:))
  ENDIF
  !
ENDIF
!
!*       1.3    Grid definition for sea/water :
!               -------------------------------
!
IF(lcpl_sea)THEN     
  !
  zarea(:,1) = ug%G%XMESH_SIZE(:) * zmask_sea(:)
  !0 = not masked ; 1 = masked
  WHERE(zarea(:,1)>0.0)
        imask(:,1) = 0
  ELSEWHERE
        imask(:,1) = 1
  ENDWHERE
  !
  CALL gather_and_write_mpi(zlon,zlon_tot)
  CALL gather_and_write_mpi(zlat,zlat_tot)
  CALL gather_and_write_mpi(zcorner_lon,zcorner_lon_tot)
  CALL gather_and_write_mpi(zcorner_lat,zcorner_lat_tot)
  CALL gather_and_write_mpi(zarea,zarea_tot)
  CALL gather_and_write_mpi(imask,imask_tot)
  !
  IF (nrank==npio) THEN
    CALL oasis_write_grid  (ysfx_sea,u%NDIM_FULL,1,zlon_tot(:,:),zlat_tot(:,:))  
    CALL oasis_write_corner(ysfx_sea,u%NDIM_FULL,1,inc,zcorner_lon_tot(:,:,:),zcorner_lat_tot(:,:,:))
    CALL oasis_write_area  (ysfx_sea,u%NDIM_FULL,1,zarea_tot(:,:))
    CALL oasis_write_mask  (ysfx_sea,u%NDIM_FULL,1,imask_tot(:,:))
  ENDIF
  !
ENDIF
!
IF (nrank==npio) CALL oasis_terminate_grids_writing()
!
 CALL oasis_enddef(ierr)
!
IF(ierr/=oasis_ok)THEN
   WRITE(iluout,*)'SFX_OASIS_PREP: OASIS enddef problem, err = ',ierr
   CALL abor1_sfx('SFX_OASIS_PREP: OASIS enddef problem')
ENDIF
!
!-------------------------------------------------------------------------------
#endif
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_PREP',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE sfx_oasis_prep