prep_isba_cc_extern.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_isba_cc_extern (GCP,HPROGRAM,HSURF,HFILE,HFILETYPE,HFILEPGD,HFILEPGDTYPE,KLUOUT,PFIELD,OPREP_AGS)
!     #################################################################################
!
!!****  *PREP_ISBA_CC_EXTERN* - initializes ISBA-CC fields from external isba field
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      B. Decharme  04/2014, external init with FA files
!!------------------------------------------------------------------
!
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
!
USE modd_surfex_mpi, ONLY : nrank, npio
USE modd_prep,           ONLY : cingrid_type, cinterp_type
USE modd_surf_par,       ONLY : xundef
!
USE modi_prep_grid_extern
USE modi_read_surf
USE modi_open_aux_io_surf
USE modi_close_aux_io_surf
USE modi_make_choice_array
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=8),   INTENT(IN)  :: HSURF     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: HFILE     ! name of file
 CHARACTER(LEN=6),   INTENT(IN)  :: HFILETYPE ! type of input file
 CHARACTER(LEN=28),  INTENT(IN)  :: HFILEPGD     ! name of file
 CHARACTER(LEN=6),   INTENT(IN)  :: HFILEPGDTYPE ! type of input file
INTEGER,             INTENT(IN)  :: KLUOUT    ! logical unit of output listing
REAL,DIMENSION(:,:,:), POINTER   :: PFIELD    ! field to interpolate horizontally (on final soil grid)
LOGICAL,            INTENT(INOUT):: OPREP_AGS
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(:), ALLOCATABLE     :: ZMASK
!
 CHARACTER(LEN=12) :: YRECFM         ! Name of the article to be read
INTEGER           :: IRESP          ! reading return code
INTEGER           :: INI            ! total 1D dimension
INTEGER           :: IPATCH         ! number of patch
 CHARACTER(LEN=3)  :: YPHOTO
 CHARACTER(LEN=3)  :: YRESPSL
 CHARACTER(LEN=4)  :: YLVL
!
INTEGER           :: JNBIOMASS             ! loop counter
INTEGER           :: JNLITTER              ! loop counter
INTEGER           :: JNLITTLEVS            ! loop counter
INTEGER           :: JNSOILCARB            ! loop counter
INTEGER           :: IVERSION, IBUGFIX     ! surface version
INTEGER           :: IWORK,INBIOMASS,INLITTER, &
                     INLITTLEVS,INSOILCARB, JP, JL
!
LOGICAL :: GDIM
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!------------------------------------------------------------------------------
!
!*      1.     Preparation of IO for reading in the file
!              -----------------------------------------
!
!* Note that all points are read, even those without physical meaning.
!  These points will not be used during the horizontal interpolation step.
!  Their value must be defined as XUNDEF.
!
IF (lhook) CALL dr_hook('PREP_ISBA_CC_EXTERN',0,zhook_handle)
!
!------------------------------------------------------------------------------
!
!*      2.     Reading of grid
!              ---------------
!
 CALL open_aux_io_surf(hfilepgd,hfilepgdtype,'FULL  ')
!
 CALL prep_grid_extern(gcp,hfilepgdtype,kluout,cingrid_type,cinterp_type,ini)
!
yrecfm='VERSION'
 CALL read_surf(hfilepgdtype,yrecfm,iversion,iresp)
!
ALLOCATE(zmask(ini))
IF (iversion>=7) THEN 
  yrecfm='FRAC_NATURE'
  CALL read_surf(hfilepgdtype,yrecfm,zmask,iresp,hdir='A')
ELSE
  zmask(:) = 1.
ENDIF
!
 CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
!
 CALL open_aux_io_surf(hfile,hfiletype,'FULL  ')
yrecfm='VERSION'
 CALL read_surf(hfilepgdtype,yrecfm,iversion,iresp)
yrecfm='BUG'
 CALL read_surf(hfiletype,yrecfm,ibugfix,iresp)
gdim = (iversion>8 .OR. iversion==8 .AND. ibugfix>0)
IF (gdim) CALL read_surf(hfiletype,'SPLIT_PATCH',gdim,iresp)
!
 CALL close_aux_io_surf(hfile,hfiletype)
!
IF (nrank/=npio) ini = 0
!
!---------------------------------------------------------------------------------------
!
!*      3.     Transformation into physical quantity to be interpolated
!              --------------------------------------------------------
!
 CALL open_aux_io_surf(hfilepgd,hfilepgdtype,'NATURE')
yrecfm='PHOTO'
 CALL read_surf(hfilepgdtype,yrecfm,yphoto,iresp,hdir='-')  
yrecfm='PATCH_NUMBER'
 CALL read_surf(hfilepgdtype,yrecfm,ipatch,iresp,hdir='-')
 CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
!
IF(iversion<8.OR.(yphoto/='NIT'.AND.yphoto/='NCB'))THEN
  oprep_ags = .false.
  IF (lhook) CALL dr_hook('PREP_ISBA_CC_EXTERN',1,zhook_handle)
  RETURN
ENDIF
!       
SELECT CASE(hsurf)
!
  CASE('BIOMASS')
     CALL open_aux_io_surf(hfilepgd,hfilepgdtype,'NATURE')
     yrecfm='NBIOMASS'
     CALL read_surf(hfilepgdtype,yrecfm,inbiomass,iresp,hdir='-')
     CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
     IF (yphoto=='NIT' .OR. yphoto=='NCB') THEN
       ALLOCATE(pfield(ini,inbiomass,ipatch))
       pfield(:,:,:) = xundef
       CALL open_aux_io_surf(hfile,hfiletype,'NATURE')
       DO jnbiomass=1,inbiomass
          WRITE(ylvl,'(I1)') jnbiomass
          yrecfm='BIOMA'//adjustl(ylvl(:len_trim(ylvl)))
          CALL make_choice_array(hfiletype, ipatch, gdim, yrecfm, pfield(:,jnbiomass,:),hdir='E')
       ENDDO
       CALL close_aux_io_surf(hfile,hfiletype)
       DO jp=1,SIZE(pfield,3)
         DO jl=1,SIZE(pfield,2)
           WHERE (zmask(:)==0.) pfield(:,jl,jp) = xundef
         ENDDO
       ENDDO
     ELSE
       oprep_ags = .false.
     ENDIF
!
  CASE('LITTER')
     CALL open_aux_io_surf(hfile,hfiletype,'NATURE')
     yrecfm='RESPSL'
     CALL read_surf(hfiletype,yrecfm,yrespsl,iresp,hdir='-')
     IF(yrespsl=='CNT')THEN
       yrecfm='NLITTER'
       CALL read_surf(hfiletype,yrecfm,inlitter,iresp,hdir='-')
       yrecfm='NLITTLEVS'
       CALL read_surf(hfiletype,yrecfm,inlittlevs,iresp,hdir='-')
       ALLOCATE(pfield(ini,inlitter*inlittlevs,ipatch))
       pfield(:,:,:) = xundef
       iwork=0
       DO jnlitter=1,inlitter
          DO jnlittlevs=1,inlittlevs
             iwork=iwork+1
             WRITE(ylvl,'(I1,A1,I1)') jnlitter,'_',jnlittlevs
             yrecfm='LITTER'//adjustl(ylvl(:len_trim(ylvl)))
             CALL make_choice_array(hfiletype, ipatch, gdim, yrecfm, pfield(:,iwork,:),hdir='E')
          ENDDO
       ENDDO
       DO jp=1,SIZE(pfield,3)
         DO jl=1,SIZE(pfield,2)
           WHERE (zmask(:)==0.) pfield(:,jl,jp) = xundef
         ENDDO
       ENDDO
     ELSE
       oprep_ags = .false.
     ENDIF    
     CALL close_aux_io_surf(hfile,hfiletype)
!
  CASE('SOILCARB')
     CALL open_aux_io_surf(hfile,hfiletype,'NATURE')
     yrecfm='RESPSL'
     CALL read_surf(hfiletype,yrecfm,yrespsl,iresp,hdir='-')
     IF(yrespsl=='CNT')THEN
       yrecfm='NSOILCARB'
       CALL read_surf(hfiletype,yrecfm,insoilcarb,iresp,hdir='-')
       ALLOCATE(pfield(ini,insoilcarb,ipatch))
       pfield(:,:,:) = xundef
       DO jnsoilcarb=1,insoilcarb
          WRITE(ylvl,'(I4)') jnsoilcarb
          yrecfm='SOILCARB'//adjustl(ylvl(:len_trim(ylvl)))
          CALL make_choice_array(hfiletype, ipatch, gdim, yrecfm, pfield(:,jnsoilcarb,:),hdir='E')
       ENDDO
       DO jp=1,SIZE(pfield,3)
         DO jl=1,SIZE(pfield,2)
           WHERE (zmask(:)==0.) pfield(:,jl,jp) = xundef
         ENDDO
       ENDDO
     ELSE
       oprep_ags = .false.
     ENDIF    
     CALL close_aux_io_surf(hfile,hfiletype)
!     
  CASE('LIGNIN')
     CALL open_aux_io_surf(hfile,hfiletype,'NATURE')
     yrecfm='RESPSL'
     CALL read_surf(hfiletype,yrecfm,yrespsl,iresp,hdir='-')
     IF(yrespsl=='CNT')THEN
       yrecfm='NLITTLEVS'
       CALL read_surf(hfiletype,yrecfm,inlittlevs,iresp,hdir='-')
       ALLOCATE(pfield(ini,inlittlevs,ipatch))
       pfield(:,:,:) = xundef
       DO jnlittlevs=1,inlittlevs
          WRITE(ylvl,'(I4)') jnlittlevs
          yrecfm='LIGNIN_STR'//adjustl(ylvl(:len_trim(ylvl)))
          CALL make_choice_array(hfiletype, ipatch, gdim, yrecfm, pfield(:,jnlittlevs,:),hdir='E')
       ENDDO
       DO jp=1,SIZE(pfield,3)
         DO jl=1,SIZE(pfield,2)
           WHERE (zmask(:)==0.) pfield(:,jl,jp) = xundef
         ENDDO
       ENDDO
     ELSE
       oprep_ags = .false.
     ENDIF    
     CALL close_aux_io_surf(hfile,hfiletype)
!
END SELECT
!
DEALLOCATE(zmask)
!
!---------------------------------------------------------------------------
!
!*      6.     End of IO
!              ---------
!
IF (lhook) CALL dr_hook('PREP_ISBA_CC_EXTERN',1,zhook_handle)
!
!---------------------------------------------------------------------------
!---------------------------------------------------------------------------
END SUBROUTINE prep_isba_cc_extern