read_latlon.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_latlon (UG, U, USS, &
                              HPROGRAM,HSCHEME,HSUBROUTINE,HFILENAME)
!     #########################################################
!
!!**** *READ_LATLON* reads a latlon file and call treatment subroutine
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    11/09/95
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
!
USE modd_pgd_grid,   ONLY : xmeshlength
!
USE modi_get_luout
USE modi_open_namelist
USE modi_close_namelist
USE modi_open_file
USE modi_close_file
USE modi_readhead
USE modi_ini_ssowork
USE modi_pt_by_pt_treatment
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
!
 CHARACTER(LEN=6),  INTENT(IN) :: HPROGRAM      ! Type of program
 CHARACTER(LEN=6),  INTENT(IN) :: HSCHEME       ! Scheme treated
 CHARACTER(LEN=6),  INTENT(IN) :: HSUBROUTINE   ! Name of the subroutine to call
 CHARACTER(LEN=28), INTENT(IN) :: HFILENAME     ! Name of the field file.
!
!*    0.2    Declaration of local variables read in the data file head
!            ---------------------------------------------------------
!
REAL    :: ZGLBLATMIN                 ! minimum latitude of data box in the file
REAL    :: ZGLBLONMIN                 ! minimum longitude of data box in the file
REAL    :: ZGLBLATMAX                 ! maximum latitude of data box in the file
REAL    :: ZGLBLONMAX                 ! maximum longitude of data box in the file
INTEGER :: INBLINE                    ! number of latitude rows (number of lines
INTEGER :: INBCOL                     ! number of longitude rows (number of columns)
REAL    :: ZNODATA                    ! value below which data are not considered
!
!*    0.3    Declaration of local variables
!            ------------------------------
!
INTEGER :: IFILE                      ! logical units
INTEGER :: ILUOUT                     ! output listing logical unit
INTEGER :: IERR                       ! return codes
!
INTEGER :: JLOOP, IFACT                ! loop index
 CHARACTER(LEN=100):: YSTRING          ! string
!
REAL    :: ZDLAT                      ! latitude mesh in the data file
REAL    :: ZDLON                      ! longitude mesh in the data file
INTEGER :: JLINE                      ! index of line
INTEGER :: JCOL                       ! index of column
!
REAL, DIMENSION(:), ALLOCATABLE :: ZVALUE ! value of a record of data points
REAL, DIMENSION(:), POINTER     :: ZLAT   ! latitude of data points
REAL, DIMENSION(:), POINTER     :: ZLON   ! longitude of data points
LOGICAL :: GCOMPRESS
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('READ_LATLON',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!*    1.     Openning of header
!            ------------------
!
 CALL open_namelist(hprogram,ifile,hfilename)
!
!----------------------------------------------------------------------------
!
!*    2.     Reading of the global field
!            ---------------------------
!
!*    2.1    Head of data file
!            -----------------
!
 CALL readhead(ifile,zglblatmin,zglblatmax,zglblonmin,zglblonmax, &
               inbline,inbcol,znodata,zdlat,zdlon,zlat,zlon,ierr,ifact,&
               gcompress)  
IF (ierr/=0) THEN
  CALL abor1_sfx('READ_LATLON: PROBLEM IN FILE HEADER')
END IF
!
!*    2.2    Closing of header
!            -----------------
!
 CALL close_namelist(hprogram,ifile)
!
!----------------------------------------------------------------------------
!
!*    3.     Adapt subgrid mesh to input file resolution
!            -------------------------------------------
!
IF (hsubroutine=='A_OROG') CALL ini_ssowork(xmeshlength,zdlat,zdlon)
!
!----------------------------------------------------------------------------
!
!*    4.     Openning of file
!            ----------------
!
 CALL open_file(hprogram,ifile,hfilename,'FORMATTED',haction='READ')
DO jloop=1,8
  READ(ifile,fmt='(A100)') ystring
END DO
!
!----------------------------------------------------------------------------
!
!*    5.     Allocation of array containing the data
!            ---------------------------------------
!
ALLOCATE(zvalue(inbcol))
!
!----------------------------------------------------------------------------
!
!*    6.     Loop on lines
!            -------------
!
DO jline=1,inbline
!
!----------------------------------------------------------------------------
!
!*    7.     Reading in the file
!            -------------------
!
  READ(ifile,fmt=*) zvalue(:)
!
!
!----------------------------------------------------------------------------
!
!*    8.     Loop on columns
!            ---------------
!
  DO jcol=1,inbcol

!-------------------------------------------------------------------------------
!
!*    9.     value not valid
!            ---------------
!
    IF (abs(zvalue(jcol)-znodata)<=1.e-10) cycle
!
!-------------------------------------------------------------------------------
!
!*   10.     Call to the adequate subroutine (point by point treatment)
!            ----------------------------------------------------------
!
    zvalue(:) = zvalue(:) / float(ifact)

    CALL pt_by_pt_treatment(ug, u, uss, &
                            iluout,zlat(jline:jline),zlon(jcol:jcol),zvalue(jcol:jcol),&            
                              hsubroutine                                              )  
!
!-------------------------------------------------------------------------------
  END DO
!-------------------------------------------------------------------------------
END DO
!-------------------------------------------------------------------------------
!
!*   11.     deallocations
!            -------------
!
DEALLOCATE(zlat)
DEALLOCATE(zlon)
DEALLOCATE(zvalue)
!
!-------------------------------------------------------------------------------
!
!*   12.     closes the file
!            ---------------
!
 CALL close_file(hprogram,ifile)
IF (lhook) CALL dr_hook('READ_LATLON',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_latlon