prep_grid_gauss.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE prep_grid_gauss (&
                                  HFILETYPE,HINTERP_TYPE,KNI)
!     ##########################################################################
!
!!****  *PREP_GRID_GAUSS* - reads EXTERNALIZED Surface grid.
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!
!!      V. Masson
!!
!!    MODIFICATIONS
!!    -------------
!!      Original   06/2003
!!      M. Jidane    Nov 2013 : correct allocation of NINLO and reading of INLOPA
!!      F. Taillefer Dec 2013 : debug estimation of XILO2
!-------------------------------------------------------------------------------
!
!*      0. DECLARATIONS
!          ------------
!
!
!
!
USE modi_read_surf
!
USE modd_grid_gauss, ONLY : xila1, xilo1, xila2, xilo2, ninla, ninlo, nilen, lrotpole, &
                            xcoef, xlap, xlop, xilatarray
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!* 0.1. Declaration of arguments
!       ------------------------
!
!
!
 CHARACTER(LEN=6),  INTENT(IN)    :: HFILETYPE    ! file type
 CHARACTER(LEN=6),  INTENT(OUT)   :: HINTERP_TYPE ! Grid type
INTEGER,           INTENT(OUT)   :: KNI          ! number of points
!
!* 0.2 Declaration of local variables
!      ------------------------------
!
 CHARACTER(LEN=12) :: YRECFM    ! Name of the article to be read
INTEGER           :: IRESP
!
!
REAL, DIMENSION(:), ALLOCATABLE :: ZLAT    ! latitudes
REAL, DIMENSION(:), ALLOCATABLE :: ZW ! work array
!
INTEGER :: JL, ICPT        ! loop counter
INTEGER :: INLATI  ! number of pseudo-latitudes
INTEGER :: INLATI2 ! number of half pseudo-latitudes
REAL    :: ZLAPO   ! latitude of the rotated pole  (deg)
REAL    :: ZLOPO   ! longitude of the rotated pole (deg)
REAL    :: ZCODIL  ! stretching factor (must be greater than or equal to 1)
INTEGER, DIMENSION(:), ALLOCATABLE :: INLOPA ! number of pseudo-longitudes on each
                                             ! pseudo-latitude circle
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-----------------------------------------------------------------------
IF (lhook) CALL dr_hook('PREP_GRID_GAUSS',0,zhook_handle)
!-----------------------------------------------------------------------
!
!*   1 Projection
!      ----------
!
yrecfm = 'LAPO'
 CALL read_surf(hfiletype,yrecfm,zlapo,iresp)
yrecfm = 'LOPO'
 CALL read_surf(hfiletype,yrecfm,zlopo,iresp)
yrecfm = 'CODIL'
 CALL read_surf(hfiletype,yrecfm,zcodil,iresp)
!
!-----------------------------------------------------------------------
!
!*   2 Grid
!      ----
!
yrecfm = 'NLATI'
 CALL read_surf(hfiletype,yrecfm,inlati,iresp)
!
IF (ALLOCATED(inlopa)) DEALLOCATE(inlopa)
ALLOCATE(inlopa(inlati))
IF (ALLOCATED(ninlo)) DEALLOCATE(ninlo)
ALLOCATE(ninlo(inlati))
yrecfm = 'NLOPA'
 CALL read_surf(hfiletype,yrecfm,inlopa,iresp,hdir='-')
!
kni = sum(inlopa)
!
ALLOCATE(zlat(kni))
! CALL READ_SURF(HFILETYPE,'LATGAUSS',ZLAT(:),IRESP,HDIR='-')
 CALL read_surf(hfiletype,'LAT_G_XY',zlat(:),iresp,hdir='-')
!
IF (ALLOCATED(xilatarray)) DEALLOCATE(xilatarray)
ALLOCATE(xilatarray(inlati))
xilatarray(1) = zlat(1)
icpt = 1
DO jl = 2,kni
  IF (zlat(jl)/=zlat(jl-1)) THEN
    icpt = icpt + 1
    xilatarray(icpt) = zlat(jl)
  ENDIF
ENDDO
!
DEALLOCATE(zlat)
!-----------------------------------------------------------------------
!
!*   3 Computes additional quantities used in interpolation
!      ----------------------------------------------------
!
inlati2  = nint(REAL(inlati)/2.0)
ninla    = inlati
nilen    = kni
xlop     = zlopo
xlap     = zlapo
xcoef    = zcodil
!
ninlo(:) = inlopa(:)
!
!* type of transform
IF (zlapo>89.99 .AND. abs(zlopo)<0.00001) THEN
  lrotpole = .false.
ELSE
  lrotpole = .true.
ENDIF
!
!XILA1=90.0*(1.0-1.0/(REAL(INLATI)))
!XILA2=-90.0*(1.0-1.0/(REAL(INLATI)))
xila1 = xilatarray(1)
xila2 = xilatarray(inlati)
xilo1=0.0
xilo2=360.0*(REAL(inlopa(inlati2))-1.0)/REAL(INLOPA(inlati2))
!
hinterp_type = 'HORIBL'
!-----------------------------------------------------------------------
IF (lhook) CALL dr_hook('PREP_GRID_GAUSS',1,zhook_handle)
!-----------------------------------------------------------------------
!
END SUBROUTINE prep_grid_gauss