ol_find_file_read.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
        SUBROUTINE ol_find_file_read(HNAME,IFILE_ID)
!     ###############################
!
!!****  *OL_FIND_FILE_READ
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      F. Habets   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07-03
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------

USE modd_ol_fileid


!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
USE netcdf
!
IMPLICIT NONE


! 
 CHARACTER(LEN=*),   INTENT(IN) :: HNAME
INTEGER, INTENT(OUT):: IFILE_ID

INTEGER, DIMENSION(:), ALLOCATABLE :: ITEMP
 CHARACTER(LEN=100), DIMENSION(:), ALLOCATABLE :: HTEMP
LOGICAL     :: LFIND_VAR
 CHARACTER(LEN=100)             :: HFILE_PAS,HNAME_PAS
INTEGER :: JRET
INTEGER :: JFILE,JVAR,IVAR_ID
REAL(KIND=JPRB) :: ZHOOK_HANDLE

!******************************************

IF (lhook) CALL dr_hook('OL_FIND_FILE_READ',0,zhook_handle)
hname_pas=hname(:len_trim(hname))

lfind_var=.false.
ifile_id=0

IF (SIZE(xid_varin).GT.0) THEN
  DO jvar=1,SIZE(xvar_to_filein)
    IF (trim(xvar_to_filein(jvar))==hname_pas) THEN
      ifile_id=xid_varin(jvar)
      lfind_var=.true.
      EXIT
    ENDIF
  ENDDO
ENDIF

IF (.NOT.lfind_var) THEN

  jfile=1

  jret=nf90_noerr+1
  DO WHILE  ((jfile<= SIZE(xid_in)) .AND. (jret /= nf90_noerr))
       ifile_id=xid_in(jfile)
       jret=nf90_inq_varid(ifile_id,hname_pas,ivar_id)
       jfile=jfile+1
  ENDDO

  IF (jret == nf90_noerr) THEN
    xin=xin+1
    ALLOCATE(itemp(xin))
    ALLOCATE(htemp(xin))
    itemp(xin)=ifile_id
    htemp(xin)=hname_pas
    IF (xin.GT.1) THEN
      itemp(1:xin-1)=xid_varin(:)
      htemp(1:xin-1)=xvar_to_filein(:)
    ENDIF
    !
    DEALLOCATE(xid_varin)
    DEALLOCATE(xvar_to_filein)
    ALLOCATE(xid_varin(xin))
    ALLOCATE(xvar_to_filein(xin))
    xid_varin=itemp
    xvar_to_filein=htemp
    DEALLOCATE(itemp)
    DEALLOCATE(htemp)
  ELSE
    CALL abor1_sfx("OL_FIND_FILE_READ: "//hname_pas//" NOT FOUND IN INPUT NC FILES")
  ENDIF

ENDIF
IF (lhook) CALL dr_hook('OL_FIND_FILE_READ',1,zhook_handle)


END SUBROUTINE ol_find_file_read