prep_isba_extern.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_isba_extern (DTCO, IO, U, GCP, &
                             HPROGRAM,HSURF,HFILE,HFILETYPE,HFILEPGD,HFILEPGDTYPE,KLUOUT,PFIELD,OKEY)
!     #################################################################################
!
!!****  *PREP_ISBA_EXTERN* - initializes ISBA fields from operational GRIB
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      B. Decharme  04/2014, external init with FA files
!!------------------------------------------------------------------
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
!
USE modd_surfex_mpi, ONLY : nrank,npio
USE modd_prep,           ONLY : cingrid_type, cinterp_type
USE modd_prep_isba,      ONLY : xgrid_soil, xwr_def
USE modd_surf_par,       ONLY : xundef
!
USE mode_read_extern
!
USE modi_make_choice_array
USE modi_prep_grid_extern
USE modi_read_surf
USE modi_interp_grid_nat
USE modi_open_aux_io_surf
USE modi_close_aux_io_surf
!
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: HSURF     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: HFILE     ! name of file
 CHARACTER(LEN=6),   INTENT(IN)  :: HFILETYPE ! type of input file
 CHARACTER(LEN=28),  INTENT(IN)  :: HFILEPGD     ! name of file
 CHARACTER(LEN=6),   INTENT(IN)  :: HFILEPGDTYPE ! type of input file
INTEGER,            INTENT(IN)   :: KLUOUT    ! logical unit of output listing
REAL,DIMENSION(:,:,:), POINTER   :: PFIELD    ! field to interpolate horizontally (on final soil grid)
LOGICAL, OPTIONAL,  INTENT(INOUT):: OKEY
!
!*      0.2    declarations of local variables
!
 CHARACTER(LEN=12) :: YRECFM         ! Name of the article to be read
INTEGER           :: IRESP          ! reading return code
INTEGER           :: INI            ! total 1D dimension
INTEGER           :: IPATCH         ! number of patch
LOGICAL           :: GGLACIER
 CHARACTER(LEN=3)  :: YPHOTO
!
REAL, DIMENSION(:,:,:), POINTER     :: ZFIELD=>null()         ! field read on initial MNH vertical soil grid, all patches
REAL, DIMENSION(:,:,:), POINTER     :: ZD=>null()            ! layer thicknesses
REAL, DIMENSION(:), ALLOCATABLE     :: ZMASK
INTEGER                             :: JP, JL       ! loop counter for patch
INTEGER :: IVERSION, IBUGFIX
LOGICAL :: GDIM
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!------------------------------------------------------------------------------
!
!*      1.     Preparation of IO for reading in the file
!              -----------------------------------------
!
!* Note that all points are read, even those without physical meaning.
!  These points will not be used during the horizontal interpolation step.
!  Their value must be defined as XUNDEF.
!
IF (lhook) CALL dr_hook('PREP_ISBA_EXTERN',0,zhook_handle)
!
!------------------------------------------------------------------------------
!
!*      2.     Reading of grid
!              ---------------
!
 CALL open_aux_io_surf(hfilepgd,hfilepgdtype,'FULL  ')
!
 CALL prep_grid_extern(gcp,hfilepgdtype,kluout,cingrid_type,cinterp_type,ini)
!
!
yrecfm='VERSION'
 CALL read_surf(hfilepgdtype,yrecfm,iversion,iresp)
!
IF (nrank/=npio) ini = 0
!
ALLOCATE(zmask(ini))
IF (iversion>=7) THEN 
  yrecfm='FRAC_NATURE'
  CALL read_surf(hfilepgdtype,yrecfm,zmask,iresp,hdir='A')
ELSE
  zmask(:) = 1.
ENDIF
!
 CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
!
 CALL open_aux_io_surf(hfile,hfiletype,'FULL  ')
yrecfm='VERSION'
 CALL read_surf(hfiletype,yrecfm,iversion,iresp)
yrecfm='BUG'
 CALL read_surf(hfiletype,yrecfm,ibugfix,iresp)
gdim = (iversion>8 .OR. iversion==8 .AND. ibugfix>0)
IF (gdim) CALL read_surf(hfiletype,'SPLIT_PATCH',gdim,iresp)
 CALL close_aux_io_surf(hfile,hfiletype)
!
IF (nrank/=npio) ini = 0
!
!---------------------------------------------------------------------------------------
!
!*      3.     Transformation into physical quantity to be interpolated
!              --------------------------------------------------------
!
SELECT CASE(hsurf)
!
!*     3.      Orography
!              ---------
!
  CASE('ZS     ')
    ALLOCATE(pfield(ini,1,1))
    pfield(:,:,:) = xundef
    yrecfm='ZS'
    CALL open_aux_io_surf(hfilepgd,hfilepgdtype,'FULL  ')
    CALL read_surf(hfilepgdtype,yrecfm,pfield(:,1,1),iresp,hdir='E')
    CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
!
!--------------------------------------------------------------------------
!
!
!*      3.1    Profile of temperature, water or ice in the soil
!
  CASE('TG    ','WG    ','WGI   ')
!* reading of the profile and its depth definition
     CALL read_extern_isba(u, dtco, gcp, io, hfile,hfiletype,hfilepgd,hfilepgdtype,&
                           kluout,ini,hsurf,hsurf,zfield,zd,okey)
! 
    IF (ini>0) THEN
      ALLOCATE(pfield(SIZE(zfield,1),SIZE(xgrid_soil),SIZE(zfield,3)))
      DO jp=1,SIZE(zfield,3)
        CALL interp_grid_nat(zd(:,:,jp),zfield(:,:,jp),xgrid_soil,pfield(:,:,jp))
      END DO
      !
      DO jp=1,SIZE(pfield,3)
        DO jl=1,SIZE(pfield,2)
          WHERE (zmask(:)==0.) pfield(:,jl,jp) = xundef
        ENDDO
      ENDDO
      !
    ENDIF
    !
    DEALLOCATE(zfield)
    DEALLOCATE(zd)
!
!--------------------------------------------------------------------------
!
!*      3.4    Water content intercepted on leaves, LAI
!
  CASE('WR     ')    
     !* number of tiles
     CALL open_aux_io_surf(hfilepgd,hfilepgdtype,'NATURE')
     yrecfm='PATCH_NUMBER'
     CALL read_surf(hfilepgdtype,yrecfm,ipatch,iresp,hdir='-')
     CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
     ALLOCATE(pfield(ini,1,ipatch))
     pfield(:,:,:) = xundef
     yrecfm = 'WR'
     CALL open_aux_io_surf(hfile,hfiletype,'NATURE')
     CALL make_choice_array(hfiletype, ipatch, gdim, yrecfm, pfield(:,1,:),hdir='E')
     CALL close_aux_io_surf(hfile,hfiletype)
     DO jp=1,SIZE(pfield,3)
       WHERE (zmask(:)==0.) pfield(:,1,jp) = xundef
     ENDDO     
!
  CASE('LAI    ')
     !* number of tiles
     CALL open_aux_io_surf(hfilepgd,hfilepgdtype,'NATURE')
     yrecfm='PATCH_NUMBER'
     CALL read_surf(hfilepgdtype,yrecfm,ipatch,iresp,hdir='-')
     yrecfm='PHOTO'
     CALL read_surf(hfilepgdtype,yrecfm,yphoto,iresp,hdir='-')     
     CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
     ALLOCATE(pfield(ini,1,ipatch))
     pfield(:,:,:) = xundef     
     IF (yphoto=='NIT' .OR. yphoto=='NCB') THEN
       CALL open_aux_io_surf(hfile,hfiletype,'NATURE')
       yrecfm = 'LAI'
       CALL make_choice_array(hfiletype, ipatch, gdim, yrecfm, pfield(:,1,:),hdir='E')
       CALL close_aux_io_surf(hfile,hfiletype)
       DO jp=1,SIZE(pfield,3)
         WHERE (zmask(:)==0.) pfield(:,1,jp) = xundef
       ENDDO       
     ENDIF
!
  CASE('ICE_STO') 
      !* number of tiles
     CALL open_aux_io_surf(hfilepgd,hfilepgdtype,'NATURE')
     yrecfm='PATCH_NUMBER'
     CALL read_surf(hfilepgdtype,yrecfm,ipatch,iresp,hdir='-')
     CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
     CALL open_aux_io_surf(hfile,hfiletype,'NATURE')
     yrecfm='GLACIER'
     CALL read_surf(hfiletype,yrecfm,gglacier,iresp,hdir='-')
     ALLOCATE(pfield(ini,1,ipatch))
     pfield(:,:,:) = 0.0     
     IF(gglacier)THEN
       yrecfm = 'ICE_STO'
       CALL make_choice_array(hfiletype, ipatch, gdim, yrecfm, pfield(:,1,:),hdir='E')
     ENDIF
     CALL close_aux_io_surf(hfile,hfiletype)
     DO jp=1,SIZE(pfield,3)
       WHERE (zmask(:)==0.) pfield(:,1,jp) = xundef
     ENDDO     
!
  CASE DEFAULT
    CALL abor1_sfx('PREP_ISBA_EXTERN: '//trim(hsurf)//" initialization not implemented !")
!
END SELECT
!
DEALLOCATE(zmask)
!
!---------------------------------------------------------------------------
!
!*      6.     End of IO
!              ---------
!
IF (lhook) CALL dr_hook('PREP_ISBA_EXTERN',1,zhook_handle)
!
!---------------------------------------------------------------------------
!---------------------------------------------------------------------------
END SUBROUTINE prep_isba_extern