mpl_locomm_create_mod.F90

Go to the documentation of this file.

MODULE mpl_locomm_create_mod

!**** MPL_LOCOMM_CREATE Create a new communicator

!     Purpose.
!     --------
!     Create a new communicator from lowest N tasks in MPI_COMM_WORLD 
!     and set as default
                                                                                
!**   Interface.
!     ----------
!        CALL MPL_LOCOMM_CREATE

!        Input required arguments :
!        -------------------------
!           N     -  Number of tasks in New Communicator

!        Input optional arguments :
!        -------------------------

!        Output required arguments :
!        -------------------------
!           KCOMM -  New Communicator

!        Output optional arguments :
!        -------------------------
!           MPL_LOCOMM_CREATE aborts when an error is detected.
 
!     Author.
!     -------
!        J.Hague        

!     Modifications.
!     --------------
!        Original: 21/07/2003

!     ------------------------------------------------------------------

USE parkind1  ,ONLY : jpim     ,jprb

USE mpl_mpif
USE mpl_data_module
USE mpl_message_mod

IMPLICIT NONE

PRIVATE
PUBLIC mpl_locomm_create

CONTAINS 


SUBROUTINE mpl_locomm_create(N,KCOMM)


#ifdef USE_8_BYTE_WORDS
  USE mpi4to8, ONLY : &
    mpi_comm_group => mpi_comm_group8, mpi_group_incl => mpi_group_incl8, mpi_comm_create => mpi_comm_create8
#endif


INTEGER(KIND=JPIM),INTENT(OUT) :: KCOMM
INTEGER(KIND=JPIM),INTENT(IN)  :: N

INTEGER(KIND=JPIM) :: IRANK(n)
INTEGER(KIND=JPIM) :: J, IER, IGROUP, MPI_GROUP_WORLD
LOGICAL   :: LLABORT=.true.

DO j=1,n
  irank(j)=j-1
ENDDO

CALL mpi_comm_group(mpl_comm,mpi_group_world,ier)
IF (ier/=0) CALL mpl_message(ier,'MPL_LOCOMM_CREATE: MPI_COMM_GROUP',ldabort=llabort)

CALL mpi_group_incl(mpi_group_world,n,irank,igroup,ier)
IF (ier/=0) CALL mpl_message(ier,'MPL_LOCOMM_CREATE: MPI_GROUP_INCL',ldabort=llabort)

CALL mpi_comm_create(mpl_comm,igroup,kcomm,ier)
IF (ier/=0) CALL mpl_message(ier,'MPL_LOCOMM_CREATE: MPI_COMM_CREATE',ldabort=llabort)

RETURN

END SUBROUTINE mpl_locomm_create

END MODULE mpl_locomm_create_mod