prep_snow_grib.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_snow_grib(HPROGRAM,HSURF,HFILE,KLUOUT,KLAYER,PFIELD)
!     #################################################################################
!
!!****  *PREP_SNOW_GRIB* - prepares snow field from operational GRIB
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original     01/2004
!!      C. Ardilouze 06/2013 read snow albedo and density (for Erai-land)
!!------------------------------------------------------------------
!
!
USE mode_read_grib
!
USE modd_type_date_surf
!
USE modd_prep_snow,      ONLY : ngrid_level, xgrid_snow
USE modd_surf_par,       ONLY : xundef
USE modd_grid_grib,      ONLY : cgrib_file, nni, cinmodel
USE modd_snow_par,       ONLY : xansmin, xansmax, xrhosmax
USE modd_csts,           ONLY : xtt
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
 CHARACTER(LEN=6),   INTENT(IN)    :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=10),   INTENT(IN)   :: HSURF     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)    :: HFILE     ! name of file
INTEGER,            INTENT(IN)    :: KLUOUT    ! logical unit of output listing
INTEGER,            INTENT(IN)    :: KLAYER    ! Number of layer of output snow scheme
REAL,DIMENSION(:,:,:), POINTER    :: PFIELD    ! field to interpolate horizontally
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(:)  , POINTER   :: ZMASK => null()          ! Land mask
REAL, DIMENSION(:),   POINTER   :: ZFIELD1D => null()       ! field read
REAL, DIMENSION(:),   POINTER   :: ZHEAT => null()          ! heat in snow
REAL, DIMENSION(:),   POINTER   :: ZRHO => null()          ! density of snow
INTEGER                         :: JVEGTYPE       ! loop counter on vegtypes
INTEGER                         :: JLAYER         ! loop on snow fine grid
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!
!*      1.     Reading of grid
!              ---------------
!
IF (lhook) CALL dr_hook('PREP_SNOW_GRIB',0,zhook_handle)
!
IF (trim(hfile).NE.cgrib_file) cgrib_file=""
!
 CALL read_grib_land_mask(hfile,kluout,cinmodel,zmask)
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading of the physical field for urban areas
!              ---------------------------------------------
!
IF (hsurf(7:8)=='RO') THEN
  ! 
  SELECT CASE(hsurf(1:3))
    CASE('DEP')
      ALLOCATE(pfield(nni,1,1))
    CASE('ALB','WWW')
      ALLOCATE(pfield(nni,1,1))
    CASE('HEA','RHO')
      ALLOCATE(pfield(nni,1,1))
  END SELECT
  !
  pfield(:,:,:) = 0.
!
!-------------------------------------------------------------------------------------
!
!*      3.     Reading of the physical field for vegetated areas
!              -------------------------------------------------
!
ELSE
!
  SELECT CASE(hsurf(1:3))
!
!*      3.1    Total snow content (kg/m2)
!
  CASE('WWW')
     CALL read_grib_snow_veg_and_depth(hfile,kluout,cinmodel,zmask,psnv=zfield1d)
     !
     ALLOCATE(pfield(SIZE(zfield1d),1,1))
     pfield(:,1,1)=zfield1d(:)
     DEALLOCATE(zfield1d)
!
!
!*      3.2    Total snow depth (m)
!
  CASE('DEP')
     CALL read_grib_snow_veg_and_depth(hfile,kluout,cinmodel,zmask,psnvd=zfield1d)
     !
     ALLOCATE(pfield(SIZE(zfield1d),1,1))
     pfield(:,1,1)=zfield1d(:)
     DEALLOCATE(zfield1d)
!
!
!*      3.3    Profile of heat in the snow
!
  CASE('HEA')
     !* read temperature
     CALL read_grib_ts(hfile,kluout,cinmodel,zmask,zfield1d)
     WHERE (zfield1d/=xundef) zfield1d(:) = min(zfield1d,xtt)
     !
     ALLOCATE(pfield(SIZE(zfield1d),1,1))
     pfield(:,1,1)=zfield1d(:)
     DEALLOCATE(zfield1d)
!
!*      3.4    Albedo
!
  CASE('ALB')    
    CALL read_grib_snow_alb(hfile,kluout,cinmodel,zmask,zfield1d)      
    ALLOCATE(pfield(SIZE(zfield1d),1,1))
    pfield(:,1,1)=zfield1d(:)
    DEALLOCATE(zfield1d)
!
!*      3.5    Density
!
  CASE('RHO')    
    CALL read_grib_snow_den(hfile,kluout,cinmodel,zmask,zfield1d)      
    ALLOCATE(pfield(SIZE(zfield1d),1,1))
    pfield(:,1,1)=zfield1d(:)
    DEALLOCATE(zfield1d)
!
!*      3.6    SG1: initial grain is partially rounded
!
  CASE('SG1')
    ALLOCATE(pfield(nni,1,1))
    pfield = -20
!
!*      3.7    SG2: initial grain is partially rounded
!
  CASE('SG2')
    ALLOCATE(pfield(nni,1,1))
    pfield = 80
!
!*      3.8    AGE: snow is 3-days old
!
  CASE('AGE')
    ALLOCATE(pfield(nni,1,1))
    pfield = 3
!
!*      3.9    HIS: 0 by default
!
  CASE('HIS')
    ALLOCATE(pfield(nni,1,1))
    pfield = 0
!
  END SELECT
!
END IF
!
DEALLOCATE(zmask)
!
!-------------------------------------------------------------------------------------
!
!*      4.     Interpolation method
!              --------------------
!
IF (lhook) CALL dr_hook('PREP_SNOW_GRIB',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
END SUBROUTINE prep_snow_grib