prep_ocean_ascllv.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #################################################################################
SUBROUTINE prep_ocean_ascllv (DTCO, UG, U, HPROGRAM,HSURF,HFILE, KLUOUT,PFIELD)
!     #################################################################################
!
!!****  *PREP_OCEAN_ASCLLDV* - prepares oceanic fields from personal data in ascii
!!                            formed as lat,lon, depth, value
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!   Read the input file which must be ascii typed, lat,lon,depth, value
!!   Version 1: 
!!              The data must be on the same grid as the pgd and on the same
!!              vertical grid as prescribed in oceanvergrid.f90
!!              NDEPTH= a definirtn nlev=NOCKMAX (modd_ocean_gridn)
!!              
!!  Version 2: (not done yet)
!!              - dummy or namlist for nb verticals levels
!!              - file prescribing the vertical grid 
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     P. PEYRILLE
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2011
!!      J.Escobar   11/2013   Add USE MODI_ABOR1_SFX and USE MODI_GET_SURF_MASK_N
!!------------------------------------------------------------------
!
USE modd_surfex_mpi, ONLY : nproc, nindex, nnum, ncomm, npio, nrank
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_prep,       ONLY : cinterp_type
USE modd_pgd_grid,       ONLY : nl,llatlonmask,cgrid,xgrid_par,ngrid_par
USE modd_ocean_grid , ONLY : nockmax
USE modd_pgdwork,        ONLY : catype
!
USE modi_open_file
USE modi_close_file
USE modi_get_luout
USE modi_get_latlonmask_n
USE modi_pack_same_rank
USE modi_abor1_sfx
USE modi_get_surf_mask_n
!
USE modi_get_type_dim_n
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1    declarations of arguments
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: HSURF     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: HFILE     ! file name
INTEGER,            INTENT(IN)  :: KLUOUT    ! output listing logical unit
!CHARACTER(LEN=28),  INTENT(IN), OPTIONAL   :: HNCVARNAME!var to read 
REAL, POINTER, DIMENSION(:,:,:)   :: PFIELD    ! field to interpolate horizontally
!
!
!*      0.2    declarations of local variables
REAL,DIMENSION(:), ALLOCATABLE :: ZLAT
REAL,DIMENSION(:), ALLOCATABLE :: ZLON
REAL,DIMENSION(:), ALLOCATABLE :: ZDEPTH
REAL,DIMENSION(:,:,:), ALLOCATABLE :: ZFIELD
REAL,DIMENSION(:,:,:,:), ALLOCATABLE :: ZFIELDR
!
INTEGER, DIMENSION(0:NPROC-1) :: INB
!
INTEGER :: IL
INTEGER :: IGLB  ! logical unit
INTEGER :: IDIM, ILU
INTEGER :: JI,JK
INTEGER :: INFOMPI, JJ
!
INTEGER, DIMENSION(:), POINTER :: IMASK  ! mask for packing from complete field to nature field
 CHARACTER(LEN=6)    :: YMASK
REAL(KIND=JPRB) :: ZHOOK_HANDLE

!-------------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('PREP_OCEAN_ASCLLV',0,zhook_handle)
!
IF (.NOT.ALLOCATED(nnum)) THEN
  ALLOCATE(nnum(u%NDIM_FULL))
  IF (nrank/=npio) THEN
    IF (ALLOCATED(nindex)) DEALLOCATE(nindex)
    ALLOCATE(nindex(u%NDIM_FULL))
  ENDIF  
  IF (nrank==npio) THEN
    inb(:) = 0
    DO jj=1,u%NDIM_FULL
      inb(nindex(jj)) = inb(nindex(jj))+1
      nnum(jj) = inb(nindex(jj))
    ENDDO
  ENDIF
  IF (nproc>1) THEN
#ifdef SFX_MPI          
    CALL mpi_bcast(nindex,SIZE(nindex)*kind(nindex)/4,mpi_integer,npio,ncomm,infompi)
    CALL mpi_bcast(nnum,SIZE(nnum)*kind(nnum)/4,mpi_integer,npio,ncomm,infompi)
    CALL mpi_bcast(ug%NGRID_FULL_PAR,kind(ug%NGRID_FULL_PAR)/4,mpi_integer,npio,ncomm,infompi)
#endif
    IF (nrank/=npio) ALLOCATE(ug%XGRID_FULL_PAR(ug%NGRID_FULL_PAR))
#ifdef SFX_MPI    
    CALL mpi_bcast(ug%XGRID_FULL_PAR,&
      SIZE(ug%XGRID_FULL_PAR)*kind(ug%XGRID_FULL_PAR)/4,mpi_real,npio,ncomm,infompi)   
#endif 
  ENDIF
ENDIF
!
catype = 'ARI'
!
!*      1.    get full dimension of grid
 CALL get_type_dim_n(dtco, u, 'FULL  ',nl)
!*      2.    get Ocean dimension
!
 CALL get_type_dim_n(dtco, u, 'SEA   ',il)

!*      3.    get grid informations known over full grid
!
 CALL get_latlonmask_n(ug, llatlonmask,cgrid,xgrid_par,ngrid_par)
!
!!

WRITE(kluout,*) "==================================== "
WRITE(kluout,*) "Control print in prep_ocean_ascllv "
WRITE(kluout,*) "NL, NOCKMAX", nl,nockmax

ALLOCATE(zlat(nl))
ALLOCATE(zlon(nl))
ALLOCATE(zdepth(nockmax))

ALLOCATE(zfieldr(nl,nockmax,4, 1))
ALLOCATE(zfield(nl,nockmax, 1))


WRITE(kluout,*) "ZFIELDR",shape(zfieldr)
WRITE(kluout,*) "File name used in ocean ascllv", hfile

WRITE(kluout,*)  "USURF= " , hsurf
WRITE(kluout,*) "NL (dim)=", nl
WRITE(kluout,*) "IL (dim)=", il
!
!*      2.     Reading of field
!              ----------------
 CALL open_file(hprogram,iglb,hfile,'FORMATTED',haction='READ')
!

DO ji=1,nl
  DO jk=1,nockmax
    READ(iglb,*,end=99) zlat(ji),zlon(ji), zdepth(jk), & 
    zfieldr(ji,jk,1,1), zfieldr(ji,jk,2,1),zfieldr(ji,jk,3,1), & 
    zfieldr(ji,jk,4,1)
  END DO
END DO


 
!      3. Close the file

99 CONTINUE
 CALL close_file (hprogram,iglb)

WRITE(kluout,*) minval(zfieldr), maxval(zfieldr)

!
! Get the correct varaibles
SELECT CASE (hsurf)
  CASE('TEMP_OC') 
  zfield(:,:,1) = zfieldr(:,:,1,1)
  CASE('SALT_OC') 
  zfield(:,:,1) = zfieldr(:,:,2,1)
  CASE('UCUR_OC') 
  zfield(:,:,1) = zfieldr(:,:,3,1)
  CASE('VCUR_OC') 
  zfield(:,:,1) = zfieldr(:,:,4,1)
END SELECT



!*      3.     Interpolation method
!              --------------------
!
cinterp_type='NONE  '
!CINTERP_TYPE='HORIBL'
!

ymask = 'SEA   '
 CALL get_type_dim_n(dtco, u, ymask,idim)
WRITE(kluout,*) "IDIM (dim sea) =", idim

ALLOCATE(pfield(1:idim,1:SIZE(zfield,2),1:SIZE(zfield,3)))

IF (idim/=SIZE(pfield,1)) THEN
   WRITE(kluout,*)'Wrong dimension of MASK: ',idim,SIZE(pfield)
   CALL abor1_sfx('PGD_FIELD: WRONG DIMENSION OF MASK')
ENDIF

ALLOCATE(imask(idim))
ilu=0
 CALL get_surf_mask_n(dtco, u, ymask,idim,imask,ilu,kluout)
DO jk=1,nockmax
  CALL pack_same_rank(imask,zfield(:,jk,1),pfield(:,jk,1))
END DO
DEALLOCATE(imask)

!*      4.     Deallocations
!              -------------
!
IF (ALLOCATED(zlon       ))  DEALLOCATE(zlon  )
IF (ALLOCATED(zlat       ))  DEALLOCATE(zlat  )
IF (ALLOCATED(zdepth      ))  DEALLOCATE(zdepth )
IF (ALLOCATED(zfield      ))  DEALLOCATE(zfield )
IF (ALLOCATED(zfieldr     ))  DEALLOCATE(zfieldr )
!
DEALLOCATE(nnum)
IF (nrank/=npio) THEN
  DEALLOCATE(nindex,ug%XGRID_FULL_PAR)
  ALLOCATE(nindex(0))
ENDIF
!
IF (lhook) CALL dr_hook('PREP_OCEAN_ASCLLV',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
END SUBROUTINE prep_ocean_ascllv