read_teb_gardenn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_teb_garden_n (DTCO, U, IO, P, PEK, HPROGRAM,HPATCH)
!     ##################################
!
!!****  *READ_TEB_GARDEN_n* - routine to initialise ISBA variables
!!                         
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003
!!
!!      READ_SURF for general reading : 08/2003 (S.Malardel)
!!      B. Decharme  2008    : Floodplains
!!      B. Decharme  01/2009 : Optional Arpege deep soil temperature read
!!      B. Decharme  09/2012 : suppress NWG_LAYER (parallelization problems)
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_diag_n, ONLY : diag_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_pe_t, isba_p_t
!
USE modd_co2v_par,       ONLY : xanfminit, xcondctmin
!                                
USE modd_surf_par,       ONLY : xundef, nundef
USE modd_snow_par,       ONLY : xz0sn
!
USE modi_read_surf
!
USE modi_init_io_surf_n
USE modi_set_surfex_filein
USE modi_end_io_surf_n
USE modi_town_presence
USE modi_allocate_gr_snow
USE modi_read_gr_snow
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_type_dim_n
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(isba_p_t), INTENT(INOUT) :: P
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM ! calling program
 CHARACTER(LEN=3),  INTENT(IN)  :: HPATCH   ! current TEB patch identificator
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
LOGICAL           :: GTOWN          ! town variables written in the file
INTEGER           :: IVERSION, IBUGFIX
INTEGER           :: ILU            ! 1D physical dimension
INTEGER           :: IRESP          ! Error code after redding
 CHARACTER(LEN=12) :: YRECFM         ! Name of the article to be read
 CHARACTER(LEN=4)  :: YLVL
REAL, DIMENSION(:),ALLOCATABLE  :: ZWORK      ! 2D array to write data in file
!
INTEGER :: IWORK   ! Work integer
!
INTEGER :: JL, JNBIOMASS  ! loop counter on layers
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_TEB_GARDEN_N',0,zhook_handle)
yrecfm='SIZE_TOWN'
 CALL get_type_dim_n(dtco, u, 'TOWN  ',ilu)
!
yrecfm='VERSION'
 CALL read_surf(hprogram,yrecfm,iversion,iresp)
!
yrecfm='BUG'
 CALL read_surf(hprogram,yrecfm,ibugfix,iresp)
!
!*       2.     Prognostic fields:
!               -----------------
!
ALLOCATE(zwork(ilu))
!* soil temperatures
!
iwork=io%NGROUND_LAYER
!
ALLOCATE(pek%XTG(ilu,iwork))
DO jl=1,iwork
  WRITE(ylvl,'(I2)') jl
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
    yrecfm=hpatch//'GD_TG'//adjustl(ylvl(:len_trim(ylvl)))
  ELSE
    yrecfm='TWN_TG'//adjustl(ylvl(:len_trim(ylvl)))
  ENDIF
  yrecfm=adjustl(yrecfm)  
  CALL read_surf(hprogram,yrecfm,zwork(:),iresp)
  pek%XTG(:,jl)=zwork
END DO
!
!
!* soil liquid water content
!
ALLOCATE(pek%XWG(ilu,iwork))
DO jl=1,io%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jl
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
    yrecfm=hpatch//'GD_WG'//adjustl(ylvl(:len_trim(ylvl)))
  ELSE
    yrecfm='TWN_WG'//adjustl(ylvl(:len_trim(ylvl)))
  ENDIF  
  yrecfm=adjustl(yrecfm)
  CALL read_surf(hprogram,yrecfm,zwork(:),iresp)
  pek%XWG(:,jl)=zwork
END DO
!
!* soil ice water content
!
ALLOCATE(pek%XWGI(ilu,iwork))
DO jl=1,io%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jl
! ajouter ici un test pour lire les anciens fichiers
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
    yrecfm=hpatch//'GD_WGI'//adjustl(ylvl(:len_trim(ylvl)))
  ELSE
    yrecfm='TWN_WGI'//adjustl(ylvl(:len_trim(ylvl)))
  ENDIF  
  yrecfm=adjustl(yrecfm)  
  CALL read_surf(hprogram,yrecfm,zwork(:),iresp)
  pek%XWGI(:,jl)=zwork
END DO
!
!* water intercepted on leaves
!
ALLOCATE(pek%XWR(ilu))
IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
  yrecfm=hpatch//'GD_WR'
ELSE
  yrecfm='TWN_WR'
ENDIF
yrecfm=adjustl(yrecfm)
 CALL read_surf(hprogram,yrecfm,pek%XWR(:),iresp)
!
!* Leaf Area Index (if prognostic)
!
IF (io%CPHOTO=='NIT' .OR. io%CPHOTO=='NCB') THEN
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
    yrecfm=hpatch//'GD_LAI'
  ELSE
    yrecfm='TWN_LAI'
  ENDIF        
  yrecfm=adjustl(yrecfm)
  CALL read_surf(hprogram,yrecfm,pek%XLAI(:),iresp)        
END IF
!
!* snow mantel
!
 CALL end_io_surf_n(hprogram)
 CALL set_surfex_filein(hprogram,'PGD ')
 CALL init_io_surf_n(dtco, u, hprogram,'FULL  ','SURF  ','READ ')
!
 CALL town_presence(hprogram,gtown)
!
 CALL end_io_surf_n(hprogram)
 CALL set_surfex_filein(hprogram,'PREP')
 CALL init_io_surf_n(dtco, u, hprogram,'TOWN  ','TEB   ','READ ')
!
IF (.NOT. gtown) THEN
  pek%TSNOW%SCHEME='1-L'
  CALL allocate_gr_snow(pek%TSNOW,ilu)
ELSE
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
    CALL read_gr_snow(hprogram,'GD',hpatch,ilu,ilu,p%NR_P,0,pek%TSNOW  )
  ELSE
    CALL read_gr_snow(hprogram,'GARD',hpatch,ilu,ilu,p%NR_P,0,pek%TSNOW  )
  ENDIF
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       4.  Semi-prognostic variables
!            -------------------------
!
!* aerodynamical resistance
!
ALLOCATE(pek%XRESA(ilu))
IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
  yrecfm=hpatch//'GD_RES'
ELSE
  yrecfm='TWN_RESA'
ENDIF
yrecfm=adjustl(yrecfm)
pek%XRESA(:) = 100.
 CALL read_surf(hprogram,yrecfm,pek%XRESA(:),iresp)
!
ALLOCATE(pek%XLE(ilu))
pek%XLE(:) = xundef
!
!* ISBA-AGS variables
!
IF (io%CPHOTO/='NON') THEN
  ALLOCATE(pek%XAN   (ilu)) 
  ALLOCATE(pek%XANDAY(ilu)) 
  ALLOCATE(pek%XANFM (ilu))
  pek%XAN(:)    = 0.
  pek%XANDAY(:) = 0.
  pek%XANFM(:)  = xanfminit
  pek%XLE(:)    = 0.
ELSE
  ALLOCATE(pek%XAN   (0)) 
  ALLOCATE(pek%XANDAY(0)) 
  ALLOCATE(pek%XANFM (0))
ENDIF
!
IF(io%CPHOTO/='NON') THEN
  ALLOCATE(pek%XBIOMASS         (ilu,io%NNBIOMASS))
  ALLOCATE(pek%XRESP_BIOMASS    (ilu,io%NNBIOMASS))
ELSE
  ALLOCATE(pek%XBIOMASS         (0,0))
  ALLOCATE(pek%XRESP_BIOMASS    (0,0))
END IF
!
IF (io%CPHOTO=='AST') THEN
  !
  pek%XBIOMASS(:,:) = 0.
  pek%XRESP_BIOMASS(:,:) = 0.
  !
ELSEIF (io%CPHOTO=='NIT' .OR. io%CPHOTO=='NCB') THEN
  !
  pek%XBIOMASS(:,:) = 0.
  DO jnbiomass=1,io%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
      yrecfm=hpatch//'GD_BIOMA'//adjustl(ylvl(:len_trim(ylvl)))
    ELSE
      yrecfm='TWN_BIOMASS'//adjustl(ylvl(:len_trim(ylvl)))
    ENDIF
    yrecfm=adjustl(yrecfm)
    CALL read_surf(hprogram,yrecfm,pek%XBIOMASS(:,jnbiomass),iresp)
  END DO

  pek%XRESP_BIOMASS(:,:) = 0.
  DO jnbiomass=2,io%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
      yrecfm=hpatch//'GD_RESPI'//adjustl(ylvl(:len_trim(ylvl)))
    ELSE
      yrecfm='TWN_RESP_BIOM'//adjustl(ylvl(:len_trim(ylvl)))
    ENDIF    
    yrecfm=adjustl(yrecfm)
    CALL read_surf(hprogram,yrecfm,pek%XRESP_BIOMASS(:,jnbiomass),iresp)
  END DO
  !
ENDIF
!
DEALLOCATE(zwork)
IF (lhook) CALL dr_hook('READ_TEB_GARDEN_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_teb_garden_n