read_dimlen.F90

Go to the documentation of this file.

!     ######
SUBROUTINE read_dimlen(KLUOUT,HFILE,HVAR,KDIM,KDIMLEN)
!#############################################################
!
USE modi_abort_trip
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
INTEGER,          INTENT(IN)       :: KLUOUT
 CHARACTER(LEN=*), INTENT(IN)       :: HFILE
 CHARACTER(LEN=*), INTENT(IN)       :: HVAR
INTEGER,          INTENT(IN)       :: KDIM
INTEGER, DIMENSION(KDIM), INTENT(OUT) :: KDIMLEN
!
!*      0.2   Declarations of local variables
!
INTEGER,DIMENSION(:),ALLOCATABLE :: IDIMIDS
!
 CHARACTER(LEN=NF90_MAX_NAME) :: YFNAME
 CHARACTER(LEN=NF90_MAX_NAME) :: YVAR
!
INTEGER :: IFILE_ID
INTEGER :: IVAR_ID
INTEGER :: INDIMS
INTEGER :: IRET
INTEGER :: JRET
INTEGER :: JDIM
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('READ_DIMLEN',0,zhook_handle)
!
yfname = hfile(1:len_trim(hfile))   
yvar   = hvar(1:len_trim(hvar))
!
iret=nf90_open(yfname,nf90_nowrite,ifile_id)
IF(iret/=nf90_noerr)THEN
  WRITE(kluout,*)'READ_DIMLEN : error in NF90_OPEN'
  CALL abort_trip('READ_DIMLEN : error in NF90_OPEN')
ENDIF
!
iret=nf90_inq_varid(ifile_id,yvar,ivar_id)
IF(iret/=nf90_noerr)THEN
  WRITE(kluout,*)'READ_DIMLEN : error in NF90_INQ_VARID'
  CALL abort_trip('READ_DIMLEN : error in NF90_INQ_VARID')
ENDIF
!
iret=nf90_inquire_variable(ifile_id,ivar_id,ndims=indims)
IF(iret/=nf90_noerr)THEN
  WRITE(kluout,*)'READ_DIMLEN : error in NF90_INQ_VARNDIMS'
  CALL abort_trip('READ_DIMLEN : error in NF90_INQ_VARNDIMS')
ENDIF
!
IF(indims/=kdim)THEN
  WRITE(kluout,*)'READ_DIMLEN from TRIP_CONF90_FRC :'
  WRITE(kluout,*)'Size read (',indims,') /= size expected (',kdim,')'
  CALL abort_trip('READ_DIMLEN : sizes not good')
ENDIF  
!
ALLOCATE(idimids(kdim))
!
iret=nf90_inquire_variable(ifile_id,ivar_id,dimids=idimids(1:indims))
IF(iret/=nf90_noerr)THEN
  WRITE(kluout,*)'READ_DIMLEN : error in NF90_INQ_VARDIMID'
  CALL abort_trip('READ_DIMLEN : error in NF90_INQ_VARDIMID')
ENDIF
!
DO jdim=1,indims
   iret=nf90_inquire_dimension(ifile_id,idimids(jdim),len=kdimlen(jdim))
   IF(iret/=nf90_noerr)THEN
      WRITE(kluout,*)'READ_DIMLEN : error in NF90_INQ_DIMLEN for dimension ',jdim
      CALL abort_trip('READ_DIMLEN : error in NF90_INQ_DIMLEN')
   ENDIF
ENDDO
!
iret=nf90_close(ifile_id)
IF(iret/=nf90_noerr)THEN
  WRITE(kluout,*)'READ_DIMLEN : error in NF90_CLOSE'
  CALL abort_trip('READ_DIMLEN : error in NF90_CLOSE')
ENDIF
!
DEALLOCATE(idimids)
!
IF (lhook) CALL dr_hook('READ_DIMLEN',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE read_dimlen