put_zsn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ########################################
      SUBROUTINE put_zs_n (F, IS, S, U, TOP, W, HPROGRAM,KI,PZS)
!     ########################################
!
!!****  *PUT_ZS_n* - routine to modify surface oropgraphy of each tile using atmospheric
!                    model orography
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original     01/2004
!!      P. Le Moigne 05/2007: write model orography over each tile
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_flake_n, ONLY : flake_t
USE modd_isba_n, ONLY : isba_s_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_teb_option_n, ONLY : teb_options_t
USE modd_watflux_n, ONLY : watflux_t
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_put_zs_inland_water_n
!
USE modi_put_zs_nature_n
!
USE modi_put_zs_sea_n
!
USE modi_put_zs_surf_atm_n
!
USE modi_put_zs_town_n
USE modi_get_size_full_n
USE modi_get_1d_mask
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(flake_t), INTENT(INOUT) :: F
TYPE(isba_s_t), INTENT(INOUT) :: IS
TYPE(seaflux_t), INTENT(INOUT) :: S
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(teb_options_t), INTENT(INOUT) :: TOP
TYPE(watflux_t), INTENT(INOUT) :: W
!
 CHARACTER(LEN=6),    INTENT(IN)  :: HPROGRAM
INTEGER,             INTENT(IN)  :: KI      ! horizontal dim. of cover
REAL, DIMENSION(KI), INTENT(IN)  :: PZS     ! orography
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('PUT_ZS_N',0,zhook_handle)
!
!*       1. Full surface
!           ------------
!
 CALL put_zs_surf_atm_n(u, hprogram,ki,pzs)
!
!*       2. inland water
!           ------------
!
IF (u%NSIZE_WATER > 0 .AND. u%CWATER/='NONE' .AND. u%CWATER/='FLUX') CALL pack_zs(u%NSIZE_WATER,u%NR_WATER,'W')
!
!*       3. nature
!           ------
!
IF (u%NSIZE_NATURE > 0 .AND. u%CNATURE/='NONE' .AND. u%CNATURE/='FLUX') CALL pack_zs(u%NSIZE_NATURE,u%NR_NATURE,'N')
!
!*       4. town
!           ----
!
IF (u%NSIZE_TOWN > 0 .AND. u%CTOWN/='NONE' .AND. u%CTOWN/='FLUX') CALL pack_zs(u%NSIZE_TOWN,u%NR_TOWN,'T')
!
!        5.sea
!           ----
!
IF (u%NSIZE_SEA > 0 .AND. u%CSEA/='NONE' .AND. u%CSEA/='FLUX') CALL pack_zs(u%NSIZE_SEA,u%NR_SEA,'S')
!
IF (lhook) CALL dr_hook('PUT_ZS_N',1,zhook_handle)
!
CONTAINS
!=======================================================================================
SUBROUTINE pack_zs(KSIZE,KMASK,YTYPE)
!
INTEGER, INTENT(IN)               :: KSIZE
INTEGER, POINTER, DIMENSION(:)    :: KMASK
 CHARACTER(LEN=1), INTENT(IN)      :: YTYPE
!
REAL, DIMENSION(KSIZE) :: ZP_ZS
INTEGER :: JJ, ISIZE_FULL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
! input arguments:
!
IF (lhook) CALL dr_hook('PUT_ZS_N:PACK_ZS',0,zhook_handle)
!
IF (.NOT.ASSOCIATED(kmask)) THEN
  ALLOCATE(kmask(ksize))
  IF (ksize>0) THEN
    CALL get_size_full_n(hprogram,u%NDIM_FULL,u%NSIZE_FULL,isize_full)
    u%NSIZE_FULL = isize_full
    IF (ytype=='W') THEN
      CALL get_1d_mask( ksize, u%NSIZE_FULL, u%XWATER, kmask)
    ELSEIF (ytype=='N') THEN
      CALL get_1d_mask( ksize, u%NSIZE_FULL, u%XNATURE, kmask)
    ELSEIF (ytype=='T') THEN
      CALL get_1d_mask( ksize, u%NSIZE_FULL, u%XTOWN, kmask)
    ELSEIF (ytype=='S') THEN
      CALL get_1d_mask( ksize, u%NSIZE_FULL, u%XSEA, kmask)
    ENDIF     
  ENDIF
ENDIF
!
DO jj=1,ksize
  zp_zs(jj)         = pzs(kmask(jj))
ENDDO
!
IF (ytype=='W') THEN
  CALL put_zs_inland_water_n(f, w, hprogram,ksize,zp_zs,u%CWATER)
ELSEIF (ytype=='N') THEN
  CALL put_zs_nature_n(is, hprogram,ksize,zp_zs)
ELSEIF (ytype=='T') THEN
  CALL put_zs_town_n(top, hprogram,ksize,zp_zs)
ELSEIF (ytype=='S') THEN
  CALL put_zs_sea_n(s, hprogram,ksize,zp_zs)
ENDIF
!
IF (lhook) CALL dr_hook('PUT_ZS_N:PACK_ZS',1,zhook_handle)
!
END SUBROUTINE pack_zs
!=======================================================================================
!
END SUBROUTINE put_zs_n