read_pgd_teb_gardenn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_pgd_teb_garden_n (OCH_BIO_FLUX, DTCO, DTV, GB, U, &
                                        IO, K, KDIM, TOP, HPROGRAM,KVERSION,KBUGFIX)
!     #########################################
!
!!****  *READ_PGD_TEB_GARDEN_n* - routine to initialise ISBA physiographic variables 
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!!      P. Le Moigne  12/2004 : add type of photosynthesis
!!      B. Decharme      2008 : add XWDRAIN
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_data_cover_n, ONLY : data_cover_t
!
USE modd_data_isba_n, ONLY : data_isba_t
USE modd_gr_biog_n, ONLY : gr_biog_t
!
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_k_t
!
USE modd_teb_option_n, ONLY : teb_options_t
!
USE modd_surf_par,        ONLY : xundef
USE modd_isba_par,        ONLY : xoptimgrid
!
USE modi_read_pgd_teb_garden_par_n
USE modi_read_surf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_type_dim_n
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
LOGICAL, INTENT(IN) :: OCH_BIO_FLUX
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(data_isba_t), INTENT(INOUT) :: DTV
TYPE(gr_biog_t), INTENT(INOUT) :: GB
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(isba_k_t), INTENT(INOUT) :: K
INTEGER, INTENT(INOUT) :: KDIM
TYPE(teb_options_t), INTENT(INOUT) :: TOP
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM ! calling program
INTEGER,           INTENT(IN)  :: KVERSION ! version of SURFEX of the file being read
INTEGER,           INTENT(IN)  :: KBUGFIX
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER           :: IRESP          ! Error code after redding
!
 CHARACTER(LEN=12) :: YRECFM         ! Name of the article to be read
!
INTEGER           :: JLAYER         ! loop counter on layers
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_PGD_TEB_GARDEN_N',0,zhook_handle)
yrecfm='SIZE_TOWN'
 CALL get_type_dim_n(dtco, u, 'TOWN  ',kdim)
!
!
!* clay fraction : attention, seul un niveau est present dans le fichier
!* on rempli tout les niveaux de  XCLAY avec les valeurs du fichiers
!
yrecfm='TWN_CLAY'
IF (kversion>7 .OR. kversion==7 .AND. kbugfix>=3) yrecfm='GD_CLAY'
 CALL read_surf(hprogram,yrecfm,k%XCLAY(:,1),iresp)
DO jlayer=2,io%NGROUND_LAYER
  k%XCLAY(:,jlayer)=k%XCLAY(:,1)
END DO
!
!* sand fraction
!
yrecfm='TWN_SAND'
IF (kversion>7 .OR. kversion==7 .AND. kbugfix>=3) yrecfm='GD_SAND'
 CALL read_surf(hprogram,yrecfm,k%XSAND(:,1),iresp)
DO jlayer=2,io%NGROUND_LAYER
  k%XSAND(:,jlayer)=k%XSAND(:,1)
END DO
!
!* orographic runoff coefficient
!
yrecfm='TWN_RUNOFFB'
IF (kversion>7 .OR. kversion==7 .AND. kbugfix>=3) yrecfm='GD_RUNOFFB'
 CALL read_surf(hprogram,yrecfm,k%XRUNOFFB,iresp)
!
!* subgrid drainage coefficient
!
IF (kversion<=3) THEN
  k%XWDRAIN = 0.
ELSE
  yrecfm='TWN_WDRAIN'
  IF (kversion>7 .OR. kversion==7 .AND. kbugfix>=3) yrecfm='GD_WDRAIN'
  CALL read_surf(hprogram,yrecfm,k%XWDRAIN,iresp)
ENDIF
!
!-------------------------------------------------------------------------------
!
!* biogenic chemical emissions
!
IF (och_bio_flux) THEN
  ALLOCATE(gb%XISOPOT(kdim))
  yrecfm='E_ISOPOT'
  CALL read_surf(hprogram,yrecfm,gb%XISOPOT,iresp)
  !
  ALLOCATE(gb%XMONOPOT(kdim))
  yrecfm='E_MONOPOT'
  CALL read_surf(hprogram,yrecfm,gb%XMONOPOT,iresp)
ELSE
  ALLOCATE(gb%XISOPOT (0))
  ALLOCATE(gb%XMONOPOT(0))
END IF
!
!-------------------------------------------------------------------------------
!
!*       4.     Physiographic data fields not to be computed by ecoclimap
!               ---------------------------------------------------------
!
IF (kversion>=7) THEN
  yrecfm='PAR_GARDEN'
  CALL read_surf(hprogram,yrecfm,io%LPAR,iresp)
ELSEIF (.NOT.top%LECOCLIMAP) THEN
  io%LPAR = .true.
ELSE
  io%LPAR = .false.
ENDIF
!
io%LECOCLIMAP = (.NOT. io%LPAR)
!
ALLOCATE(dtv%LDATA_LAI        (1))
ALLOCATE(dtv%LDATA_VEG        (1))
ALLOCATE(dtv%LDATA_Z0         (1))
ALLOCATE(dtv%LDATA_EMIS       (1))
ALLOCATE(dtv%LDATA_ALBNIR_VEG (1))
ALLOCATE(dtv%LDATA_ALBVIS_VEG (1))
ALLOCATE(dtv%LDATA_ALBUV_VEG  (1))
ALLOCATE(dtv%LDATA_ALBNIR_SOIL(1))
ALLOCATE(dtv%LDATA_ALBVIS_SOIL(1))
ALLOCATE(dtv%LDATA_ALBUV_SOIL (1))
!
IF (.NOT.io%LPAR) THEN
  dtv%LDATA_LAI        = .false.
  dtv%LDATA_VEG        = .false.
  dtv%LDATA_Z0         = .false.
  dtv%LDATA_EMIS       = .false.
  dtv%LDATA_ALBNIR_VEG = .false.
  dtv%LDATA_ALBVIS_VEG = .false.
  dtv%LDATA_ALBUV_VEG  = .false.
  dtv%LDATA_ALBNIR_SOIL= .false.
  dtv%LDATA_ALBVIS_SOIL= .false.
  dtv%LDATA_ALBUV_SOIL = .false.
ELSE
  dtv%LDATA_LAI        = .true.
  dtv%LDATA_VEG        = .true.
  dtv%LDATA_Z0         = .true.
  dtv%LDATA_EMIS       = .true.
  dtv%LDATA_ALBNIR_VEG = .true.
  dtv%LDATA_ALBVIS_VEG = .true.
  dtv%LDATA_ALBUV_VEG  = .true.
  dtv%LDATA_ALBNIR_SOIL= .true.
  dtv%LDATA_ALBVIS_SOIL= .true.
  dtv%LDATA_ALBUV_SOIL = .true.        
ENDIF
!
IF (io%LPAR) CALL read_pgd_teb_garden_par_n(dtv, io, kdim, hprogram)
!
IF (lhook) CALL dr_hook('READ_PGD_TEB_GARDEN_N',1,zhook_handle)
!
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_pgd_teb_garden_n