read_nam_grid_lonlat_rot.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ################################################################
      SUBROUTINE read_nam_grid_lonlat_rot(PGRID_FULL_PAR,KDIM_FULL,HPROGRAM,KGRID_PAR,KL,PGRID_PAR,HDIR)
!     ################################################################
!
!!****  *READ_NAM_GRID_LONLAT_ROT* - routine to read in namelist the horizontal grid
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      P. Samuelsson   SMHI
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    12/2012 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_surfex_mpi, ONLY : nrank, nsize_task
!
USE mode_pos_surf
!
USE modi_open_namelist
USE modi_close_namelist
USE modi_get_luout
!
USE mode_gridtype_lonlat_rot
!
USE modi_read_and_send_mpi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
REAL, DIMENSION(:), POINTER :: PGRID_FULL_PAR
INTEGER, INTENT(IN) :: KDIM_FULL
!
 CHARACTER(LEN=6),           INTENT(IN)    :: HPROGRAM   ! calling program
INTEGER,                    INTENT(INOUT) :: KGRID_PAR  ! size of PGRID_PAR
INTEGER,                    INTENT(OUT)   :: KL         ! number of points
REAL, DIMENSION(KGRID_PAR), INTENT(OUT)   :: PGRID_PAR  ! parameters defining this grid
 CHARACTER(LEN=1), INTENT(IN) :: HDIR
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: ILUOUT ! output listing logical unit
INTEGER :: ILUNAM ! namelist file  logical unit
!
REAL, DIMENSION(:), ALLOCATABLE :: ZLAT, ZLAT0 ! latitude  of all points
REAL, DIMENSION(:), ALLOCATABLE :: ZLON, ZLON0 ! longitude of all points
!
REAL,    DIMENSION(:), POINTER     :: ZGRID_PAR
!
LOGICAL :: GFOUND
!
!
!*       0.3   Declarations of namelist
!              ------------------------
!
REAL    :: XWEST   ! West longitude in rotated grid (degrees)
REAL    :: XSOUTH  ! South latitude in rotated grid  (degrees)
REAL    :: XDLON   ! Longitudal grid spacing  (degrees)
REAL    :: XDLAT   ! Latitudal grid spacing  (degrees)
REAL    :: XPOLON  ! Longitude of rotated pole (degrees)
REAL    :: XPOLAT  ! Latitude of rotated pole  (degrees)
INTEGER :: NLON    ! number of points in longitude
INTEGER :: NLAT    ! number of points in latitude
REAL(KIND=JPRB) :: ZHOOK_HANDLE
NAMELIST/nam_lonlat_rot/xwest,xsouth,xdlon,xdlat,xpolon,xpolat,nlon,nlat
!
!------------------------------------------------------------------------------
!
!*       1.    opening of namelist
! 
IF (lhook) CALL dr_hook('READ_NAM_GRID_LONLAT_ROT',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
IF (hdir/='H') THEN
  !
  CALL open_namelist(hprogram,ilunam)
  !
  !---------------------------------------------------------------------------
  !
  !*       2.    Reading of projection parameters
  !              --------------------------------
  !
  CALL posnam(ilunam,'NAM_LONLAT_ROT',gfound,iluout)
  IF (gfound) READ(unit=ilunam,nml=nam_lonlat_rot)
  !
  !---------------------------------------------------------------------------
  !
  !*       3.    Number of points
  !              ----------------
  !
  kl = nlon * nlat
  !
  !---------------------------------------------------------------------------
  CALL close_namelist(hprogram,ilunam)
  !---------------------------------------------------------------------------
  !
  !*       4.    All this information stored into pointer PGRID_PAR
  !              --------------------------------------------------
  !
  ALLOCATE(zlat(kl))
  ALLOCATE(zlon(kl))
  !
  CALL latlon_lonlat_rot(xwest,xsouth,xdlon,xdlat,xpolon,xpolat, &
                           nlon,nlat,zlon,zlat                   )  
  !
ELSE
  !
  ALLOCATE(zlon0(kdim_full),zlat0(kdim_full))
  !
  CALL get_gridtype_lonlat_rot(pgrid_full_par,pwest=xwest,psouth=xsouth,&
                       pdlon=xdlon,pdlat=xdlat,ppolon=xpolon,ppolat=xpolat,&
                       klon=nlon,klat=nlat,kl=kl,plon=zlon0,plat=zlat0)
  !
  ALLOCATE(zlon(kl),zlat(kl))
  !
  CALL read_and_send_mpi(zlon0,zlon)
  CALL read_and_send_mpi(zlat0,zlat)
  !
  DEALLOCATE(zlon0,zlat0)
  !
ENDIF
!
 CALL put_gridtype_lonlat_rot(zgrid_par,                                 &
                               xwest,xsouth,xdlon,xdlat,xpolon,xpolat,  &
                               nlon,nlat,kl,zlon,zlat                   )  
!
DEALLOCATE(zlat)
DEALLOCATE(zlon)
!
!---------------------------------------------------------------------------
!
!* 1st call : initializes dimension
!
IF (kgrid_par==0) THEN
  kgrid_par = SIZE(zgrid_par)
!
ELSE
!
!* 2nd call : initializes grid array
!
  pgrid_par(:) = 0.
  pgrid_par(:) = zgrid_par
END IF
!
DEALLOCATE(zgrid_par)
IF (lhook) CALL dr_hook('READ_NAM_GRID_LONLAT_ROT',1,zhook_handle)
!
!---------------------------------------------------------------------------
!
END SUBROUTINE read_nam_grid_lonlat_rot