read_prep_teb_greenroof_conf.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_prep_teb_greenroof_conf(HPROGRAM,HVAR,HFILE,HFILETYPE,HFILEPGD,HFILEPGDTYPE,   &
                                              HATMFILE,HATMFILETYPE,HPGDFILE,HPGDFILETYPE,KLUOUT,OUNIF)
!     #######################################################
!
!!****  *READ_PREP_TEB_GREENROOF_CONF* - routine to read the configuration for ISBA
!!                              fields preparation
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!    Based on "read_prep_teb_garden_conf"
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!     A. Lemonsu & C. de Munck
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2011
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modi_read_prep_surf_atm_conf
!
! AFAIRE : VERIFIER SI BESOIN DE MODN_PREP_TEB_GREENROOF
!USE MODN_PREP_TEB_GREENROOF
USE modd_prep_teb_greenroof, ONLY : cfile_gr, ctype, cfilepgd_gr, ctypepgd, &
                                    cfile_hug_gr, ctype_hug,         &
                                    cfile_hug_surf_gr, cfile_hug_root_gr, cfile_hug_deep_gr,  &
                                    xhug_surf_gr, xhug_root_gr, xhug_deep_gr,                 &
                                    xhugi_surf_gr, xhugi_root_gr, xhugi_deep_gr,              &
                                    cfile_tg_gr, ctype_tg,                              &
                                    cfile_tg_surf_gr, cfile_tg_root_gr, cfile_tg_deep_gr,     &
                                    xtg_surf_gr, xtg_root_gr, xtg_deep_gr 
!
USE modd_surf_par,   ONLY : xundef
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM    ! program calling
 CHARACTER(LEN=7),  INTENT(IN)  :: HVAR        ! variable treated
 CHARACTER(LEN=28), INTENT(OUT) :: HFILE       ! file name
 CHARACTER(LEN=6),  INTENT(OUT) :: HFILETYPE   ! file type
 CHARACTER(LEN=28), INTENT(OUT) :: HFILEPGD    ! file name
 CHARACTER(LEN=6),  INTENT(OUT) :: HFILEPGDTYPE! file type
 CHARACTER(LEN=28), INTENT(IN)  :: HATMFILE    ! atmospheric file name
 CHARACTER(LEN=6),  INTENT(IN)  :: HATMFILETYPE! atmospheric file type
 CHARACTER(LEN=28), INTENT(IN)  :: HPGDFILE    ! atmospheric file name
 CHARACTER(LEN=6),  INTENT(IN)  :: HPGDFILETYPE! atmospheric file type
INTEGER,           INTENT(IN)  :: KLUOUT      ! logical unit of output listing
LOGICAL,           INTENT(OUT) :: OUNIF       ! flag for prescribed uniform field

!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER           :: IRESP          ! IRESP  : return-code if a problem appears 
                                    ! at the open of the file in LFI  routines 
INTEGER           :: ILUNAM         ! Logical unit of namelist file
!
 CHARACTER(LEN=28) :: YNAMELIST      ! namelist file
!
LOGICAL           :: GFOUND         ! Return code when searching namelist
REAL(KIND=JPRB)   :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!
IF (lhook) CALL dr_hook('READ_PREP_TEB_GREENROOF_CONF',0,zhook_handle)
hfile    = '                         '
hfiletype    = '      '
!
hfilepgd = '                         '
hfilepgdtype = '      '
!
ounif    = .false.
!
!-------------------------------------------------------------------------------
!
!* choice of input file
!  --------------------
!
SELECT CASE (hvar)
  CASE ('WG     ','WGI    ')
    IF (len_trim(cfile_hug_gr)>0 .AND. len_trim(ctype_hug)>0 ) THEN
      hfile     = cfile_hug_gr
      hfiletype = ctype_hug
    END IF
  CASE ('TG     ')
    IF (len_trim(cfile_tg_gr)>0 .AND. len_trim(ctype_tg)>0 ) THEN
      hfile     = cfile_tg_gr
      hfiletype = ctype_tg
    END IF
END SELECT
!
IF (len_trim(hfile)==0 .AND. len_trim(cfile_gr)>0 .AND. len_trim(ctype)>0) THEN
  hfile     = cfile_gr
  hfiletype = ctype
END IF
!
IF (len_trim(hfilepgd)==0 .AND. len_trim(cfilepgd_gr)>0 .AND. len_trim(ctypepgd)>0) THEN
  hfilepgd     = cfilepgd_gr
  hfilepgdtype = ctypepgd
END IF
!
!! If no file name in the scheme namelist,
!! try to find a name in NAM_SURF_ATM
!
IF (len_trim(hfile)==0) THEN
!
 CALL read_prep_surf_atm_conf(hprogram,hfile,hfiletype,hfilepgd,hfilepgdtype,&
                             hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kluout)
!
END IF
!
!! If no file name in the scheme namelist,
!! nor in NAM_SURF_ATM, look if ascii input files are present
!
SELECT CASE (hvar)
  CASE ('WG     ','WGI    ')
    IF ( len_trim(ctype_hug )>0       .AND. &
           len_trim(cfile_hug_surf_gr)>0   .AND. &
           len_trim(cfile_hug_root_gr)>0   .AND. &
           len_trim(cfile_hug_deep_gr)>0         ) THEN  
       hfiletype = ctype_hug 
    END IF
    IF (hvar=='WGI    ' .AND. hfiletype=='ASCLLV') THEN
       ounif = .true.
       IF (lhook) CALL dr_hook('READ_PREP_TEB_GREENROOF_CONF',1,zhook_handle)
       RETURN
    ENDIF
  CASE ('TG     ')
    IF ( len_trim(ctype_tg )>0       .AND. &
           len_trim(cfile_tg_surf_gr)>0   .AND. &
           len_trim(cfile_tg_root_gr)>0   .AND. &
           len_trim(cfile_tg_deep_gr)>0         ) THEN  
       hfiletype = ctype_tg 
    END IF
END SELECT
!
!-------------------------------------------------------------------------------
!
!* Is an uniform field prescribed?
!  ------------------------------
!
SELECT CASE (hvar)
  CASE ('WG     ')
    ounif = (xhug_surf_gr/=xundef) .OR. (xhug_root_gr/=xundef) .OR. (xhug_deep_gr/=xundef)
    IF (ounif .AND. (xhug_surf_gr==xundef)) THEN
       WRITE(kluout,*)'ONE OF XHUG_SURF_GR, XHUG_ROOT_GR OR XHUG_DEEP_GR IS GIVEN'
       CALL abor1_sfx('READ_PREP_TEB_GREENROOF_CONF: XHUG_SURF_GR MUST BE SET')
    END IF
    IF (ounif .AND. (xhug_root_gr==xundef)) THEN
       WRITE(kluout,*)'ONE OF XHUG_SURF_GR, XHUG_ROOT_GR OR XHUG_DEEP_GR IS GIVEN'
       CALL abor1_sfx('READ_PREP_TEB_GREENROOF_CONF: XHUG_ROOT_GR MUST BE SET')
    END IF
    IF (ounif .AND. (xhug_deep_gr==xundef)) THEN
       WRITE(kluout,*)'ONE OF XHUG_SURF_GR, XHUG_ROOT_GR OR XHUG_DEEP_GR IS GIVEN'
       CALL abor1_sfx('READ_PREP_TEB_GREENROOF_CONF: XHUG_DEEP MUST BE SET')
    END IF
     !
      CASE ('WGI    ')
    ounif = (xhugi_surf_gr/=xundef) .OR. (xhugi_root_gr/=xundef) .OR. (xhugi_deep_gr/=xundef)
    IF (ounif .AND. (xhugi_surf_gr==xundef)) THEN
       WRITE(kluout,*)'ONE OF XHUGI_SURF_GR, XHUGI_ROOT_GR OR XHUGI_DEEP_GR IS GIVEN'
       CALL abor1_sfx('READ_PREP_TEB_GREENROOF_CONF: XHUGI_SURF_GR MUST BE SET')
    END IF
    IF (ounif .AND. (xhugi_root_gr==xundef)) THEN
       WRITE(kluout,*)'ONE OF XHUGI_SURF_GR, XHUGI_ROOT_GR OR XHUGI_DEEP_GR IS GIVEN'
       CALL abor1_sfx('READ_PREP_TEB_GREENROOF_CONF: XHUGI_ROOT_GR MUST BE SET')
    END IF
    IF (ounif .AND. (xhugi_deep_gr==xundef)) THEN
       WRITE(kluout,*)'ONE OF XHUGI_SURF_GR, XHUGI_ROOT_GR OR XHUGI_DEEP_GR IS GIVEN'
       CALL abor1_sfx('READ_PREP_TEB_GREENROOF_CONF: XHUGI_DEEP_GR MUST BE SET')
    END IF
    !
  CASE ('TG     ')
    ounif = (xtg_surf_gr/=xundef)  .OR. (xtg_root_gr/=xundef)  .OR. (xtg_deep_gr/=xundef)
    IF (ounif .AND. (xtg_surf_gr==xundef)) THEN
       WRITE(kluout,*)'ONE OF XTG_SURF_GR, XTG_ROOT_GR OR XTG_DEEP_GR IS GIVEN'
       CALL abor1_sfx('READ_PREP_TEB_GREENROOF_CONF: XTG_SURF_GR MUST BE SET')
    END IF
    IF (ounif .AND. (xtg_root_gr==xundef)) THEN
       WRITE(kluout,*)'ONE OF XTG_SURF_GR, XTG_ROOT_GR OR XTG_DEEP_GR IS GIVEN'
       CALL abor1_sfx('READ_PREP_TEB_GREENROOF_CONF: XTG_ROOT_GR MUST BE SET')
    END IF
    IF (ounif .AND. (xtg_deep_gr==xundef)) THEN
       WRITE(kluout,*)'ONE OF XTG_SURF_GR, XTG_ROOT_GR OR XTG_DEEP_GR IS GIVEN'
       CALL abor1_sfx('READ_PREP_TEB_GREENROOF_CONF: XTG_DEEP_GR MUST BE SET')
    END IF
    !
END SELECT
!
!-------------------------------------------------------------------------------
!
!* If no file and no uniform field is prescribed: default values used
!  ---------------------------------------------
!
IF (len_trim(hfiletype)==0 .AND. .NOT. ounif) THEN
  IF (hvar(1:2)/='TG' .AND. hvar(1:2)/='WG') THEN
    IF (hvar(1:2)/='ZS') WRITE(kluout,*) 'NO FILE FOR FIELD ',hvar, &
                                        ': UNIFORM DEFAULT FIELD IS PRESCRIBED'
    ounif = .true.
    IF (lhook) CALL dr_hook('READ_PREP_TEB_GREENROOF_CONF',1,zhook_handle)
    RETURN
  ELSE
    WRITE(kluout,*) 'AN INPUT FILE OR A UNIFORM VALUE IS REQUIRED FOR FIELD: ',hvar
    WRITE(kluout,*) 'Please complete NAM_PREP_TEB_GREENROOF'
    CALL abor1_sfx('READ_PREP_TEB_GREENROOF_CONF: AN INPUT FILE OR A UNIFORM VALUE IS REQUIRED FOR '//hvar)
  END IF
END IF
IF (lhook) CALL dr_hook('READ_PREP_TEB_GREENROOF_CONF',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_prep_teb_greenroof_conf