pgd_teb_garden_par.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pgd_teb_garden_par (DTCO, UG, U, USS, KDIM, IO, DTV, HPROGRAM)
!     ##############################################################
!
!!**** *PGD_TEB_GARDEN_PAR* monitor for averaging and interpolations of cover fractions
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    A. Lemonsu       Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    09/2009
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_data_isba_n, ONLY : data_isba_t
!
USE modd_data_cover_par,    ONLY : nvegtype
USE modd_surf_par,          ONLY : xundef
!
USE modd_pgdwork,           ONLY : catype
!
USE modi_get_luout
USE modi_open_namelist
USE modi_close_namelist
USE modi_pgd_field
USE modi_abor1_sfx
!
USE mode_pos_surf
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
INTEGER, INTENT(IN) :: KDIM
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(data_isba_t), INTENT(INOUT) :: DTV
!
 CHARACTER(LEN=6),    INTENT(IN)    :: HPROGRAM     ! Type of program
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER               :: ILUOUT    ! output listing logical unit
INTEGER               :: ILUNAM    ! namelist file  logical unit
LOGICAL               :: GFOUND    ! true if namelist is found
LOGICAL               :: GNO_PAR_GARDEN ! true no fraction is prescribed
INTEGER               :: JTIME     ! loop counter on time
!
!*    0.3    Declaration of namelists
!            ------------------------
!
INTEGER                                :: NTIME_GD
INTEGER, PARAMETER                     :: NGROUND_MAX  = 20
INTEGER, PARAMETER                     :: NVEGTYPE_MAX = 19
INTEGER, PARAMETER                     :: NTIME_MAX    = 12
!
! type of vegetation
!
 CHARACTER(LEN=4)                       :: CTYP_GARDEN_HVEG ! type of high vegetation
 CHARACTER(LEN=4)                       :: CTYP_GARDEN_LVEG ! type of low  vegetation
 CHARACTER(LEN=4)                       :: CTYP_GARDEN_NVEG ! type of bare soil
!
! uniform value
!
REAL                                   :: XUNIF_FRAC_HVEG  ! fractions of high vegetation
REAL                                   :: XUNIF_FRAC_LVEG  ! fractions of low  vegetation
REAL                                   :: XUNIF_FRAC_NVEG  ! fractions of bare soil
REAL,DIMENSION(NTIME_MAX)              :: XUNIF_LAI_HVEG   ! LAI       of high vegetation
REAL,DIMENSION(NTIME_MAX)              :: XUNIF_LAI_LVEG   ! LAI       of low  vegetation
REAL                                   :: XUNIF_H_HVEG     ! height of trees
!
! name of files containing data
!
 CHARACTER(LEN=28)                      :: CFNAM_FRAC_HVEG  ! fractions of high vegetation
 CHARACTER(LEN=28)                      :: CFNAM_FRAC_LVEG  ! fractions of low  vegetation
 CHARACTER(LEN=28)                      :: CFNAM_FRAC_NVEG  ! fractions of bare soil
 CHARACTER(LEN=28),DIMENSION(NTIME_MAX) :: CFNAM_LAI_HVEG   ! LAI       of high vegetation
 CHARACTER(LEN=28),DIMENSION(NTIME_MAX) :: CFNAM_LAI_LVEG   ! LAI       of low  vegetation
 CHARACTER(LEN=28)                      :: CFNAM_H_HVEG     ! height of trees
!
! type of files containing data
!
 CHARACTER(LEN=28)                      :: CFTYP_FRAC_HVEG  ! fractions of high vegetation
 CHARACTER(LEN=28)                      :: CFTYP_FRAC_LVEG  ! fractions of low  vegetation
 CHARACTER(LEN=28)                      :: CFTYP_FRAC_NVEG  ! fractions of bare soil
 CHARACTER(LEN=28),DIMENSION(NTIME_MAX) :: CFTYP_LAI_HVEG   ! LAI       of high vegetation
 CHARACTER(LEN=28),DIMENSION(NTIME_MAX) :: CFTYP_LAI_LVEG   ! LAI       of low  vegetation
 CHARACTER(LEN=28)                      :: CFTYP_H_HVEG     ! height of trees
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
NAMELIST/nam_data_teb_garden/   ntime_gd,                                          &
                                ctyp_garden_hveg, ctyp_garden_lveg,                &
                                ctyp_garden_nveg,                                  &
                                xunif_frac_hveg, xunif_frac_lveg, xunif_frac_nveg, &
                                xunif_lai_hveg , xunif_lai_lveg ,                  &
                                xunif_h_hveg   ,                                   &
                                cfnam_frac_hveg, cfnam_frac_lveg, cfnam_frac_nveg, &
                                cfnam_lai_hveg , cfnam_lai_lveg ,                  &
                                cfnam_h_hveg   ,                                   &
                                cftyp_frac_hveg, cftyp_frac_lveg, cftyp_frac_nveg, &
                                cftyp_lai_hveg , cftyp_lai_lveg ,                  &
                                cftyp_h_hveg  

!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) CALL dr_hook('PGD_TEB_GARDEN_PAR',0,zhook_handle)

ntime_gd = 12
!
CTYP_GARDEN_HVEG   = 'TEBD'           ! Temperate broadleaf trees (forest)
CTYP_GARDEN_LVEG   = 'PARK'           ! Grassland
CTYP_GARDEN_NVEG   = 'NO  '           ! No vegetation
!
xunif_frac_hveg    = xundef
xunif_frac_lveg    = xundef
xunif_frac_nveg    = xundef
xunif_lai_hveg     = xundef
xunif_lai_lveg     = xundef
xunif_h_hveg       = xundef
!
CFNAM_FRAC_HVEG    = '                            '
CFNAM_FRAC_LVEG    = '                            '
CFNAM_FRAC_NVEG    = '                            '
CFNAM_LAI_HVEG     = '                            '
CFNAM_LAI_LVEG     = '                            '
CFNAM_H_HVEG       = '                            '
!
CFTYP_FRAC_HVEG    = '      '
CFTYP_FRAC_LVEG    = '      '
CFTYP_FRAC_NVEG    = '      '
CFTYP_LAI_HVEG     = '      '
CFTYP_LAI_LVEG     = '      '
CFTYP_H_HVEG       = '      '
!
!-------------------------------------------------------------------------------
dtv%NTIME = 12
!-------------------------------------------------------------------------------
!
!*    2.      Input file for cover types
!             --------------------------
!
 CALL get_luout(hprogram,iluout)
 CALL open_namelist(hprogram,ilunam)
!
 CALL posnam(ilunam,'NAM_DATA_TEB_GARDEN',gfound,iluout)
IF (gfound) READ(unit=ilunam,nml=nam_data_teb_garden)
!
 CALL close_namelist(hprogram,ilunam)
!
IF (ntime_gd==1) THEN
  xunif_lai_hveg(2:) = xunif_lai_hveg(1)
  xunif_lai_lveg(2:) = xunif_lai_lveg(1)
ELSE IF (ntime_gd/=12) THEN
  CALL abor1_sfx( 'Namelist NAM_DATA_TEB_GARDEN: NTIME_GD must be equal to 1 or 12')
END IF
!-------------------------------------------------------------------------------
!
!*    3.      Coherence check
!             ---------------
!
io%LPAR =  (xunif_frac_hveg /= xundef .OR. len_trim(cfnam_frac_hveg) >0 )&
         .AND. (xunif_frac_lveg /= xundef .OR. len_trim(cfnam_frac_lveg) >0 )&
         .AND. (xunif_frac_nveg /= xundef .OR. len_trim(cfnam_frac_nveg) >0 )

gno_par_garden = (xunif_frac_hveg == xundef .AND. len_trim(cfnam_frac_hveg)==0)&
           .AND. (xunif_frac_lveg == xundef .AND. len_trim(cfnam_frac_lveg)==0)&
           .AND. (xunif_frac_nveg == xundef .AND. len_trim(cfnam_frac_nveg)==0)

IF ( .NOT. io%LPAR .AND. .NOT. gno_par_garden ) THEN
  WRITE(iluout,*) ' Error for fraction of high, low and no vegetation fractions in gardens '
  WRITE(iluout,*) ' You need to specify the three of them ... or none. '
  CALL abor1_sfx( 'Namelist NAM_DATA_TEB_GARDEN: you need to specify all of  HVEG, LVEG, NVEG fractions or NONE of them')
END IF
!
IF (gno_par_garden) THEN
  IF (lhook) CALL dr_hook('PGD_TEB_GARDEN_PAR',1,zhook_handle)
  RETURN
END IF
!
!-------------------------------------------------------------------------------
!
dtv%NTIME = ntime_gd
!
ALLOCATE(dtv%XPAR_FRAC_HVEG   (kdim        ))
ALLOCATE(dtv%XPAR_FRAC_LVEG   (kdim        ))
ALLOCATE(dtv%XPAR_FRAC_NVEG   (kdim        ))
ALLOCATE(dtv%XPAR_LAI_HVEG    (kdim,dtv%NTIME))
ALLOCATE(dtv%XPAR_LAI_LVEG    (kdim,dtv%NTIME))
ALLOCATE(dtv%XPAR_H_HVEG      (kdim        ))
!
io%CTYPE_HVEG = ctyp_garden_hveg
io%CTYPE_LVEG = ctyp_garden_lveg
io%CTYPE_NVEG = ctyp_garden_nveg
!
!-------------------------------------------------------------------------------
!
!*    3.      Uniform fields are prescribed
!             -----------------------------
!
CATYPE = 'ARI'
!
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'FRAC_HVEG: fraction of high vegetation','TWN',cfnam_frac_hveg,   &
                 cftyp_frac_hveg,xunif_frac_hveg,dtv%XPAR_FRAC_HVEG(:))  
!
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'FRAC_LVEG: fraction of low vegetation' ,'TWN',cfnam_frac_lveg,   &
                 cftyp_frac_lveg,xunif_frac_lveg,dtv%XPAR_FRAC_LVEG(:))  
!
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'FRAC_NVEG: fraction of bare soil'      ,'TWN',cfnam_frac_nveg,   &
                 cftyp_frac_nveg,xunif_frac_nveg,dtv%XPAR_FRAC_NVEG(:))  
!
!
DO jtime=1,dtv%NTIME
!
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'LAI_HVEG: LAI of high vegetation','TWN',cfnam_lai_hveg(jtime),  &
                  cftyp_lai_hveg(jtime),xunif_lai_hveg(jtime),dtv%XPAR_LAI_HVEG(:,jtime))  
!
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'LAI_LVEG: LAI of low  vegetation','TWN',cfnam_lai_lveg(jtime),  &
                  cftyp_lai_lveg(jtime),xunif_lai_lveg(jtime),dtv%XPAR_LAI_LVEG(:,jtime))  
!
!
ENDDO
!
!
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'H_HVEG: height of trees','TWN',cfnam_h_hveg,                     &
                 cftyp_h_hveg,xunif_h_hveg,dtv%XPAR_H_HVEG(:))  
IF (lhook) CALL dr_hook('PGD_TEB_GARDEN_PAR',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE pgd_teb_garden_par