pack_grid_lonlat_rot.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ##############################################################
      SUBROUTINE pack_grid_lonlat_rot(KMASK_SIZE,KMASK,KGRID_PAR1,PGRID_PAR1,KGRID_PAR2,OPACK,PGRID_PAR2)
!     ##############################################################
!
!!**** *PACK_GRID_LONLAT_ROT* packs the grid definition vector
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!      P. Samuelsson   SMHI
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    12/2012
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modi_pack_same_rank
USE mode_gridtype_lonlat_rot
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                        INTENT(IN)    :: KMASK_SIZE ! size of mask
INTEGER, DIMENSION(KMASK_SIZE), INTENT(IN)    :: KMASK      ! mask used
INTEGER,                        INTENT(IN)    :: KGRID_PAR1 ! size of input grid vector
REAL,    DIMENSION(KGRID_PAR1), INTENT(IN)    :: PGRID_PAR1 ! parameters of input grid
INTEGER,                        INTENT(INOUT) :: KGRID_PAR2 ! size of output grid vector
LOGICAL,                        INTENT(IN)    :: OPACK      ! flag to pack the grid vector
REAL,    DIMENSION(KGRID_PAR2), INTENT(OUT)   :: PGRID_PAR2 ! parameters of output grid
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL    :: ZWEST   ! West longitude in rotated grid (degrees)
REAL    :: ZSOUTH  ! South latitude in rotated grid  (degrees)
REAL    :: ZDLON   ! Longitudal grid spacing  (degrees)
REAL    :: ZDLAT   ! Latitudal grid spacing  (degrees)
REAL    :: ZPOLON  ! Longitude of rotated pole (degrees)
REAL    :: ZPOLAT  ! Latitude of rotated pole  (degrees)
INTEGER :: ILON    ! number of points in longitude
INTEGER :: ILAT    ! number of points in latitude
INTEGER :: IL      ! number of points used
REAL, DIMENSION(:), ALLOCATABLE    :: ZLAT1     ! latitude of all grid points
REAL, DIMENSION(:), ALLOCATABLE    :: ZLON1     ! longitude of all grid points
REAL, DIMENSION(:), ALLOCATABLE    :: ZLAT2     ! latitude of subset of grid points
REAL, DIMENSION(:), ALLOCATABLE    :: ZLON2     ! longitude of subset of grid points

!
REAL, DIMENSION(:), POINTER       :: ZGRID_PAR2 ! parameters of output grid
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!----------------------------------------------------------------------------
!
!*    1.     Computes grid parameters
!            ------------------------
!
IF (lhook) CALL dr_hook('PACK_GRID_LONLAT_ROT',0,zhook_handle)
 CALL get_gridtype_lonlat_rot(pgrid_par1,                                &
                               zwest,zsouth,zdlon,zdlat,zpolon,zpolat,  &
                               ilon,ilat, il                            )  
ALLOCATE(zlat1(il))
ALLOCATE(zlon1(il))
!
 CALL get_gridtype_lonlat_rot(pgrid_par1,plon=zlon1,plat=zlat1)
!----------------------------------------------------------------------------
!
!*    2.     Packs latitude and longitude arrays
!            -----------------------------------
!
!
ALLOCATE(zlat2(kmask_size))
ALLOCATE(zlon2(kmask_size))
!
 CALL pack_same_rank(kmask,zlat1,zlat2)
 CALL pack_same_rank(kmask,zlon1,zlon2)
!
DEALLOCATE(zlat1)
DEALLOCATE(zlon1)

!----------------------------------------------------------------------------
!
!*    3.     Stores data in new grid vector
!            ------------------------------
!
 CALL put_gridtype_lonlat_rot(zgrid_par2,                                &
                               zwest,zsouth,zdlon,zdlat,zpolon,zpolat,  &
                               ilon,ilat,kmask_size,zlon2,zlat2         )  

DEALLOCATE(zlat2)
DEALLOCATE(zlon2)
!----------------------------------------------------------------------------
!
IF (opack) THEN
  pgrid_par2(:) = zgrid_par2(:)
ELSE
  kgrid_par2    = SIZE(zgrid_par2(:))
END IF
!
DEALLOCATE(zgrid_par2)
IF (lhook) CALL dr_hook('PACK_GRID_LONLAT_ROT',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE pack_grid_lonlat_rot