pgd_teb_greenroof_par.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pgd_teb_greenroof_par (DTCO, DTV, UG, U, USS, IO, S, K, KDIM, HPROGRAM)
!     ##############################################################
!
!!**** *PGD_TEB_GREENROOF_PAR* monitor for averaging and interpolations of cover fractions
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    A. Lemonsu       Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original                     09/2009
!!    A. Lemonsu / C. de Munck     04/2011    : TEB GreenRoof
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_data_isba_n, ONLY : data_isba_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_s_t, isba_k_t
!
USE modd_data_cover_par,       ONLY : nvegtype
USE modd_surf_par,             ONLY : xundef
USE modd_teb_veg,              ONLY : nlayer_gr_max, ntime_gr_max
!
USE modd_pgdwork,              ONLY : catype
!
USE modi_read_nam_pgd_teb_greenroof
USE modi_pgd_field
USE modi_test_nam_var_surf
!
USE mode_pos_surf
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(data_isba_t), INTENT(INOUT) :: DTV
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(isba_s_t), INTENT(INOUT) :: S
TYPE(isba_k_t), INTENT(INOUT) :: K
!
INTEGER, INTENT(IN) :: KDIM
!
 CHARACTER(LEN=6),    INTENT(IN)             :: HPROGRAM     ! Type of program
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER                                     :: ILUOUT    ! output listing logical unit
INTEGER                                     :: ILUNAM    ! namelist file  logical unit
LOGICAL                                     :: GFOUND    ! true if namelist is found
!
INTEGER                                     :: JLAYER    ! loop counter on layers
INTEGER                                     :: JLAYER_GR ! loop counter on green roof layers
INTEGER                                     :: JTIME     ! loop counter on time
INTEGER                                     :: JPATCH    ! loop counter on patch
INTEGER                                     :: JVEGTYPE  ! loop counter on vegtypes
!
!
INTEGER, PARAMETER                          :: JPGROUND_MAX   = 20
INTEGER, PARAMETER                          :: JPVEGTYPE_MAX  = 12
!
! declaration of namelist variables
INTEGER                                     :: ILAYER_GR      ! number of green roof physical layers
INTEGER                                     :: ITIME_GR       ! ntime for green roof parameters
 CHARACTER(LEN=5)                            :: YTYP_GR        ! type of green roof
!
! uniform value
!
REAL,DIMENSION(NLAYER_GR_MAX)              :: ZUNIF_OM_GR      ! fraction of organic matter (OM) in green roof layer
REAL,DIMENSION(NLAYER_GR_MAX)              :: ZUNIF_CLAY_GR    ! fraction of clay for the non-OM part of the green roof layer
REAL,DIMENSION(NLAYER_GR_MAX)              :: ZUNIF_SAND_GR    ! fraction of sand for the non-OM part of the green roof layer
REAL,DIMENSION(NTIME_GR_MAX)               :: ZUNIF_LAI_GR     ! LAI of green roof vegetation
!
! name of files containing data
!
 CHARACTER(LEN=28),DIMENSION(NLAYER_GR_MAX) :: YFNAM_OM_GR      ! fraction of organic matter (OM) in green roof layer
 CHARACTER(LEN=28),DIMENSION(NLAYER_GR_MAX) :: YFNAM_CLAY_GR    ! fraction of clay for the non-OM part of the green roof layer
 CHARACTER(LEN=28),DIMENSION(NLAYER_GR_MAX) :: YFNAM_SAND_GR    ! fraction of sand for the non-OM part of the green roof layer
 CHARACTER(LEN=28),DIMENSION(NTIME_GR_MAX)  :: YFNAM_LAI_GR     ! LAI  of green roof
!
! type of files containing data
!
 CHARACTER(LEN=6 ),DIMENSION(NLAYER_GR_MAX) :: YFTYP_OM_GR      ! fraction of organic matter (OM) in green roof layer
 CHARACTER(LEN=6 ),DIMENSION(NLAYER_GR_MAX) :: YFTYP_CLAY_GR    ! fraction of clay for the non-OM part of the green roof layer
 CHARACTER(LEN=6 ),DIMENSION(NLAYER_GR_MAX) :: YFTYP_SAND_GR    ! fraction of sand for the non-OM part of the green roof layer
 CHARACTER(LEN=6 ),DIMENSION(NTIME_GR_MAX)  :: YFTYP_LAI_GR     ! LAI  of green roof
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) CALL dr_hook('PGD_TEB_GREENROOF_PAR',0,zhook_handle)
!
ilayer_gr        = 0
itime_gr         = 0
ytyp_gr          = '     '           
!
zunif_om_gr      = xundef
zunif_clay_gr    = xundef
zunif_sand_gr    = xundef
zunif_lai_gr     = xundef
!
yfnam_om_gr      = '                            '
yfnam_clay_gr    = '                            '
yfnam_sand_gr    = '                            '
yfnam_lai_gr     = '                            '
!
yftyp_om_gr      = '      '
yftyp_clay_gr    = '      '
yftyp_sand_gr    = '      '
yftyp_lai_gr     = '      '
!
!-------------------------------------------------------------------------------
!
!*    2.      Input files for green roof characteristics
!             -------------------------------------------
!
 CALL read_nam_pgd_teb_greenroof(hprogram, itime_gr,ilayer_gr,ytyp_gr,                     &
                                zunif_om_gr, zunif_clay_gr, zunif_sand_gr, zunif_lai_gr,  &
                                yfnam_om_gr, yfnam_clay_gr, yfnam_sand_gr, yfnam_lai_gr,  &
                                yftyp_om_gr, yftyp_clay_gr, yftyp_sand_gr, yftyp_lai_gr)
!
dtv%NTIME              = itime_gr
io%NGROUND_LAYER      = ilayer_gr
io%CTYP_COV           = ytyp_gr
!
!*           Coherence of options for the green roof type
!             -------------------------------------------
!
 CALL test_nam_var_surf(iluout,'CTYP_GR',io%CTYP_COV,'GRASS','SEDUM')
!
!
ALLOCATE(s%XSOC       (kdim,io%NGROUND_LAYER))
ALLOCATE(k%XCLAY      (kdim,io%NGROUND_LAYER))
ALLOCATE(k%XSAND      (kdim,io%NGROUND_LAYER))
ALLOCATE(dtv%XPAR_LAI   (kdim,dtv%NTIME ,1))
!
!-------------------------------------------------------------------------------
!
!*    3.2      Uniform fields are prescribed
!             -----------------------------
!
CATYPE = 'ARI'
!
!
DO jlayer_gr=1,io%NGROUND_LAYER
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'OM_GR: fraction of OM in GR layer','BLD',yfnam_om_gr(jlayer_gr),   &
               yftyp_om_gr(jlayer_gr), zunif_om_gr(jlayer_gr), s%XSOC(:,jlayer_gr))
ENDDO
!
DO jlayer_gr=1,io%NGROUND_LAYER
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'CLAY_GR: fraction of CLAY in the non-OM part of GR layer','BLD',yfnam_clay_gr(jlayer_gr),   &
               yftyp_clay_gr(jlayer_gr), zunif_clay_gr(jlayer_gr), k%XCLAY(:,jlayer_gr))
ENDDO
!
DO jlayer_gr=1,io%NGROUND_LAYER
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'SAND_GR: fraction of SAND in the non-OM part of GR layer','BLD',yfnam_sand_gr(jlayer_gr),   &
               yftyp_sand_gr(jlayer_gr), zunif_sand_gr(jlayer_gr), k%XSAND(:,jlayer_gr))
ENDDO
!
DO jtime=1,dtv%NTIME
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'LAI_GR: LAI of green roof','BLD',yfnam_lai_gr(jtime),  &
                yftyp_lai_gr(jtime),zunif_lai_gr(jtime),dtv%XPAR_LAI(:,jtime,1))
!
ENDDO
!
!
IF (lhook) CALL dr_hook('PGD_TEB_GREENROOF_PAR',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE pgd_teb_greenroof_par