read_teb_greenroofn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_teb_greenroof_n (DTCO, U, IO, P, PEK, HPROGRAM,HPATCH)
!     ##################################
!
!!****  *READ_TEB_GREENROOF_n* - routine to initialise ISBA variables
!!                         
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!    based on read_teb_greenroofn
!!
!!    AUTHOR
!!    ------
!!      C. de Munck & A. Lemonsu *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2011
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_pe_t, isba_p_t
!
USE modd_co2v_par,          ONLY : xanfminit, xcondctmin
!                                
USE modd_surf_par,          ONLY : xundef
USE modd_snow_par,          ONLY : xz0sn
!
USE modi_read_surf
!
USE modi_read_gr_snow
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_type_dim_n
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(isba_p_t), INTENT(INOUT) :: P
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM ! calling program
 CHARACTER(LEN=3),  INTENT(IN)  :: HPATCH   ! current TEB patch identificator
!
!*       0.2   Declarations of local variables
!              -------------------------------
INTEGER           :: ILU                        ! 1D physical dimension
INTEGER           :: IRESP                           ! Error code after redding
INTEGER           :: IWORK                           ! Work integer
INTEGER           :: JLAYER, JNBIOMASS               ! loop counter on layers
 CHARACTER(LEN=30) :: YRECFM                          ! Name of the article to be read
 CHARACTER(LEN=4)  :: YLVL
REAL, DIMENSION(:),ALLOCATABLE  :: ZWORK             ! 2D array to write data in file
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_TEB_GREENROOF_N',0,zhook_handle)
yrecfm='SIZE_TOWN'
 CALL get_type_dim_n(dtco, u, 'TOWN  ',ilu)
!
!
!*       2.     Prognostic fields:
!               -----------------
!
ALLOCATE(zwork(ilu))
!
!* soil temperatures
!
iwork = io%NGROUND_LAYER
!
DO jlayer=1,iwork
  WRITE(ylvl,'(I2)') jlayer
  yrecfm=hpatch//'GR_TG'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  CALL read_surf(hprogram,yrecfm,zwork(:),iresp)
  pek%XTG(:,jlayer) = zwork
END DO
!
!
!* soil liquid water content
!
DO jlayer=1,io%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jlayer
  yrecfm=hpatch//'GR_WG'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  CALL read_surf(hprogram,yrecfm,zwork(:),iresp)
  pek%XWG(:,jlayer) = zwork
END DO
!
!* soil ice water content
!
DO jlayer=1,io%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jlayer
  yrecfm=hpatch//'GR_WGI'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  CALL read_surf(hprogram,yrecfm,zwork(:),iresp)
  pek%XWGI(:,jlayer) = zwork
END DO
!
!* water intercepted on leaves
!
yrecfm=hpatch//'GR_WR'
yrecfm=adjustl(yrecfm)
 CALL read_surf(hprogram,yrecfm,pek%XWR(:),iresp)
!
!* Leaf Area Index
!
IF (io%CPHOTO=='NIT' .OR. io%CPHOTO=='NCB') THEN
  yrecfm = hpatch//'GR_LAI'
  yrecfm=adjustl(yrecfm)
  CALL read_surf(hprogram,yrecfm,pek%XLAI(:),iresp)
END IF
!
!* snow mantel
!
 CALL read_gr_snow(hprogram,'GR',hpatch,ilu,ilu,p%NR_P,0,pek%TSNOW  )! IOO:GreenROOf 
!
!-------------------------------------------------------------------------------
!
!*       4.  Semi-prognostic variables
!            -------------------------
!
!* aerodynamical resistance
!
yrecfm = hpatch//'GR_RESA'
yrecfm=adjustl(yrecfm)
pek%XRESA(:) = 100.
 CALL read_surf(hprogram,yrecfm,pek%XRESA(:),iresp)
!
pek%XLE(:) = xundef
!
!* ISBA-AGS variables
!
IF (io%CPHOTO/='NON') THEN
  pek%XAN(:)    = 0.
  pek%XANDAY(:) = 0.
  pek%XANFM(:)  = xanfminit
  pek%XLE(:)    = 0.
END IF
!
IF (io%CPHOTO=='AST') THEN
  pek%XBIOMASS(:,:)      = 0.
  pek%XRESP_BIOMASS(:,:) = 0.
ELSEIF (io%CPHOTO=='NIT') THEN
  pek%XBIOMASS(:,:) = 0.
  DO jnbiomass=1,io%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    yrecfm=hpatch//'GR_BIOMA'//adjustl(ylvl(:len_trim(ylvl)))
    yrecfm=adjustl(yrecfm)
    CALL read_surf(hprogram,yrecfm,pek%XBIOMASS(:,jnbiomass),iresp)
  END DO

  pek%XRESP_BIOMASS(:,:) = 0.
  DO jnbiomass=2,io%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    yrecfm=hpatch//'GR_RESPI'//adjustl(ylvl(:len_trim(ylvl)))
    yrecfm=adjustl(yrecfm)
    CALL read_surf(hprogram,yrecfm,pek%XRESP_BIOMASS(:,jnbiomass),iresp)
  END DO
ENDIF
!
!
DEALLOCATE(zwork)
IF (lhook) CALL dr_hook('READ_TEB_GREENROOF_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_teb_greenroof_n