prep_hor_teb_field.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_hor_teb_field (B, BOP, DTCO, U, GCP, G, T, TOP, &
                               HPROGRAM,HSURF,HATMFILE,HATMFILETYPE,HPGDFILE,HPGDFILETYPE,KPATCH,YDCTL)
!     #################################################################################
!
!
!!****  *PREP_HOR_TEB_FIELD* - reads, interpolates and prepares a TEB field
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      P. Le Moigne 10/2005, Phasage Arome
!!      P. Marguinaud10/2014, Support for a 2-part PREP
!!------------------------------------------------------------------
!
USE modd_bem_n, ONLY : bem_t
USE modd_bem_option_n, ONLY : bem_options_t
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
USE modd_sfx_grid_n, ONLY : grid_t
USE modd_teb_n, ONLY : teb_t
USE modd_teb_option_n, ONLY : teb_options_t
!
USE modd_type_snow
USE modd_type_date_surf, ONLY : date_time
USE modd_surfex_mpi, ONLY : nrank, npio, ncomm, nproc
USE modd_grid_grib, ONLY : cinmodel
USE modd_prep,     ONLY : cingrid_type, cinterp_type, xzs_ls, cmask
USE modd_prep_teb, ONLY : xgrid_roof, xgrid_road, xgrid_wall, xgrid_floor, lsnow_ideal_teb, &
                          xwsnow_roof, xrsnow_roof, xtsnow_roof, xlwcsnow_roof, xasnow_roof, &
                          xwsnow_road, xrsnow_road, xtsnow_road, xlwcsnow_road, xasnow_road, &
                          xhui_bld, xhui_bld_def
!
USE modd_csts, ONLY: xg, xp00
USE modd_surf_par, ONLY: xundef
!
USE mode_prep_ctl, ONLY : prep_ctl, prep_ctl_int_part2, prep_ctl_int_part4
!
USE mode_thermos
!
USE modi_prep_grib_grid
USE modi_read_prep_teb_conf
USE modi_read_prep_teb_snow
USE modi_prep_teb_grib
USE modi_prep_teb_unif
USE modi_prep_teb_buffer
USE modi_hor_interpol
USE modi_prep_hor_snow_fields
USE modi_get_luout
USE modi_prep_teb_extern
USE modi_allocate_gr_snow
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1    declarations of arguments
!
!
TYPE(bem_t), INTENT(INOUT) :: B
TYPE(bem_options_t), INTENT(INOUT) :: BOP
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
TYPE(grid_t), INTENT(INOUT) :: G
TYPE(teb_t), INTENT(INOUT) :: T
TYPE(teb_options_t), INTENT(INOUT) :: TOP
type(prep_ctl),    INTENT(INOUT) :: ydctl
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: HSURF     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: HATMFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HATMFILETYPE! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: HPGDFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HPGDFILETYPE! type of the Atmospheric file
!
INTEGER,            INTENT(IN)  :: KPATCH
!
!*      0.2    declarations of local variables
!
TYPE(nsurf_snow) :: TNPSNOW
!
 CHARACTER(LEN=6)              :: YFILETYPE ! type of input file
 CHARACTER(LEN=28)             :: YFILE     ! name of file
 CHARACTER(LEN=6)              :: YFILEPGDTYPE ! type of input file
 CHARACTER(LEN=28)             :: YFILEPGD     ! name of file
REAL, DIMENSION(:), ALLOCATABLE :: ZSG1SNOW, ZSG2SNOW, ZHISTSNOW, ZAGESNOW
REAL, POINTER, DIMENSION(:,:) :: ZFIELDIN  ! field to interpolate horizontally
REAL, POINTER, DIMENSION(:,:) :: ZFIELDOUT ! field interpolated   horizontally
REAL, ALLOCATABLE, DIMENSION(:) :: ZPS !surface pressure
REAL, PARAMETER               :: ZRHOA=1.19 ! volumic mass of air at 20C and 1000hPa
INTEGER                       :: ILUOUT    ! output listing logical unit
INTEGER :: INFOMPI, INL
!
type(date_time)                :: tztime_grib    ! current date and time
LOGICAL             :: GUNIF     ! flag for prescribed uniform field
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
!
!*      1.     Reading of input file name and type
!
IF (lhook) CALL dr_hook('PREP_HOR_TEB_FIELD',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL read_prep_teb_conf(hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,&
                        hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,iluout,gunif)
!
cmask = 'TOWN'
!
!-------------------------------------------------------------------------------------
!
!*      2.     Snow variables case?
!
IF (hsurf=='SN_ROOF') THEN
  CALL read_prep_teb_snow(hprogram,t%TSNOW_ROOF%SCHEME,t%TSNOW_ROOF%NLAYER,&
                                   t%TSNOW_ROAD%SCHEME,t%TSNOW_ROAD%NLAYER,&
                                   yfile,yfiletype,yfilepgd,yfilepgdtype)
  IF (len_trim(yfile)>0 .AND. len_trim(yfiletype)>0) gunif = .false.                                   
  ALLOCATE(zsg1snow(SIZE(xwsnow_roof)))
  ALLOCATE(zsg2snow(SIZE(xwsnow_roof)))
  ALLOCATE(zhistsnow(SIZE(xwsnow_roof)))
  ALLOCATE(zagesnow(SIZE(xwsnow_roof)))
  ALLOCATE(tnpsnow%AL(1))
  tnpsnow%AL(1)%SCHEME = t%TSNOW_ROOF%SCHEME
  tnpsnow%AL(1)%NLAYER = t%TSNOW_ROOF%NLAYER
  CALL prep_hor_snow_fields(dtco, g, u, gcp, &
                            hprogram,hsurf,              &
                            yfile,yfiletype,             &
                            yfilepgd, yfilepgdtype,      &
                            iluout,gunif,1,kpatch,       &
                            SIZE(g%XLAT),tnpsnow, top%TTIME,&
                            xwsnow_roof, xrsnow_roof,    &
                            xtsnow_roof, xlwcsnow_roof,  &
                            xasnow_roof,                 &
                            lsnow_ideal_teb, zsg1snow,   &
                            zsg2snow, zhistsnow, zagesnow, ydctl)

  CALL allocate_gr_snow(t%TSNOW_ROOF,SIZE(g%XLAT))
  t%TSNOW_ROOF%WSNOW = tnpsnow%AL(1)%WSNOW
  t%TSNOW_ROOF%RHO   = tnpsnow%AL(1)%RHO
  t%TSNOW_ROOF%ALB   = tnpsnow%AL(1)%ALB
  t%TSNOW_ROOF%T     = tnpsnow%AL(1)%T
  t%TSNOW_ROOF%HEAT = tnpsnow%AL(1)%HEAT
  !
  CALL type_snow_init(tnpsnow%AL(1))
  DEALLOCATE(tnpsnow%AL)

  DEALLOCATE(zsg1snow)
  DEALLOCATE(zsg2snow)
  DEALLOCATE(zhistsnow)
  DEALLOCATE(zagesnow)                            
  IF (lhook) CALL dr_hook('PREP_HOR_TEB_FIELD',1,zhook_handle)
  RETURN
ELSE IF (hsurf=='SN_ROAD') THEN
  CALL read_prep_teb_snow(hprogram,t%TSNOW_ROOF%SCHEME,t%TSNOW_ROOF%NLAYER,&
                                   t%TSNOW_ROAD%SCHEME,t%TSNOW_ROAD%NLAYER,&
                                   yfile,yfiletype,yfilepgd,yfilepgdtype)
  IF (len_trim(yfile)>0 .AND. len_trim(yfiletype)>0) gunif = .false.                                   
  ALLOCATE(zsg1snow(SIZE(xwsnow_road)))
  ALLOCATE(zsg2snow(SIZE(xwsnow_road)))
  ALLOCATE(zhistsnow(SIZE(xwsnow_road)))
  ALLOCATE(zagesnow(SIZE(xwsnow_road)))    
  ALLOCATE(tnpsnow%AL(1))
  tnpsnow%AL(1)%SCHEME = t%TSNOW_ROAD%SCHEME
  tnpsnow%AL(1)%NLAYER = t%TSNOW_ROAD%NLAYER
  CALL prep_hor_snow_fields(dtco, g, u, gcp, &
                            hprogram,hsurf,              &
                            yfile,yfiletype,             &
                            yfilepgd, yfilepgdtype,      &                            
                            iluout,gunif,1,kpatch,       &
                            SIZE(g%XLAT),tnpsnow, top%TTIME,&
                            xwsnow_road, xrsnow_road,    &
                            xtsnow_road, xlwcsnow_road,  &
                            xasnow_road,                 &
                            lsnow_ideal_teb, zsg1snow,   &
                            zsg2snow, zhistsnow, zagesnow, ydctl)

  CALL allocate_gr_snow(t%TSNOW_ROAD,SIZE(g%XLAT))
  t%TSNOW_ROAD%WSNOW = tnpsnow%AL(1)%WSNOW
  t%TSNOW_ROAD%RHO   = tnpsnow%AL(1)%RHO
  t%TSNOW_ROAD%ALB   = tnpsnow%AL(1)%ALB
  t%TSNOW_ROAD%T     = tnpsnow%AL(1)%T
  t%TSNOW_ROAD%HEAT = tnpsnow%AL(1)%HEAT
  !
  CALL type_snow_init(tnpsnow%AL(1))
  DEALLOCATE(tnpsnow%AL)
                    
  DEALLOCATE(zsg1snow)
  DEALLOCATE(zsg2snow)
  DEALLOCATE(zhistsnow)
  DEALLOCATE(zagesnow)                               
  IF (lhook) CALL dr_hook('PREP_HOR_TEB_FIELD',1,zhook_handle)
  RETURN
END IF
!
!
!*      4.     Reading of input  configuration (Grid and interpolation type)
!
NULLIFY (zfieldin, zfieldout)
!
IF (ydctl%LPART1) THEN
!
  IF (gunif) THEN
    CALL prep_teb_unif(iluout,hsurf,zfieldin)
  ELSE IF (yfiletype=='GRIB  ') THEN
    CALL prep_grib_grid(yfile,iluout,cinmodel,cingrid_type,cinterp_type,tztime_grib) 
    IF (nrank==npio)CALL prep_teb_grib(hprogram,hsurf,yfile,iluout,zfieldin)        
  ELSE IF (yfiletype=='MESONH' .OR.yfiletype=='ASCII ' .OR.yfiletype=='LFI   '&
          .OR.yfiletype=='FA    '.OR.yfiletype=='AROME '.OR.yfiletype=='NC    ') THEN
    CALL prep_teb_extern(dtco,gcp,top,bop,hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,iluout,kpatch,zfieldin)
  ELSE IF (yfiletype=='BUFFER') THEN
    CALL prep_teb_buffer(hprogram,hsurf,iluout,zfieldin)
  ELSE
    CALL abor1_sfx('PREP_HOR_TEB_FIELD: data file type not supported : '//yfiletype)
  END IF
!
ENDIF
!
!*      5.     Horizontal interpolation
!
 CALL prep_ctl_int_part2 (ydctl, hsurf, cmask, 'TOWN', zfieldin)
!
IF (ydctl%LPART3) THEN
!
  IF (nrank==npio) THEN
    inl = SIZE(zfieldin,2)
  ELSEIF (.NOT.ASSOCIATED(zfieldin)) THEN
    ALLOCATE(zfieldin(0,0))
  ENDIF
  !
  IF (nproc>1) THEN
#ifdef SFX_MPI
    CALL mpi_bcast(inl,kind(inl)/4,mpi_integer,npio,ncomm,infompi)
#endif
  ENDIF
  ALLOCATE(zfieldout(SIZE(g%XLAT),inl))
  !
  IF (top%CWALL_OPT/='UNIF'.OR.trim(hsurf)/='T_WALLB') THEN
    CALL hor_interpol(dtco, u, gcp, iluout,zfieldin,zfieldout)
  ENDIF
  !
  DEALLOCATE(zfieldin )
  !
ENDIF
!
 CALL prep_ctl_int_part4 (ydctl, hsurf, 'TOWN', cmask, zfieldin, zfieldout)

IF (ydctl%LPART5) THEN
!
!*      6.     Return to historical variable
!
  SELECT CASE (hsurf)
    CASE('ZS     ') 
      ALLOCATE(xzs_ls(SIZE(zfieldout,1)))
      xzs_ls(:) = zfieldout(:,1)
    CASE('WS_ROOF') 
      ALLOCATE(t%XWS_ROOF(SIZE(zfieldout,1)))
      t%XWS_ROOF(:) = zfieldout(:,1)
    CASE('WS_ROAD')
      ALLOCATE(t%XWS_ROAD(SIZE(zfieldout,1)))
      t%XWS_ROAD(:) = zfieldout(:,1)
    CASE('TI_ROAD') 
      ALLOCATE(t%XTI_ROAD(SIZE(zfieldout,1)))
      t%XTI_ROAD(:) = zfieldout(:,1)
    CASE('TI_BLD ') 
      ALLOCATE(b%XTI_BLD (SIZE(zfieldout,1)))
      b%XTI_BLD (:) = zfieldout(:,1)
    CASE('QI_BLD ') 
      ALLOCATE(b%XQI_BLD (SIZE(zfieldout,1)))
      IF (all(zfieldout .GE. xundef-1.e+5 .AND. zfieldout .LE. xundef+1.e+5)) THEN
        ALLOCATE(zps(SIZE(zfieldout,1)))
        zps = xp00 - zrhoa * xg * xzs_ls
        IF (xhui_bld==xundef) THEN
          zfieldout(:,1) = xhui_bld_def * qsat(b%XTI_BLD, zps)
        ELSE
          zfieldout(:,1) = xhui_bld * qsat(b%XTI_BLD, zps)
        ENDIF
        DEALLOCATE(zps)
      ENDIF
      b%XQI_BLD (:) = zfieldout(:,1)
    CASE('T_WIN1 ') 
      ALLOCATE(b%XT_WIN1 (SIZE(zfieldout,1)))
      b%XT_WIN1 (:) = zfieldout(:,1)
    CASE('T_WIN2 ') 
      ALLOCATE(b%XT_WIN2 (SIZE(zfieldout,1)))
      b%XT_WIN2 (:) = zfieldout(:,1)
    CASE('T_FLOOR')
      ALLOCATE(b%XT_FLOOR(SIZE(zfieldout,1),bop%NFLOOR_LAYER))
      CALL init_from_ref_grid(xgrid_floor,zfieldout,b%XD_FLOOR,b%XT_FLOOR)
    CASE('T_MASS')
      ALLOCATE(b%XT_MASS(SIZE(zfieldout,1),bop%NFLOOR_LAYER))
      CALL init_from_ref_grid(xgrid_floor,zfieldout,b%XD_FLOOR,b%XT_MASS)        
    CASE('T_ROAD ') 
      ALLOCATE(t%XT_ROAD(SIZE(zfieldout,1),top%NROAD_LAYER))     
      CALL init_from_ref_grid(xgrid_road,zfieldout,t%XD_ROAD,t%XT_ROAD)
    CASE('T_WALLA')
      ALLOCATE(t%XT_WALL_A(SIZE(zfieldout,1),top%NWALL_LAYER))     
      CALL init_from_ref_grid(xgrid_wall,zfieldout,t%XD_WALL,t%XT_WALL_A)  
    CASE('T_WALLB')
      ALLOCATE(t%XT_WALL_B(SIZE(zfieldout,1),top%NWALL_LAYER))      
      IF (top%CWALL_OPT=='UNIF') THEN
        t%XT_WALL_B = t%XT_WALL_A
      ELSE
        CALL init_from_ref_grid(xgrid_wall,zfieldout,t%XD_WALL,t%XT_WALL_B)       
      END IF  
    CASE('T_ROOF ') 
      ALLOCATE(t%XT_ROOF(SIZE(zfieldout,1),top%NROOF_LAYER))
      CALL init_from_ref_grid(xgrid_roof,zfieldout,t%XD_ROOF,t%XT_ROOF)
    CASE('T_CAN  ') 
      ALLOCATE(t%XT_CANYON(SIZE(zfieldout,1)))
      t%XT_CANYON (:) = zfieldout(:,1)
    CASE('Q_CAN  ') 
      ALLOCATE(t%XQ_CANYON(SIZE(zfieldout,1)))
      t%XQ_CANYON (:) = zfieldout(:,1)
  END SELECT
!
ENDIF
!-------------------------------------------------------------------------------------
!
!*      7.     Deallocations
!
IF (ASSOCIATED (zfieldout)) DEALLOCATE(zfieldout)
IF (lhook) CALL dr_hook('PREP_HOR_TEB_FIELD',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!-------------------------------------------------------------------------------------
!
CONTAINS
!
!-------------------------------------------------------------------------------------
!-------------------------------------------------------------------------------------
SUBROUTINE init_from_ref_grid(PGRID1,PT1,PD2,PT2)
!
USE modi_interp_grid
!
REAL, DIMENSION(:,:), INTENT(IN)  :: PT1    ! temperature profile
REAL, DIMENSION(:),   INTENT(IN)  :: PGRID1 ! normalized grid
REAL, DIMENSION(:,:), INTENT(IN)  :: PD2    ! output layer thickness
REAL, DIMENSION(:,:), INTENT(OUT) :: PT2    ! temperature profile
!
INTEGER                                  :: JL  ! loop counter
REAL, DIMENSION(SIZE(PT1,1),SIZE(PT1,2)) :: ZD1 ! input grid
REAL, DIMENSION(SIZE(PD2,1),SIZE(PD2,2)) :: ZD2 ! output grid
REAL, DIMENSION(SIZE(PD2,1))             :: ZD  ! output total thickness
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('INIT_FROM_REF_GRID',0,zhook_handle)
zd2(:,:) = 0.
zd(:)   = 0.
!
DO jl=1,SIZE(zd2,2)
  zd2(:,jl) = zd(:) + pd2(:,jl)/2.
  zd(:)    = zd(:) + pd2(:,jl)
END DO
!
DO jl=1,SIZE(pt1,2)
  zd1(:,jl) = pgrid1(jl) * zd(:)
END DO
!
 CALL interp_grid(zd1,pt1,zd2,pt2)
IF (lhook) CALL dr_hook('INIT_FROM_REF_GRID',1,zhook_handle)
!
END SUBROUTINE init_from_ref_grid
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_hor_teb_field