put_sfxcpln.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE put_sfxcpl_n (F, IM, S, U, W, &
                         HPROGRAM,KI,KSW,PSW_BANDS,PZENITH, &
                        PLAND_WTD,PLAND_FWTD,PLAND_FFLOOD, &
                        PLAND_PIFLOOD,PSEA_SST,PSEA_UCU,   &
                        PSEA_VCU,PSEAICE_SIT,PSEAICE_CVR,  &
                        PSEAICE_ALB,PTSRAD,                &
                        PDIR_ALB,PSCA_ALB,PEMIS,PTSURF     )  
!     #################################################################################################
!
!!****  *PUT_SFXCPL_n* - routine to modify some variables in surfex from information coming
!                        from an ocean and/or a river routing model (but already on Surfex grid)
!
!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme      *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    08/2009
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_flake_n, ONLY : flake_t
USE modd_surfex_n, ONLY : isba_model_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_watflux_n, ONLY : watflux_t
!
USE modd_surf_par,   ONLY : xundef
!
USE modn_sfx_oasis,  ONLY : lwater
USE modd_sfx_oasis,  ONLY : lcpl_sea, lcpl_seaice, &
                            lcpl_land, lcpl_gw,    &
                            lcpl_flood
!                          
USE modi_get_luout
!
USE modi_abor1_sfx
USE modi_put_sfx_land
USE modi_put_sfx_sea
USE modi_update_esm_surf_atm_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(flake_t), INTENT(INOUT) :: F
TYPE(isba_model_t), INTENT(INOUT) :: IM
TYPE(seaflux_t), INTENT(INOUT) :: S
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(watflux_t), INTENT(INOUT) :: W
!
 CHARACTER(LEN=6),        INTENT(IN)  :: HPROGRAM
INTEGER,                 INTENT(IN)  :: KI      ! number of points
INTEGER,                 INTENT(IN)  :: KSW     ! number of bands
!
REAL, DIMENSION(KI),      INTENT(IN) :: PZENITH
REAL, DIMENSION(KSW),     INTENT(IN) :: PSW_BANDS ! mean wavelength of each shortwave band (m)
!
REAL, DIMENSION(KI),      INTENT(IN) :: PLAND_WTD     ! Land water table depth (m)
REAL, DIMENSION(KI),      INTENT(IN) :: PLAND_FWTD    ! Land grid-cell fraction of water table rise (-)
REAL, DIMENSION(KI),      INTENT(IN) :: PLAND_FFLOOD  ! Land Floodplains fraction (-)
REAL, DIMENSION(KI),      INTENT(IN) :: PLAND_PIFLOOD ! Land Potential flood infiltration (kg/m2)
!
REAL, DIMENSION(KI),      INTENT(IN) :: PSEA_SST ! Sea surface temperature (K)
REAL, DIMENSION(KI),      INTENT(IN) :: PSEA_UCU ! Sea u-current stress (Pa)
REAL, DIMENSION(KI),      INTENT(IN) :: PSEA_VCU ! Sea v-current stress (Pa)
!
REAL, DIMENSION(KI),      INTENT(IN) :: PSEAICE_SIT ! Sea-ice Temperature (K)
REAL, DIMENSION(KI),      INTENT(IN) :: PSEAICE_CVR ! Sea-ice cover (-)
REAL, DIMENSION(KI),      INTENT(IN) :: PSEAICE_ALB ! Sea-ice albedo (-)
!
REAL, DIMENSION(KI),     INTENT(OUT) :: PTSRAD   ! Total radiative temperature see by the atmosphere
REAL, DIMENSION(KI),     INTENT(OUT) :: PTSURF   ! Total surface temperature see by the atmosphere
REAL, DIMENSION(KI),     INTENT(OUT) :: PEMIS    ! Total emissivity see by the atmosphere
REAL, DIMENSION(KI,KSW), INTENT(OUT) :: PDIR_ALB ! Total direct albedo see by the atmosphere
REAL, DIMENSION(KI,KSW), INTENT(OUT) :: PSCA_ALB ! Total diffus albedo see by the atmosphere
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
!
INTEGER :: ILU, ILUOUT
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('PUT_SFXCL_N',0,zhook_handle)
!
 CALL get_luout(hprogram,iluout)
!-------------------------------------------------------------------------------
!
! Global argument
!
IF(ki/=u%NSIZE_FULL)THEN
  WRITE(iluout,*) 'size of field from the coupler :', ki
  WRITE(iluout,*) 'size of field in SURFEX        :', u%NSIZE_FULL
  CALL abor1_sfx('PUT_SFXCPL_N: VECTOR SIZE NOT CORRECT FOR COUPLING')
ENDIF
!
!-------------------------------------------------------------------------------
! Put variable over land tile
!-------------------------------------------------------------------------------
!
IF(lcpl_land)THEN
  CALL put_sfx_land(im%O, im%S, im%K, im%NK, im%NP, u, iluout, lcpl_gw, lcpl_flood, &
                    pland_wtd(:), pland_fwtd(:),pland_fflood(:),pland_piflood(:))        
ENDIF
!
!-------------------------------------------------------------------------------
! Put variable over sea and/or water tile
!-------------------------------------------------------------------------------
!
IF(lcpl_sea)THEN
!
  CALL put_sfx_sea(s, u, w, iluout,lcpl_seaice,lwater,psea_sst(:),psea_ucu(:), &
                   psea_vcu(:),pseaice_sit(:),pseaice_cvr(:),pseaice_alb(:) )
!
ENDIF
!
!-------------------------------------------------------------------------------
! Update radiative properties at time t+1 for radiative scheme
!-------------------------------------------------------------------------------
!
IF(lcpl_sea.OR.lcpl_flood)THEN
  CALL update_esm_surf_atm_n(f, im, s, u, w, hprogram, ki, ksw, pzenith, psw_bands,  &
                             ptsrad, pdir_alb, psca_alb, pemis, ptsurf )
ENDIF
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('PUT_SFXCL_N',1,zhook_handle)
!
!
END SUBROUTINE put_sfxcpl_n