read_nam_grid_lonlatval.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ################################################################
      SUBROUTINE read_nam_grid_lonlatval(PGRID_FULL_PAR,KDIM_FULL,HPROGRAM,KGRID_PAR,KL,PGRID_PAR,HDIR)
!     ################################################################
!
!!****  *READ_NAM_GRID_LONLATVAL* - routine to read in namelist the horizontal grid
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      E. Martin   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2007 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_surfex_mpi, ONLY : nrank, nsize_task
!
USE mode_pos_surf
!
USE modi_open_namelist
USE modi_close_namelist
USE modi_get_luout
!
USE mode_gridtype_lonlatval
USE modi_read_and_send_mpi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
REAL, DIMENSION(:), POINTER :: PGRID_FULL_PAR
INTEGER, INTENT(IN) :: KDIM_FULL
!
 CHARACTER(LEN=6),           INTENT(IN)    :: HPROGRAM   ! calling program
INTEGER,                    INTENT(INOUT) :: KGRID_PAR  ! size of PGRID_PAR
INTEGER,                    INTENT(OUT)   :: KL         ! number of points
REAL, DIMENSION(KGRID_PAR), INTENT(OUT)   :: PGRID_PAR  ! parameters defining this grid
 CHARACTER(LEN=1), INTENT(IN) :: HDIR
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: ILUOUT ! output listing logical unit
INTEGER :: ILUNAM ! namelist file  logical unit
!
REAL, DIMENSION(:),   ALLOCATABLE :: ZX, ZX0       ! X conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: ZY, ZY0       ! Y conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: ZDX, ZDX0      ! X grid mesh size
REAL, DIMENSION(:),   ALLOCATABLE :: ZDY, ZDY0      ! Y grid mesh size
!
!*       0.3   Declarations of namelist
!              ------------------------
!
INTEGER :: NPOINTS  ! number of points
REAL, DIMENSION(100000) :: XX  ! X coordinate of grid mesh center (in meters)
REAL, DIMENSION(100000) :: XY  ! Y coordinate of grid mesh center (in meters)
REAL, DIMENSION(100000) :: XDX ! X mesh size (in meters)
REAL, DIMENSION(100000) :: XDY ! Y mesh size (in meters)
!
REAL, DIMENSION(:), POINTER :: ZGRID_PAR
!
LOGICAL :: GFOUND
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
NAMELIST/nam_lonlatval/npoints,xx,xy,xdx,xdy
!
!------------------------------------------------------------------------------
!
!*       1.    opening of namelist
! 
IF (lhook) CALL dr_hook('READ_NAM_GRID_LONLATVAL',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
IF (hdir/='H') THEN
  !
  CALL open_namelist(hprogram,ilunam)
  !
  !---------------------------------------------------------------------------
  !
  !*       2.    Reading of projection parameters
  !              --------------------------------
  !
  CALL posnam(ilunam,'NAM_LONLATVAL',gfound,iluout)
  IF (gfound) READ(unit=ilunam,nml=nam_lonlatval)
  !
  !---------------------------------------------------------------------------
  CALL close_namelist(hprogram,ilunam)
  !---------------------------------------------------------------------------
  !
  !*       3.    Number of points
  !              ----------------
  !
  kl = npoints
  !
  !---------------------------------------------------------------------------
  !
  !*       3.    Array of X and Y coordinates
  !              ----------------------------
  !
  !
  ALLOCATE(zx(kl))
  ALLOCATE(zy(kl))
  zx(:) = xx(:kl)
  zy(:) = xy(:kl)
  !
  !---------------------------------------------------------------------------
  !
  !*       4.    Array of X and Y increments
  !              ---------------------------
  !
  ALLOCATE(zdx(kl))
  ALLOCATE(zdy(kl))
  zdx(:) = xdx(:kl)
  zdy(:) = xdy(:kl)
  !
ELSE
  !
  ALLOCATE(zx0(kdim_full),zy0(kdim_full),zdx0(kdim_full),zdy0(kdim_full))
  !
  CALL get_gridtype_lonlatval(pgrid_full_par,&
                              px=zx0,py=zy0,pdx=zdx0,pdy=zdy0)
  !
  kl = nsize_task(nrank)
  ALLOCATE(zx(kl),zy(kl),zdx(kl),zdy(kl))
  !
  CALL read_and_send_mpi(zx0,zx)
  CALL read_and_send_mpi(zy0,zy)
  CALL read_and_send_mpi(zdx0,zdx)
  CALL read_and_send_mpi(zdy0,zdy)
  !
  DEALLOCATE(zx0,zy0,zdx0,zdy0)  
  !
ENDIF
!---------------------------------------------------------------------------
!
!*       8.    All this information stored into pointer PGRID_PAR
!              --------------------------------------------------
!
 CALL put_gridtype_lonlatval(zgrid_par,zx,zy,zdx,zdy)
!
!---------------------------------------------------------------------------
DEALLOCATE(zx)
DEALLOCATE(zy)
DEALLOCATE(zdx)
DEALLOCATE(zdy)
!---------------------------------------------------------------------------
!
!* 1st call : initializes dimension
!
IF (kgrid_par==0) THEN
  kgrid_par = SIZE(zgrid_par)
!
ELSE
!
!* 2nd call : initializes grid array
!
  pgrid_par(:) = 0.
  pgrid_par(:) = zgrid_par
END IF
!
DEALLOCATE(zgrid_par)
IF (lhook) CALL dr_hook('READ_NAM_GRID_LONLATVAL',1,zhook_handle)
!
!---------------------------------------------------------------------------
!
END SUBROUTINE read_nam_grid_lonlatval