read_pgd_tebn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_pgd_teb_n (DTCO, U, UG, GCP, TOP, TG, &
                                 BOP, BDD, DTB, DTT, HPROGRAM)
!     #########################################
!
!!****  *READ_PGD_TEB_n* - reads TEB physiographic fields
!!                       
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
!
USE modd_teb_option_n, ONLY : teb_options_t
USE modd_sfx_grid_n, ONLY : grid_t
USE modd_bem_option_n, ONLY : bem_options_t
USE modd_bld_description_n, ONLY : bld_desc_t
USE modd_data_bem_n, ONLY : data_bem_t
USE modd_data_teb_n, ONLY : data_teb_t
!
USE modd_type_date_surf
!
USE modd_data_cover_par, ONLY : jpcover
!
!
USE mode_read_surf_cov, ONLY : read_surf_cov
!
USE modi_read_surf
USE modi_pack_init
USE modi_read_pgd_teb_par_n
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_type_dim_n
!
USE modi_read_lecoclimap
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
!
TYPE(teb_options_t), INTENT(INOUT) :: TOP
TYPE(grid_t), INTENT(INOUT) :: TG
TYPE(bem_options_t), INTENT(INOUT) :: BOP
TYPE(bld_desc_t), INTENT(INOUT) :: BDD
TYPE(data_bem_t), INTENT(INOUT) :: DTB
TYPE(data_teb_t), INTENT(INOUT) :: DTT
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM ! calling program
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
 CHARACTER(LEN=12) :: YRECFM         ! Name of the article to be read
INTEGER           :: IVERSION
INTEGER           :: IBUGFIX
INTEGER           :: IRESP          ! Error code after redding
!
LOGICAL :: GECOSG
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_PGD_TEB_N',0,zhook_handle)
yrecfm='SIZE_TOWN'
 CALL get_type_dim_n(dtco, u, 'TOWN  ',tg%NDIM)
!
!*       2.     Other dimension initializations:
!               --------------------------------
!
 CALL read_surf(hprogram,'VERSION',iversion,iresp)
 CALL read_surf(hprogram,'BUG',ibugfix,iresp)
!
!* number of TEB patches
!
IF (iversion<7 .OR. iversion==7 .AND. ibugfix<=2) THEN
  top%NTEB_PATCH=1
ELSE
  yrecfm='TEB_PATCH'
  CALL read_surf(hprogram,yrecfm,top%NTEB_PATCH,iresp)
END IF
!
!* number of road and roof layers
!
yrecfm='ROAD_LAYER'
 CALL read_surf( hprogram,yrecfm,top%NROAD_LAYER,iresp)

yrecfm='ROOF_LAYER'
 CALL read_surf(hprogram,yrecfm,top%NROOF_LAYER,iresp)

yrecfm='WALL_LAYER'
 CALL read_surf(hprogram,yrecfm,top%NWALL_LAYER,iresp)
!
!
!* type of averaging for Buildings (to allow ascendant compatibility)
!* type of Building Energy Model
!
IF (iversion<7 .OR.( iversion==7 .AND. ibugfix<=2)) THEN
  top%CBLD_ATYPE='ARI'
  top%CBEM = 'DEF'
ELSE
  yrecfm='BLD_ATYPE'
  CALL read_surf(hprogram,yrecfm,top%CBLD_ATYPE,iresp)
  yrecfm='BEM'
  CALL read_surf(hprogram,yrecfm,top%CBEM,iresp)
END IF
!
IF (top%CBEM=="BEM") THEN
  yrecfm='FLOOR_LAYER'
  CALL read_surf(hprogram,yrecfm,bop%NFLOOR_LAYER,iresp)
  yrecfm='COOL_COIL'
  CALL read_surf(hprogram,yrecfm,bop%CCOOL_COIL,iresp)
  yrecfm='HEAT_COIL'
  CALL read_surf(hprogram,yrecfm,bop%CHEAT_COIL,iresp)
  yrecfm='AUTOSIZE'
  CALL read_surf(hprogram,yrecfm,bop%LAUTOSIZE,iresp)
ENDIF
!
!* Case of urban green roofs
!
IF (top%LGARDEN) THEN
  IF (iversion<7 .OR.( iversion==7 .AND. ibugfix<=2)) THEN
    top%LGREENROOF = .false.
  ELSE
    yrecfm='LGREENROOF'
    CALL read_surf(hprogram,yrecfm,top%LGREENROOF,iresp)
  END IF
!
!* Case of urban hydrology
!
  IF (iversion<7 .OR.( iversion==7 .AND. ibugfix<=3)) THEN
    top%LHYDRO = .false.
  ELSE
    yrecfm='LURBAN_HYDRO'
    CALL read_surf(hprogram,yrecfm,top%LHYDRO,iresp)
  END IF
ENDIF
!
!* Solar panels
!
IF (iversion<7 .OR.( iversion==7 .AND. ibugfix<=3)) THEN
  top%LSOLAR_PANEL = .false.
ELSE
  yrecfm='SOLAR_PANEL'
  CALL read_surf(hprogram,yrecfm,top%LSOLAR_PANEL,iresp)
END IF
!
!
!
!*       3.     Physiographic data fields:
!               -------------------------
!
!* cover classes
!
ALLOCATE(top%LCOVER(jpcover))
ALLOCATE(top%XZS(tg%NDIM))
ALLOCATE(tg%XLAT       (tg%NDIM))
ALLOCATE(tg%XLON       (tg%NDIM))
ALLOCATE(tg%XMESH_SIZE (tg%NDIM))
 CALL pack_init(dtco,u,ug,hprogram,'TOWN  ',tg, top%LCOVER,top%XCOVER,top%XZS )
!
!-------------------------------------------------------------------------------
!
!*       4.     Physiographic data fields not to be computed by ecoclimap
!               ---------------------------------------------------------
!
 CALL read_lecoclimap(hprogram,top%LECOCLIMAP,gecosg)
!
 CALL read_pgd_teb_par_n(dtco, u, gcp, bdd, dtb, dtt, tg%NDIM, top, &
                         hprogram,tg%NDIM,'-')
!
IF (lhook) CALL dr_hook('READ_PGD_TEB_N',1,zhook_handle)
!
!------------------------------------------------------------------------------
!
END SUBROUTINE read_pgd_teb_n