ol_read_atm.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE ol_read_atm (&
                         HSURF_FILETYPE, HFORCING_FILETYPE, KFORC_STEP,    &
                          PTA,PQA,PWIND,PDIR_SW,PSCA_SW,PLW,PSNOW,PRAIN,PPS,&
                          PCO2,PDIR,OLIMIT_QAIR                             )  
!**************************************************************************
!
!!    PURPOSE
!!    -------
!         Read in the netcdf file the atmospheric forcing for the actual time
!         step KFORC_STEP, and for the next one.
!         The two time step are needed for the time interpolation of the
!         forcing.
!         If the end of the file  is reached, set the two step to the last
!         values.
!         Return undef value if the variable is not present
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      F. Habets   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original     06/2003
!!      P. Le Moigne 10/2004: set XCOUNT to 2 because of revised temporal loop in offline.f90:
!!                            time evolution is done at the end of isba time step so first 
!!                            isba computation is done on first forcing time step
!!      P. Le Moigne 10/2005: consistency checking between orographies read from forcing 
!!                            file and from initial file
!!      B. Decharme  01/2009: Optional, limitation of Qair (<= Qsat(tair))
!
!
!
!
USE modd_surf_par,   ONLY : xundef
USE modd_io_surf_ol, ONLY : xstart,xcount,xstride,lpartr
!         
USE modi_ol_read_atm_netcdf
USE modi_ol_read_atm_ascii 
USE modi_ol_read_atm_binary
!
USE mode_thermos
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
! global variables
!
!
REAL, DIMENSION(:,:),INTENT(INOUT) :: PTA !K
REAL, DIMENSION(:,:),INTENT(INOUT) :: PQA
REAL, DIMENSION(:,:),INTENT(INOUT) :: PWIND
REAL, DIMENSION(:,:),INTENT(INOUT) :: PDIR_SW
REAL, DIMENSION(:,:),INTENT(INOUT) :: PSCA_SW
REAL, DIMENSION(:,:),INTENT(INOUT) :: PLW
REAL, DIMENSION(:,:),INTENT(INOUT) :: PSNOW
REAL, DIMENSION(:,:),INTENT(INOUT) :: PRAIN
REAL, DIMENSION(:,:),INTENT(INOUT) :: PPS
REAL, DIMENSION(:,:),INTENT(INOUT) :: PCO2
REAL, DIMENSION(:,:),INTENT(INOUT) :: PDIR
INTEGER,INTENT(IN)               :: KFORC_STEP
 CHARACTER(LEN=6)    ,INTENT(IN)  :: HSURF_FILETYPE
 CHARACTER(LEN=6)    ,INTENT(IN)  :: HFORCING_FILETYPE
LOGICAL             ,INTENT(IN)  :: OLIMIT_QAIR
!
REAL, PARAMETER :: ZTAIR  = 286.0
REAL, PARAMETER :: ZPSURF = 101325.0
!
REAL, DIMENSION(SIZE(PTA,1),SIZE(PTA,2)) :: ZWORK1, ZWORK2, ZQSAT
!
INTEGER              :: JFRC, IFRC, JJ, INI, INB
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!
!set time variables
IF (lhook) CALL dr_hook('OL_READ_ATM',0,zhook_handle)
xstart =kforc_step
xcount =SIZE(pta,2)
xstride=1
lpartr=.true.
!
! read data
!
IF      (hforcing_filetype == 'NETCDF') THEN
  CALL ol_read_atm_netcdf(&
                           hsurf_filetype,                                   &
                           pta,pqa,pwind,pdir_sw,psca_sw,plw,psnow,prain,pps,&
                           pco2,pdir                                         )  
ELSE IF (hforcing_filetype == 'ASCII ') THEN
  CALL ol_read_atm_ascii  (kforc_step,                       &
                           pta,pqa,pwind,pdir_sw,psca_sw,plw,psnow,prain,pps,&
                           pco2,pdir                                         )  
ELSE IF (hforcing_filetype == 'BINARY') THEN
  CALL ol_read_atm_binary (kforc_step,                       &
                           pta,pqa,pwind,pdir_sw,psca_sw,plw,psnow,prain,pps,&
                           pco2,pdir                                         )  
ENDIF
!
! Assume Qair <= Qsat_air
!
IF(olimit_qair)THEN
!  
  ini  = SIZE(pta,1)
  ifrc = SIZE(pta,2)
  inb  = 0
!
  DO jfrc=1,ifrc    
     DO jj=1,ini     
        IF(pta(jj,jfrc)>0.0.AND.pta(jj,jfrc)/=xundef)THEN
           inb             = inb+1
           zwork1(jj,jfrc) = pta(jj,jfrc)
           zwork2(jj,jfrc) = pps(jj,jfrc)
        ELSE
           zwork1(jj,jfrc) = ztair
           zwork2(jj,jfrc) = zpsurf
           pta(jj,jfrc) = xundef
           pqa(jj,jfrc) = 0.0
        ENDIF
     ENDDO
  ENDDO
!  
  IF(inb==0 .AND. ini/=0)THEN
    CALL abor1_sfx('OL_READ_ATM: THE FORCING IS UNDEFINED')
  ENDIF
!
  zqsat(:,:) = qsat(zwork1(:,:),zwork2(:,:))
!  
  pqa(:,:) = min(pqa(:,:),zqsat(:,:))
!  
ENDIF
!
IF (lhook) CALL dr_hook('OL_READ_ATM',1,zhook_handle)
!
END SUBROUTINE ol_read_atm