read_grid.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_grid (HPROGRAM,G,KRESP,PDIR)
!     #########################################
!
!!****  *READ_GRID* - routine to initialise the horizontal grid of a scheme
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
USE modd_sfx_grid_n, ONLY : grid_t
!
USE modi_get_luout
USE modi_read_surf
USE modi_latlon_grid
USE modi_read_gridtype
!
USE modd_assim, ONLY : lread_all, lassim
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM   ! calling program
TYPE(grid_t), INTENT(INOUT) :: G
INTEGER,            INTENT(OUT) :: KRESP      ! error return code
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: PDIR ! heading of main axis of grid compared to North (degrees)
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
LOGICAL :: GREAD_ALL
INTEGER :: ILUOUT
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!---------------------------------------------------------------------------
!
!*       1.    Reading of type of grid
!              -----------------------
!
IF (lhook) CALL dr_hook('READ_GRID',0,zhook_handle)
!
IF (lassim) THEN
  gread_all = lread_all
  lread_all = .true.
ENDIF
!
 CALL read_surf(hprogram,'GRID_TYPE',g%CGRID,kresp)
!
!---------------------------------------------------------------------------
!
!*       2.    Reading parameters of the grid
!              ------------------------------
!
 CALL read_gridtype(hprogram,g%CGRID,g%NGRID_PAR,SIZE(g%XLAT),.false.)
!
ALLOCATE(g%XGRID_PAR(g%NGRID_PAR))
 CALL read_gridtype(hprogram,g%CGRID,g%NGRID_PAR,SIZE(g%XLAT),.true.,g%XGRID_PAR,kresp)
!
!---------------------------------------------------------------------------
!
!*       3.    Latitude, longitude, mesh size
!              ------------------------------
!
 CALL get_luout(hprogram,iluout)
!
SELECT CASE (g%CGRID)
  CASE("NONE      ")
    IF (PRESENT(pdir)) pdir(:) = 0.
    !
    CALL read_surf(hprogram,'LON',      g%XLON,kresp)
    IF (kresp/=0 .AND. lhook) CALL dr_hook('READ_GRID',1,zhook_handle)
    IF (kresp/=0) RETURN
    CALL read_surf(hprogram,'LAT',      g%XLAT,kresp)
    IF (kresp/=0 .AND. lhook) CALL dr_hook('READ_GRID',1,zhook_handle)
    IF (kresp/=0) RETURN
    CALL read_surf(hprogram,'MESH_SIZE',g%XMESH_SIZE,kresp)
    IF (kresp/=0 .AND. lhook) CALL dr_hook('READ_GRID',1,zhook_handle)
    IF (kresp/=0) RETURN

  CASE DEFAULT
    IF (PRESENT(pdir)) THEN
      CALL latlon_grid(g,SIZE(g%XLAT),pdir)
    ELSE
      CALL latlon_grid(g,SIZE(g%XLAT))
    END IF

END SELECT
!
IF (lassim) lread_all = gread_all
!
IF (lhook) CALL dr_hook('READ_GRID',1,zhook_handle)
!
!---------------------------------------------------------------------------
!
END SUBROUTINE read_grid