mode_write_surf_nc.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
MODULE mode_write_surf_nc
!
INTERFACE write_surf0_nc
        MODULE PROCEDURE write_surfx0_nc
        MODULE PROCEDURE write_surfn0_nc
        MODULE PROCEDURE write_surfc0_nc
        MODULE PROCEDURE write_surfl0_nc
END INTERFACE
INTERFACE write_surfn_nc
        MODULE PROCEDURE write_surfx1_nc
        MODULE PROCEDURE write_surfn1_nc
        MODULE PROCEDURE write_surfn2_nc
        MODULE PROCEDURE write_surfl1_nc
        MODULE PROCEDURE write_surfx2_nc
        MODULE PROCEDURE write_surfx3_nc
END INTERFACE
INTERFACE write_surft_nc
        MODULE PROCEDURE write_surft0_nc
        MODULE PROCEDURE write_surft1_nc
        MODULE PROCEDURE write_surft2_nc
END INTERFACE
!
CONTAINS
!
!     #############################################################
      SUBROUTINE write_surfx0_nc (HSELECT,HREC,PFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *WRITEX0* - routine to read a real scalar
!
!
USE modd_io_surf_nc, ONLY : nid_nc, ldef
!
USE modi_io_buff
!
USE modi_def_var_netcdf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),  INTENT(IN)  :: HREC     ! name of the article to be read
REAL,               INTENT(IN)  :: PFIELD   ! the real scalar to be read
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(IN)  :: HCOMMENT
!
!*      0.2   Declarations of local variables
!
LOGICAL :: GFOUND
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT
INTEGER, DIMENSION(0) :: IDIMS
INTEGER :: IRET
INTEGER :: IVAR_ID,JRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX0_NC',0,zhook_handle)
!
kresp=0
iret=0
!
yatt_title(1) = "comment"
yatt(1) = hcomment
!
 CALL io_buff(hrec,'W',gfound)
IF (gfound .AND. lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX0_NC',1,zhook_handle)
IF (gfound) RETURN
!
IF (nid_nc /= 0) THEN        
  ! 1. Define the variable
  !----------------------------
  IF (ldef) THEN
    !
    CALL def_var_netcdf(hselect, nid_nc, hrec, hrec, idims, yatt_title, yatt,  ivar_id, nf90_double)
    !
  ELSE
    ! 2. Put variable
    !----------------------------
    iret = nf90_inq_varid(nid_nc,hrec,ivar_id)
    iret = nf90_put_var(nid_nc,ivar_id,pfield)
  ENDIF
ENDIF
!
! 3. Check for errors
!--------------------
IF (nid_nc==0 .OR. iret.NE.nf90_noerr) kresp=1
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX0_NC',1,zhook_handle)
!
END SUBROUTINE write_surfx0_nc
!
!     #############################################################
      SUBROUTINE write_surfn0_nc ( HSELECT, HREC,KFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *WRITEN0* - routine to read an integer
!
!
!
!
USE modd_io_surf_nc, ONLY : nid_nc,ldef
!
USE modi_io_buff
!
USE modi_def_var_netcdf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),  INTENT(IN) :: HREC     ! name of the article to be read
INTEGER,            INTENT(IN)  :: KFIELD   ! the integer scalar to be read
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(IN) :: HCOMMENT
!
!*      0.2   Declarations of local variables
!
LOGICAL :: GFOUND
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT
INTEGER, DIMENSION(0) :: IDIMS
INTEGER              :: IVAR_ID, JRET
INTEGER :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN0_NC',0,zhook_handle)
!
iret = 0
kresp= 0
!
yatt_title(1) = "comment"
yatt(1) = hcomment
!
 CALL io_buff(hrec,'W',gfound)
IF (gfound .AND. lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN0_NC',1,zhook_handle)
IF (gfound) RETURN
!
! 0. find filename
! -----------------
!
IF (nid_nc /= 0) THEN    
  ! 1. Find id of the variable
  !----------------------------
  IF (ldef) THEN
    CALL def_var_netcdf(hselect, nid_nc, hrec, hrec, idims, yatt_title, yatt, ivar_id, nf90_int)
    ! 
    ! 2. Get variable
    !----------------------------
  ELSE
    iret=nf90_inq_varid(nid_nc,hrec,ivar_id)
    iret=nf90_put_var(nid_nc,ivar_id,kfield)
  ENDIF
ENDIF
!
! 3. Check for errors
!--------------------
IF (nid_nc==0 .OR. iret.NE.nf90_noerr) kresp=1
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN0_NC',1,zhook_handle)
!
END SUBROUTINE write_surfn0_nc
!
!     #############################################################
      SUBROUTINE write_surfc0_nc ( HSELECT, HREC,HFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *WRITEC0* - routine to read a STRING
!
!
!
!
USE modd_io_surf_nc, ONLY : nid_nc, ldef
!
USE modi_io_buff
!
USE modi_def_var_netcdf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),  INTENT(IN)  :: HREC     ! name of the article to be read
 CHARACTER(LEN=40),  INTENT(IN)  :: HFIELD   ! the integer scalar to be read
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(IN)  :: HCOMMENT
!
!*      0.2   Declarations of local variables
!
LOGICAL :: GFOUND
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT
INTEGER, DIMENSION(1) :: IDIMS, ISTART, ICOUNT
 CHARACTER(LEN=1), DIMENSION(:), ALLOCATABLE :: YFIELD
INTEGER :: IVAR_ID, JRET
INTEGER :: IRET, J
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFC0_NC',0,zhook_handle)
!
kresp=0
!
yatt_title(1) = "comment"
yatt(1) = hcomment
!
 CALL io_buff(hrec,'W',gfound)
IF (gfound .AND. lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFC0_NC',1,zhook_handle)
IF (gfound) RETURN
!
IF (nid_nc /= 0) THEN 
  ! 1. Find id of the variable
  !----------------------------
  IF (ldef) THEN
    iret = nf90_inq_dimid(nid_nc,'char_len',idims(1))
    !
    CALL def_var_netcdf(hselect, nid_nc, hrec, hrec, idims, yatt_title, yatt, ivar_id, nf90_char,len_trim(hfield))
    !
  ELSE
    iret = nf90_inq_varid(nid_nc,hrec,ivar_id)
    ! 2. Get variable
    !----------------------------
    ALLOCATE(yfield(len(hfield)))
    DO j=1,len(hfield)
      yfield(j) = hfield(j:j)
    ENDDO
    istart(1) = 1
    icount(1) = len(hfield)
    iret=nf90_put_var(nid_nc,ivar_id,yfield,istart,icount)
  ENDIF
ENDIF
!
! 3. Check for errors
!--------------------
IF (nid_nc==0 .OR. iret.NE.nf90_noerr) kresp=1
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFC0_NC',1,zhook_handle)
!
END SUBROUTINE write_surfc0_nc
!
!     #############################################################
      SUBROUTINE write_surfl0_nc ( HSELECT, HREC,OFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *WRITEL0* - routine to read a logical
!
!
!
!
USE modd_io_surf_nc, ONLY : nid_nc,ldef
!
USE modi_io_buff
!
USE modi_def_var_netcdf
!
USE modi_handle_err
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),   INTENT(IN) :: HREC     ! name of the article to be read
LOGICAL,             INTENT(IN) :: OFIELD   ! array containing the data field
INTEGER,             INTENT(OUT):: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),  INTENT(IN) :: HCOMMENT
!
!*      0.2   Declarations of local variables
!
LOGICAL :: GFOUND
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT
INTEGER, DIMENSION(0) :: IDIMS
 CHARACTER(LEN=1)    :: YFIELD   ! work array read in the file
INTEGER              :: IVAR_ID
INTEGER :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFL0_NC',0,zhook_handle)
!
IF (ofield) THEN
  yfield = 'T'
ELSE
  yfield = 'F'
ENDIF
!
iret=0
kresp=0
!
 CALL io_buff(hrec,'W',gfound)
IF (gfound .AND. lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFL0_NC',1,zhook_handle)
IF (gfound) RETURN
!
yatt_title(1) = "comment"
yatt(1) = hcomment
!
IF (nid_nc /= 0) THEN        
  !
  IF (ldef) THEN
    CALL def_var_netcdf(hselect, nid_nc, hrec, hrec, idims, yatt_title, yatt, ivar_id, nf90_char)
    !
  ELSE
    !
    iret = nf90_inq_varid(nid_nc,hrec,ivar_id)
    ! 2. Put variable
    !----------------------------
    !
    iret=nf90_put_var(nid_nc,ivar_id,yfield)
    !
    CALL handle_err(iret,hrec)
  ENDIF
  !
ENDIF
!
! 3. Check for errors
!--------------------
IF (nid_nc==0 .OR. iret.NE.nf90_noerr) kresp=1
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFL0_NC',1,zhook_handle)
!
END SUBROUTINE write_surfl0_nc
!
!
!     #############################################################
      SUBROUTINE write_surfx1_nc ( HSELECT, HREC,PFIELD,KRESP,HCOMMENT,HDIR,HNAM_DIM)
!     #############################################################
!
!!****  *WRITEX1* - routine to fill a real 1D array for the externalised surface 
! 
USE modd_surfex_mpi, ONLY : nrank, npio, nproc, ncomm
!
!
USE modd_io_surf_nc, ONLY : nid_nc, lmask, nmask, nmask_ign, cfileout_nc,ldef
!
USE modi_def_var_netcdf
!
USE modi_io_buff
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),   INTENT(IN) :: HREC     ! name of the article to be read
REAL, DIMENSION(:),  INTENT(IN) :: PFIELD   ! array containing the data field
INTEGER,             INTENT(OUT):: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),  INTENT(IN) :: HCOMMENT
 CHARACTER(LEN=1),    INTENT(IN) :: HDIR     ! type of field :
                                            ! 'H' : field with
                                            !       horizontal spatial dim.
                                            ! '-' : no horizontal dim.
 CHARACTER(LEN=*), OPTIONAL,  INTENT(IN) :: HNAM_DIM                                           
!*      0.2   Declarations of local variables
!
INTEGER :: IRET0
LOGICAL :: GFOUND
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT
INTEGER, DIMENSION(2) :: IDIMIDS
INTEGER, DIMENSION(2) :: IDIMLEN
 CHARACTER(LEN=100)    :: YNAME
 CHARACTER(LEN=16)     :: YNAM_DIM
INTEGER               :: IVAR_ID, JDIM, INDIMS
INTEGER               :: JRET
INTEGER               :: INFOMPI
INTEGER,DIMENSION(5)  :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX1_NC',0,zhook_handle)
!
kresp = 0
!
iret(:) = 0
!
yatt_title(1) = "comment"
yatt(1) = hcomment
!
IF (PRESENT(hnam_dim)) THEN
  ynam_dim = hnam_dim
ELSE
  ynam_dim = "Number_of_points"
ENDIF
!
indims = 0
idimlen(:) = 0
yname = ""
!
 CALL io_buff(hrec,'W',gfound)
!
IF (gfound .AND. lhook) CALL dr_hook("WRITE_SURF_NC:WRITE_SURFX1_NC",1,zhook_handle)
IF (gfound) RETURN
!
IF (nrank==npio) THEN 
  !
  IF (nid_nc /= 0) THEN
    !
    ! 0. find filename
    ! -----------------
    !
    iret(1) = nf90_inquire(nid_nc,ndimensions=indims)
    iret(2) = nf90_inq_dimid(nid_nc,trim(ynam_dim),idimids(1))
    IF (iret(2)/=0) THEN
      iret(2) = nf90_inq_dimid(nid_nc,'lon',idimids(1))
      IF (iret(2)/=0) THEN
        iret(2) = nf90_inq_dimid(nid_nc,'xx',idimids(1))
        iret(3) = nf90_inq_dimid(nid_nc,'yy',idimids(2))
      ELSE
        iret(3) = nf90_inq_dimid(nid_nc,'lat',idimids(2))
      ENDIF
      iret0=nf90_inquire_dimension(nid_nc,idimids(2),len=idimlen(2))
    ENDIF
    iret0=nf90_inquire_dimension(nid_nc,idimids(1),len=idimlen(1))
    !
    iret(4)=nf90_inquire_dimension(nid_nc,idimids(1),name=yname)
    !
    DO jret=1,4
      IF (iret0==0 .OR. iret(jret).NE.nf90_noerr) kresp=1
    ENDDO
    !
  ELSE
    indims = 0
    idimids(:) = 0
    idimlen(:) = 0
    yname = ""    
  ENDIF
  !
ELSE
  indims = 0
  idimids(:) = 0
  idimlen(:) = 0
  yname = ""    
ENDIF
!
#ifdef SFX_MPI
IF (nproc>1) THEN
  CALL mpi_bcast(yname,len(yname),mpi_character,npio,ncomm,infompi)
  CALL mpi_bcast(indims,kind(indims)/4,mpi_integer,npio,ncomm,infompi)
  CALL mpi_bcast(idimlen,kind(idimlen)*SIZE(idimlen)/4,mpi_integer,npio,ncomm,infompi)  
ENDIF
#endif
!
IF (yname.NE.'lon' .AND. yname.NE.'xx') THEN
  IF (ldef) THEN
    IF (nrank==npio) THEN
      CALL def_var_netcdf( hselect, nid_nc, hrec, hrec, idimids(1:1), yatt_title, yatt, ivar_id, nf90_double,1)
    ENDIF
  ELSE
    jret = nf90_inq_varid(nid_nc,hrec,ivar_id)
    CALL write_datax1_nc(idimlen(1),indims)
  ENDIF
ELSE
  IF (ldef) THEN
    IF (nrank==npio) THEN
      CALL def_var_netcdf( hselect, nid_nc, hrec, hrec, idimids(1:2), yatt_title, yatt, ivar_id, nf90_double)
    ENDIF 
  ELSE  
    jret = nf90_inq_varid(nid_nc,hrec,ivar_id)
    CALL write_datax1_nc(idimlen(1)*idimlen(2),indims)
  ENDIF
ENDIF
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX1_NC',1,zhook_handle)
!
CONTAINS
!
SUBROUTINE write_datax1_nc(KDIM,KNDIMS)
!
USE modd_surf_par, ONLY : xundef
!
USE modi_gather_and_write_mpi
USE modi_unpack_same_rank
USE modi_handle_err
!
USE netcdf
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: KDIM
INTEGER, INTENT(IN) :: KNDIMS
!
REAL, DIMENSION(KDIM) :: ZTAB1D
REAL, DIMENSION(KDIM) :: ZWORK_IGN
!
INTEGER, DIMENSION(2) :: ISTART, ICOUNT
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX1_NC:WRITE_DATAX1_NC',0,zhook_handle)
!
ztab1d(:) = xundef
!
IF (hdir=='-') THEN
  IF (nrank==npio) ztab1d(1:SIZE(pfield)) = pfield(:)
ELSEIF(.NOT.ALLOCATED(nmask_ign))THEN
  IF (lmask) THEN
    CALL gather_and_write_mpi(pfield,ztab1d,nmask)
  ELSE 
    CALL gather_and_write_mpi(pfield,ztab1d)
  ENDIF
ELSE
  !ign grid 
  IF (lmask) THEN
    CALL gather_and_write_mpi(pfield,zwork_ign(1:SIZE(nmask_ign)),nmask)
  ELSE 
    CALL gather_and_write_mpi(pfield,zwork_ign(1:SIZE(nmask_ign)))
  ENDIF
  CALL unpack_same_rank(nmask_ign,zwork_ign(1:SIZE(nmask_ign)),ztab1d)
ENDIF
!
IF (nrank==npio) THEN
  istart(:) = 1
  icount(:) = idimlen(1:2)
  iret(5)=nf90_put_var(nid_nc,ivar_id,ztab1d,istart,icount)
  CALL handle_err(iret(5),hrec) 
ENDIF

!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX1_NC:WRITE_DATAX1_NC',1,zhook_handle)
!
END SUBROUTINE write_datax1_nc
!
END SUBROUTINE write_surfx1_nc
!
!     #############################################################
      SUBROUTINE write_surfx2_nc ( HSELECT, HREC,PFIELD,KRESP,HCOMMENT,HDIR,HNAM_DIM)
!     #############################################################
!
!!****  *WRITEX2* - routine to fill a real 2D array for the externalised surface 
!
!
!
!
USE modd_surfex_mpi, ONLY : nrank, npio, nproc, ncomm
!
USE modd_io_surf_nc, ONLY : nid_nc, lmask, nmask, nmask_ign, ldef
!
USE modi_io_buff
!
USE modi_def_var_netcdf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),    INTENT(IN) :: HREC     ! name of the article to be read
REAL, DIMENSION(:,:), INTENT(IN) :: PFIELD   ! array containing the data field
INTEGER,              INTENT(OUT):: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),   INTENT(IN) :: HCOMMENT
 CHARACTER(LEN=1),     INTENT(IN) :: HDIR     ! type of field :
                                             ! 'H' : field with
                                             !       horizontal spatial dim.
                                             ! '-' : no horizontal dim.
 CHARACTER(LEN=*), OPTIONAL,  INTENT(IN) :: HNAM_DIM                                              
!*      0.2   Declarations of local variables
!
INTEGER :: IRET0
LOGICAL :: GFOUND
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT
INTEGER, DIMENSION(3) :: IDIMIDS
INTEGER, DIMENSION(3) :: IDIMLEN
 CHARACTER(LEN=100)    :: YNAME
 CHARACTER(LEN=18)     :: YNAM_DIM
INTEGER               :: IVAR_ID, JDIM, INDIMS
INTEGER               :: JRET
INTEGER               :: INFOMPI
INTEGER, DIMENSION(5) :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX2_NC',0,zhook_handle)
!
kresp = 0
!
iret(:) = 0
!
indims = 0
idimlen(:) = 0
yname = ""
kresp=0
!
 CALL io_buff(hrec,'W',gfound)
!
yatt_title(1) = "comment"
yatt(1) = hcomment
!
IF (gfound .AND. lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX2_NC',1,zhook_handle)
IF (gfound) RETURN
!
IF (PRESENT(hnam_dim)) THEN
  ynam_dim = hnam_dim
ELSE
  ynam_dim = "Number_of_Patches"
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (nid_nc /= 0) THEN 
    !    
    ! 0. find filename
    ! -----------------
    !
    iret(1) = nf90_inquire(nid_nc,ndimensions=indims)
    IF ( trim(ynam_dim) == "Nemis_snap" ) THEN
      iret(2) = nf90_inq_dimid(nid_nc,"Nsnap_temp",idimids(1))
    ELSE
      iret(2) = nf90_inq_dimid(nid_nc,"Number_of_points",idimids(1))
    ENDIF
    IF (iret(2)==0) THEN
      iret(3) = nf90_inq_dimid(nid_nc,trim(ynam_dim),idimids(2))
    ELSE
      iret(2) = nf90_inq_dimid(nid_nc,'lon',idimids(1))
      IF (iret(2)/=0) THEN
        iret(2) = nf90_inq_dimid(nid_nc,'xx',idimids(1))
        iret(3) = nf90_inq_dimid(nid_nc,'yy',idimids(2))
      ELSE
        iret(3) = nf90_inq_dimid(nid_nc,'lat',idimids(2))
      ENDIF
      iret(4) = nf90_inq_dimid(nid_nc,trim(ynam_dim),idimids(3))
      iret0=nf90_inquire_dimension(nid_nc,idimids(3),len=idimlen(3))
    ENDIF           
    DO jdim=1,2
      iret0=nf90_inquire_dimension(nid_nc,idimids(jdim),len=idimlen(jdim))
    ENDDO
    !
    iret(5)=nf90_inquire_dimension(nid_nc,idimids(1),name=yname)
    !
    DO jret=1,5
      IF (iret0==0 .OR. iret(jret).NE.nf90_noerr) kresp=1
    ENDDO
    !
  ELSE
    indims = 0
    idimids(:) = 0
    idimlen(:) = 0
    yname = ""
  ENDIF
  !
ELSE
  indims = 0
  idimids(:) = 0
  idimlen(:) = SIZE(pfield,2)
  yname = ""        
ENDIF
!
#ifdef SFX_MPI
IF (nproc>1) THEN
  CALL mpi_bcast(yname,len(yname),mpi_character,npio,ncomm,infompi)
  CALL mpi_bcast(indims,kind(indims)/4,mpi_integer,npio,ncomm,infompi)
  CALL mpi_bcast(idimlen,kind(idimlen)*SIZE(idimlen)/4,mpi_integer,npio,ncomm,infompi)
ENDIF
#endif
!
IF (yname .NE. 'lon' .AND. yname .NE. 'xx') THEN
  IF (ldef) THEN
    IF (nrank==npio) THEN
      CALL def_var_netcdf( hselect, &
                        nid_nc, hrec, hrec, idimids(1:2), yatt_title, yatt, ivar_id, nf90_double)
    ENDIF
  ELSE
    jret = nf90_inq_varid(nid_nc,hrec,ivar_id)
    CALL write_datax2_nc(idimlen(1),idimlen(2),indims)
  ENDIF
ELSE
  IF (ldef) THEN
    IF (nrank==npio) THEN
      CALL def_var_netcdf( hselect, &
                        nid_nc, hrec, hrec, idimids(1:3), yatt_title, yatt, ivar_id, nf90_double)
    ENDIF
  ELSE
    jret = nf90_inq_varid(nid_nc,hrec,ivar_id)
    CALL write_datax2_nc(idimlen(1)*idimlen(2),idimlen(3),indims)
  ENDIF
ENDIF
!
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX2_NC',1,zhook_handle)
!
CONTAINS
!
SUBROUTINE write_datax2_nc(KDIM1,KDIM2,KNDIMS)
!
USE modd_surf_par, ONLY : xundef
!
USE modi_gather_and_write_mpi
USE modi_unpack_same_rank
USE modi_handle_err
!
USE netcdf
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: KDIM1
INTEGER, INTENT(IN) :: KDIM2
INTEGER, INTENT(IN) :: KNDIMS
!
REAL, DIMENSION(KDIM1,KDIM2) :: ZTAB2D    ! work array read in the file
REAL, DIMENSION(KDIM1,SIZE(PFIELD,2)) :: ZWORK_IGN ! work array read in the file
!
INTEGER, DIMENSION(3) :: ISTART, ICOUNT
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX2_NC:WRITE_DATAX2_NC',0,zhook_handle)
!
ztab2d = xundef
!
IF (hdir=='-') THEN
  IF (nrank==npio) ztab2d(1:SIZE(pfield,1),1:SIZE(pfield,2)) = pfield(:,:)
ELSEIF(.NOT.ALLOCATED(nmask_ign))THEN
  IF (lmask) THEN
    CALL gather_and_write_mpi(pfield,ztab2d(:,1:SIZE(pfield,2)),nmask)
  ELSE 
    CALL gather_and_write_mpi(pfield,ztab2d(:,1:SIZE(pfield,2)))
  ENDIF
ELSE
  !ign grid 
  IF (lmask) THEN
    CALL gather_and_write_mpi(pfield,zwork_ign(1:SIZE(nmask_ign),:),nmask)
  ELSE 
    CALL gather_and_write_mpi(pfield,zwork_ign(1:SIZE(nmask_ign),:))
  ENDIF
  CALL unpack_same_rank(nmask_ign,zwork_ign(1:SIZE(nmask_ign),:),ztab2d(:,1:SIZE(pfield,2)))
ENDIF
!
IF (nrank==npio) THEN
  istart(:) = 1
  icount(:) = idimlen(1:3)
  iret(5)=nf90_put_var(nid_nc,ivar_id,ztab2d,istart,icount)
  CALL handle_err(iret(5),hrec)  
ENDIF
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX2_NC:WRITE_DATAX2_NC',1,zhook_handle)
!
END SUBROUTINE write_datax2_nc
!
END SUBROUTINE write_surfx2_nc
!
!     #############################################################
      SUBROUTINE write_surfx3_nc ( HSELECT, HREC,PFIELD,KRESP,HCOMMENT,HDIR,HNAM_DIM)
!     #############################################################
!
!!****  *WRITEX2* - routine to fill a real 2D array for the externalised surface 
!
!
!
!
USE modd_surfex_mpi, ONLY : nrank, npio, nproc, ncomm
!
USE modd_io_surf_nc, ONLY : nid_nc, lmask, nmask, nmask_ign, ldef
!
USE modi_io_buff
!
USE modi_def_var_netcdf
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),    INTENT(IN) :: HREC     ! name of the article to be read
REAL, DIMENSION(:,:,:), INTENT(IN) :: PFIELD   ! array containing the data field
INTEGER,              INTENT(OUT):: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),   INTENT(IN) :: HCOMMENT
 CHARACTER(LEN=1),     INTENT(IN) :: HDIR     ! type of field :
                                             ! 'H' : field with
                                             !       horizontal spatial dim.
                                             ! '-' : no horizontal dim.
 CHARACTER(LEN=*), OPTIONAL,  INTENT(IN) :: HNAM_DIM                                              
!*      0.2   Declarations of local variables
!
INTEGER :: IRET0
LOGICAL :: GFOUND
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT
INTEGER, DIMENSION(4) :: IDIMIDS
INTEGER, DIMENSION(4) :: IDIMLEN
 CHARACTER(LEN=100)    :: YNAME
 CHARACTER(LEN=18)     :: YNAM_DIM
INTEGER               :: IVAR_ID, JDIM, INDIMS
INTEGER               :: JRET
INTEGER               :: INFOMPI
INTEGER, DIMENSION(5) :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX3_NC',0,zhook_handle)
!
kresp = 0
!
iret(:) = 0
!
indims = 0
idimlen(:) = 0
yname = ""
kresp=0
!
 CALL io_buff(hrec,'W',gfound)
!
yatt_title(1) = "comment"
yatt(1) = hcomment
!
IF (gfound .AND. lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX3_NC',1,zhook_handle)
IF (gfound) RETURN
!
IF (PRESENT(hnam_dim)) THEN
  ynam_dim = hnam_dim
ELSE
  CALL abor1_sfx("WRITE_SURFX3_NC: TO WRITE A 3D FIELD, HNAM_DIM IS NEEDED")
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (nid_nc /= 0) THEN 
    !    
    ! 0. find filename
    ! -----------------
    !
    iret(1) = nf90_inquire(nid_nc,ndimensions=indims)
    iret(2) = nf90_inq_dimid(nid_nc,"Number_of_points",idimids(1))
    IF (iret(2)==0) THEN
      iret(3) = nf90_inq_dimid(nid_nc,trim(ynam_dim),idimids(2))
      iret(4) = nf90_inq_dimid(nid_nc,"Number_of_Patches",idimids(3))
    ELSE
      iret(2) = nf90_inq_dimid(nid_nc,'lon',idimids(1))
      IF (iret(2)/=0) THEN
        iret(2) = nf90_inq_dimid(nid_nc,'xx',idimids(1))
        iret(3) = nf90_inq_dimid(nid_nc,'yy',idimids(2))
      ELSE
        iret(3) = nf90_inq_dimid(nid_nc,'lat',idimids(2))
      ENDIF
      iret(4) = nf90_inq_dimid(nid_nc,trim(ynam_dim),idimids(3))
      iret0=nf90_inquire_dimension(nid_nc,idimids(3),len=idimlen(3))
      iret(5) = nf90_inq_dimid(nid_nc,"Number_of_Patches",idimids(4))
      iret0=nf90_inquire_dimension(nid_nc,idimids(4),len=idimlen(4))
    ENDIF           
    DO jdim=1,2
      iret0=nf90_inquire_dimension(nid_nc,idimids(jdim),len=idimlen(jdim))
    ENDDO
    !
    iret(5)=nf90_inquire_dimension(nid_nc,idimids(1),name=yname)
    !
    DO jret=1,5
      IF (iret0==0 .OR. iret(jret).NE.nf90_noerr) kresp=1
    ENDDO
    !
  ELSE
    indims = 0
    idimids(:) = 0
    idimlen(:) = 0
    yname = ""
  ENDIF
  !
ELSE
  indims = 0
  idimids(:) = 0
  idimlen(:) = SIZE(pfield,2)
  yname = ""        
ENDIF
!
#ifdef SFX_MPI
IF (nproc>1) THEN
  CALL mpi_bcast(yname,len(yname),mpi_character,npio,ncomm,infompi)
  CALL mpi_bcast(indims,kind(indims)/4,mpi_integer,npio,ncomm,infompi)
  CALL mpi_bcast(idimlen,kind(idimlen)*SIZE(idimlen)/4,mpi_integer,npio,ncomm,infompi)
ENDIF
#endif
!
IF (yname .NE. 'lon' .AND. yname .NE. 'xx') THEN
  IF (ldef) THEN
    IF (nrank==npio) THEN
      CALL def_var_netcdf( hselect, &
                        nid_nc, hrec, hrec, idimids(1:3), yatt_title, yatt, ivar_id, nf90_double)
    ENDIF
  ELSE
    jret = nf90_inq_varid(nid_nc,hrec,ivar_id)
    CALL write_datax3_nc(idimlen(1),idimlen(2),idimlen(3),indims)
  ENDIF
ELSE
  IF (ldef) THEN
    IF (nrank==npio) THEN
      CALL def_var_netcdf( hselect, &
                        nid_nc, hrec, hrec, idimids(1:4), yatt_title, yatt, ivar_id, nf90_double)
    ENDIF
  ELSE
    jret = nf90_inq_varid(nid_nc,hrec,ivar_id)
    CALL write_datax3_nc(idimlen(1)*idimlen(2),idimlen(3),idimlen(4),indims)
  ENDIF
ENDIF
!
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX2_NC',1,zhook_handle)
!
CONTAINS
!
SUBROUTINE write_datax3_nc(KDIM1,KDIM2,KDIM3,KNDIMS)
!
USE modd_surf_par, ONLY : xundef
!
USE modi_gather_and_write_mpi
USE modi_unpack_same_rank
USE modi_handle_err
!
USE netcdf
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: KDIM1
INTEGER, INTENT(IN) :: KDIM2
INTEGER, INTENT(IN) :: KDIM3
INTEGER, INTENT(IN) :: KNDIMS
!
REAL, DIMENSION(KDIM1,KDIM2,KDIM3) :: ZTAB3D    ! work array read in the file
REAL, DIMENSION(KDIM1,SIZE(PFIELD,2),SIZE(PFIELD,3)) :: ZWORK_IGN ! work array read in the file
!
INTEGER, DIMENSION(4) :: ISTART, ICOUNT
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX2_NC:WRITE_DATAX2_NC',0,zhook_handle)
!
ztab3d = xundef
!
IF (hdir=='-') THEN
  IF (nrank==npio) ztab3d(1:SIZE(pfield,1),1:SIZE(pfield,2),1:SIZE(pfield,3)) = pfield(:,:,:)
ELSEIF(.NOT.ALLOCATED(nmask_ign))THEN
  IF (lmask) THEN
    CALL gather_and_write_mpi(pfield,ztab3d(:,1:SIZE(pfield,2),1:SIZE(pfield,3)),nmask)
  ELSE 
    CALL gather_and_write_mpi(pfield,ztab3d(:,1:SIZE(pfield,2),1:SIZE(pfield,3)))
  ENDIF
ELSE
  !ign grid 
  IF (lmask) THEN
    CALL gather_and_write_mpi(pfield,zwork_ign(1:SIZE(nmask_ign),:,:),nmask)
  ELSE 
    CALL gather_and_write_mpi(pfield,zwork_ign(1:SIZE(nmask_ign),:,:))
  ENDIF
  CALL unpack_same_rank(nmask_ign,zwork_ign(1:SIZE(nmask_ign),:,:),ztab3d(:,1:SIZE(pfield,2),1:SIZE(pfield,3)))
ENDIF
!
IF (nrank==npio) THEN
  istart(:) = 1
  icount(:) = idimlen(1:4)        
  iret(5)=nf90_put_var(nid_nc,ivar_id,ztab3d,istart,icount)
  CALL handle_err(iret(5),hrec)  
ENDIF
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFX3_NC:WRITE_DATAX3_NC',1,zhook_handle)
!
END SUBROUTINE write_datax3_nc
!
END SUBROUTINE write_surfx3_nc
!
!     #############################################################
      SUBROUTINE write_surfn1_nc ( HSELECT, HREC,KFIELD,KRESP,HCOMMENT,HDIR,HNAM_DIM)
!     #############################################################
!
!!****  *WRITEN0* - routine to read an integer
!
!
!
!
USE modd_surfex_mpi, ONLY : nrank, npio, nproc, ncomm
!
USE modd_io_surf_nc, ONLY : nid_nc, lmask, nmask, nmask_ign, cfileout_nc, ldef
!
USE modi_def_var_netcdf
!
USE modi_io_buff
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),      INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:),  INTENT(IN)  :: KFIELD   ! the integer scalar to be read
INTEGER,                INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),     INTENT(IN)  :: HCOMMENT
 CHARACTER(LEN=1),       INTENT(IN) :: HDIR     ! type of field :
                                               ! 'H' : field with
                                               !       horizontal spatial dim.
                                               ! '-' : no horizontal dim.
 CHARACTER(LEN=*), OPTIONAL,  INTENT(IN) :: HNAM_DIM  
! 
!*      0.2   Declarations of local variables
!
INTEGER :: IRET0
LOGICAL :: GFOUND
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT
INTEGER, DIMENSION(2) :: IDIMIDS
INTEGER, DIMENSION(2) :: IDIMLEN
 CHARACTER(LEN=100)    :: YNAME
 CHARACTER(LEN=16)     :: YNAM_DIM
INTEGER               :: IVAR_ID, JDIM
INTEGER               :: JRET
INTEGER               :: INFOMPI
INTEGER,DIMENSION(5)  :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN1_NC',0,zhook_handle)
!
kresp = 0
!
iret(:) = 0
!
yatt_title(1) = "comment"
yatt(1) = hcomment
!
IF (PRESENT(hnam_dim)) THEN
  ynam_dim = hnam_dim
ELSE
  ynam_dim = "Number_of_points"
ENDIF
!
!
idimlen(:) = 0
yname = ""
kresp=0
!
 CALL io_buff(hrec,'W',gfound)
!
IF (gfound .AND. lhook) CALL dr_hook("WRITE_SURF_NC:WRITE_SURFN1_NC",1,zhook_handle)
IF (gfound) RETURN
!
IF (nrank==npio) THEN 
  !
  IF (nid_nc /= 0) THEN
    !
    ! 0. find filename
    ! -----------------
    !
    iret(2) = nf90_inq_dimid(nid_nc,trim(ynam_dim),idimids(1))
    IF (iret(2)/=0) THEN
      iret(2) = nf90_inq_dimid(nid_nc,'lon',idimids(1))
      IF (iret(2)/=0) THEN
        iret(2) = nf90_inq_dimid(nid_nc,'xx',idimids(1))
        iret(3) = nf90_inq_dimid(nid_nc,'yy',idimids(2))
      ELSE
        iret(3) = nf90_inq_dimid(nid_nc,'lat',idimids(2))
      ENDIF
      iret0=nf90_inquire_dimension(nid_nc,idimids(2),len=idimlen(2))
    ENDIF
    iret0=nf90_inquire_dimension(nid_nc,idimids(1),len=idimlen(1))
    !
    iret(4)=nf90_inquire_dimension(nid_nc,idimids(1),name=yname)
    !
    DO jret=1,4
      IF (iret0==0 .OR. iret(jret).NE.nf90_noerr) kresp=1
    ENDDO
    !
  ELSE
    idimids(:) = 0
    idimlen(:) = 0
    yname = ""    
  ENDIF
  !
ELSE
  idimids(:) = 0
  idimlen(:) = 0
  yname = ""    
ENDIF
!
#ifdef SFX_MPI
IF (nproc>1) THEN
  CALL mpi_bcast(yname,len(yname),mpi_character,npio,ncomm,infompi)
  CALL mpi_bcast(idimlen,kind(idimlen)*SIZE(idimlen)/4,mpi_integer,npio,ncomm,infompi)  
ENDIF
#endif
!
IF (yname.NE.'lon' .AND. yname.NE.'xx') THEN
  IF (ldef) THEN
    IF (nrank==npio) THEN
      CALL def_var_netcdf(hselect, nid_nc, hrec, hrec, idimids(1:1), yatt_title, yatt, ivar_id, nf90_int)
    ENDIF
  ELSE
    jret = nf90_inq_varid(nid_nc,hrec,ivar_id)
    CALL write_datan1_nc(idimlen(1))
  ENDIF
ELSE
  IF (ldef) THEN
    IF (nrank==npio) THEN
      CALL def_var_netcdf(hselect, nid_nc, hrec, hrec, idimids(1:2), yatt_title, yatt, ivar_id, nf90_int)
    ENDIF  
  ELSE
    jret = nf90_inq_varid(nid_nc,hrec,ivar_id)    
    CALL write_datan1_nc(idimlen(1)*idimlen(2))
  ENDIF
ENDIF
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN1_NC',1,zhook_handle)
!
CONTAINS
!
SUBROUTINE write_datan1_nc(KDIM)
!
USE modd_surf_par, ONLY : nundef
!
USE modi_gather_and_write_mpi
USE modi_unpack_same_rank
USE modi_handle_err
!
USE netcdf
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: KDIM
!
INTEGER, DIMENSION(KDIM) :: ITAB1D
INTEGER, DIMENSION(KDIM) :: IWORK_IGN
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN1_NC:WRITE_DATAN1_NC',0,zhook_handle)
!
itab1d(:) = nundef
!
IF (hdir=='-') THEN
  IF ( nrank==npio ) itab1d(1:SIZE(kfield)) = kfield(:)
ELSEIF(.NOT.ALLOCATED(nmask_ign))THEN
  IF (lmask) THEN
    CALL gather_and_write_mpi(kfield,itab1d,nmask)
  ELSE 
    CALL gather_and_write_mpi(kfield,itab1d)
  ENDIF
ELSE
  !ign grid 
  IF (lmask) THEN
    CALL gather_and_write_mpi(kfield,iwork_ign(1:SIZE(nmask_ign)),nmask)
  ELSE 
    CALL gather_and_write_mpi(kfield,iwork_ign(1:SIZE(nmask_ign)))
  ENDIF
  CALL unpack_same_rank(nmask_ign,iwork_ign(1:SIZE(nmask_ign)),itab1d)
ENDIF
!
IF (nrank==npio) THEN 
  iret(5)=nf90_put_var(nid_nc,ivar_id,itab1d)
  CALL handle_err(iret(5),hrec)  
ENDIF
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN1_NC:WRITE_DATAN1_NC',1,zhook_handle)
!
END SUBROUTINE write_datan1_nc
!
END SUBROUTINE write_surfn1_nc
!

!     #############################################################
      SUBROUTINE write_surfn2_nc ( HSELECT, HREC,KFIELD,KRESP,HCOMMENT,HDIR,HNAM_DIM)
!     #############################################################
!
!!****  *WRITEN0* - routine to read an integer
!
!
!
!
USE modd_surfex_mpi, ONLY : nrank, npio, nproc, ncomm
!
USE modd_io_surf_nc, ONLY : nid_nc, lmask, nmask, nmask_ign, ldef
!
USE modi_io_buff
!
USE modi_def_var_netcdf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),      INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:,:),  INTENT(IN)  :: KFIELD   ! the integer scalar to be read
INTEGER,                INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),     INTENT(IN)  :: HCOMMENT
 CHARACTER(LEN=1),       INTENT(IN) :: HDIR     ! type of field :
                                               ! 'H' : field with
                                               !       horizontal spatial dim.
                                               ! '-' : no horizontal dim.
 CHARACTER(LEN=*), OPTIONAL,  INTENT(IN) :: HNAM_DIM                                                 
!*      0.2   Declarations of local variables
!
INTEGER :: IRET0
LOGICAL :: GFOUND
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT
INTEGER, DIMENSION(3) :: IDIMIDS
INTEGER, DIMENSION(3) :: IDIMLEN
 CHARACTER(LEN=100)    :: YNAME
 CHARACTER(LEN=16)     :: YNAM_DIM
INTEGER               :: IVAR_ID, JDIM, INDIMS
INTEGER               :: JRET
INTEGER               :: INFOMPI
INTEGER, DIMENSION(5) :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN2_NC',0,zhook_handle)
!
kresp = 0
!
iret(:) = 0
!
indims = 0
idimlen(:) = 0
yname = ""
kresp=0
!
 CALL io_buff(hrec,'W',gfound)
!
yatt_title(1) = "comment"
yatt(1) = hcomment
!
IF (gfound .AND. lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN2_NC',1,zhook_handle)
IF (gfound) RETURN
!
IF (PRESENT(hnam_dim)) THEN
  ynam_dim = hnam_dim
ELSE
  ynam_dim = "Number_of_points"
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (nid_nc /= 0) THEN 
    !    
    ! 0. find filename
    ! -----------------
    !
    iret(1) = nf90_inquire(nid_nc,ndimensions=indims)
    iret(2) = nf90_inq_dimid(nid_nc,trim(ynam_dim),idimids(1))
    IF (iret(2)==0) THEN
      iret(3) = nf90_inq_dimid(nid_nc,'Number_of_Tile',idimids(2))
    ELSE
      iret(2) = nf90_inq_dimid(nid_nc,'lon',idimids(1))
      IF (iret(2)/=0) THEN
        iret(2) = nf90_inq_dimid(nid_nc,'xx',idimids(1))
        iret(3) = nf90_inq_dimid(nid_nc,'yy',idimids(2))
      ELSE
        iret(3) = nf90_inq_dimid(nid_nc,'lat',idimids(2))
      ENDIF
      iret(4) = nf90_inq_dimid(nid_nc,'Number_of_Tile',idimids(3))
      iret0=nf90_inquire_dimension(nid_nc,idimids(3),len=idimlen(3))
    ENDIF           
    DO jdim=1,2
      iret0=nf90_inquire_dimension(nid_nc,idimids(jdim),len=idimlen(jdim))
    ENDDO
    !
    iret(5)=nf90_inquire_dimension(nid_nc,idimids(1),name=yname)
    !
    DO jret=1,5
      IF (iret0==0 .OR. iret(jret).NE.nf90_noerr) kresp=1
    ENDDO
    !
  ELSE
    indims = 0
    idimids(:) = 0
    idimlen(:) = 0
    yname = ""
  ENDIF
  !
ELSE
  indims = 0
  idimids(:) = 0
  idimlen(:) = SIZE(kfield,2)
  yname = ""        
ENDIF
!
#ifdef SFX_MPI
IF (nproc>1) THEN
  CALL mpi_bcast(yname,len(yname),mpi_character,npio,ncomm,infompi)
  CALL mpi_bcast(indims,kind(indims)/4,mpi_integer,npio,ncomm,infompi)
  CALL mpi_bcast(idimlen,kind(idimlen)*SIZE(idimlen)/4,mpi_integer,npio,ncomm,infompi)  
ENDIF
#endif
!
IF (yname .NE. 'lon' .AND. yname .NE. 'xx') THEN
  IF (ldef) THEN
    IF (nrank==npio) THEN
      CALL def_var_netcdf(hselect, nid_nc, hrec, hrec, idimids(1:2), yatt_title, yatt, ivar_id, nf90_int)
    ENDIF
  ELSE
    jret = nf90_inq_varid(nid_nc,hrec,ivar_id)
    CALL write_datan2_nc(idimlen(1),idimlen(2),indims)
  ENDIF
ELSE
  IF (ldef) THEN
    IF (nrank==npio) THEN
      CALL def_var_netcdf(hselect, nid_nc, hrec, hrec, idimids(1:3), yatt_title, yatt, ivar_id, nf90_int)
    ENDIF 
  ELSE
    jret = nf90_inq_varid(nid_nc,hrec,ivar_id)    
    CALL write_datan2_nc(idimlen(1)*idimlen(2),idimlen(3),indims)
  ENDIF
ENDIF
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN2_NC',1,zhook_handle)
!
CONTAINS
!
SUBROUTINE write_datan2_nc(KDIM1,KDIM2,KNDIMS)
!
USE modd_surf_par, ONLY : nundef
!
USE modi_gather_and_write_mpi
USE modi_unpack_same_rank
USE modi_handle_err
!
USE netcdf
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: KDIM1
INTEGER, INTENT(IN) :: KDIM2
INTEGER, INTENT(IN) :: KNDIMS
!
INTEGER, DIMENSION(KDIM1,KDIM2) :: ITAB2D    ! work array read in the file
INTEGER, DIMENSION(KDIM1,KDIM2) :: IWORK_IGN ! work array read in the file
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN2_NC:WRITE_DATAN2_NC',0,zhook_handle)
!
itab2d(:,:) = nundef
!
IF(.NOT.ALLOCATED(nmask_ign))THEN
  IF (lmask) THEN
    CALL gather_and_write_mpi(kfield,itab2d(:,1:SIZE(kfield,2)),nmask)
  ELSE 
    CALL gather_and_write_mpi(kfield,itab2d(:,1:SIZE(kfield,2)))
  ENDIF
ELSE
  !ign grid 
  IF (lmask) THEN
    CALL gather_and_write_mpi(kfield,iwork_ign(1:SIZE(nmask_ign),:),nmask)
  ELSE 
    CALL gather_and_write_mpi(kfield,iwork_ign(1:SIZE(nmask_ign),:))
  ENDIF
  CALL unpack_same_rank(nmask_ign,iwork_ign(1:SIZE(nmask_ign),:),itab2d(:,1:SIZE(kfield,2)))
ENDIF
!
IF (nrank==npio) THEN
  iret(5)=nf90_put_var(nid_nc,ivar_id,itab2d)
  CALL handle_err(iret(5),hrec)  
ENDIF
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFN2_NC:WRITE_DATAN2_NC',1,zhook_handle)
!
END SUBROUTINE write_datan2_nc
!
END SUBROUTINE write_surfn2_nc
!
!     #############################################################
      SUBROUTINE write_surfl1_nc ( HSELECT, HREC,OFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *WRITEL1* - routine to read a logical array
!
!
!
!
USE modd_surfex_mpi, ONLY : nrank, npio
!
USE modd_io_surf_nc, ONLY : nid_nc, lmask, nmask, nmask_ign, ldef
!
USE modi_io_buff
!
USE modi_def_var_netcdf
!
USE modi_handle_err
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=*),      INTENT(IN) :: HREC     ! name of the article to be read
LOGICAL, DIMENSION(:), INTENT(IN) :: OFIELD   ! array containing the data field
INTEGER,               INTENT(OUT):: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),    INTENT(IN) :: HCOMMENT
 CHARACTER(LEN=1),      INTENT(IN) :: HDIR     ! type of field :
                                              ! 'H' : field with
                                              !       horizontal spatial dim.
                                              ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
LOGICAL :: GFOUND
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT
INTEGER, DIMENSION(1) :: IDIMIDS
INTEGER, DIMENSION(1) :: IDIMLEN
INTEGER               :: IVAR_ID, JDIM, INDIMS
INTEGER               :: JRET
INTEGER, DIMENSION(3) :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFL1_NC',0,zhook_handle)
!
iret(:) = 0
!
yatt_title(1) = "comment"
yatt(1) = hcomment
!
kresp=0
!
 CALL io_buff(hrec,'W',gfound)
IF (gfound .AND. lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFL1_NC',1,zhook_handle)
IF (gfound) RETURN
!
IF (nid_nc /= 0) THEN 
  !
  IF (nrank==npio) THEN
    !
    ! 0. find filename
    ! -----------------
    !
    IF (hrec(1:2)=='L_') THEN
      iret(1) = nf90_inq_dimid(nid_nc,'Nb_of_input_data',idimids(1))
    ELSE
      iret(1) = nf90_inq_dimid(nid_nc,'Number_of_covers',idimids(1))
    ENDIF
    iret(2) = nf90_inquire_dimension(nid_nc,idimids(1),len=idimlen(1))
    !
    IF (ldef) THEN
      CALL def_var_netcdf(hselect, nid_nc, hrec, hrec, idimids(1:1), yatt_title, yatt, ivar_id, nf90_char, 1)
    !
    ELSE
      jret = nf90_inq_varid(nid_nc, hrec, ivar_id)
      CALL write_datal1_nc(idimlen(1))
    ENDIF
    !
  ENDIF
  !
ENDIF
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFL1_NC',1,zhook_handle)
!
CONTAINS
!
SUBROUTINE write_datal1_nc(KDIM)
!
INTEGER, INTENT(IN) :: KDIM
!
 CHARACTER(LEN=1), DIMENSION(KDIM) :: YTAB1D  ! work array read in the file
INTEGER, DIMENSION(1) :: ISTART, ICOUNT
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFL1_NC:WRITE_DATAL1_NC',0,zhook_handle)
!
ytab1d(:) = ""
!
DO jret=1,min(SIZE(ofield),SIZE(ytab1d))
  IF (ofield(jret)) THEN
    ytab1d(jret) ='T'
  ELSE
    ytab1d(jret) ='F'
  ENDIF
ENDDO  
!
! 2. Put variable
!-----------------
istart(1) = 1
icount(1) = kdim
iret(3)=nf90_put_var(nid_nc,ivar_id,ytab1d,istart,icount)
!
 CALL handle_err(iret(3),hrec)
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFL1_NC:WRITE_DATAL1_NC',1,zhook_handle)
END SUBROUTINE write_datal1_nc
!
END SUBROUTINE write_surfl1_nc
!
!
!     #############################################################
      SUBROUTINE write_surft0_nc ( HSELECT, HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *WRITET0* - routine to read a NETCDF  date_time scalar
!
!
!
!
USE modd_io_surf_nc, ONLY : nid_nc, lmask, nmask, nmask_ign, ldef
!
USE modi_io_buff
!
USE modi_def_var_netcdf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),  INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER,            INTENT(IN)  :: KYEAR    ! year
INTEGER,            INTENT(IN)  :: KMONTH   ! month
INTEGER,            INTENT(IN)  :: KDAY     ! day
REAL,               INTENT(IN)  :: PTIME    ! time
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(IN)  :: HCOMMENT
!
!*      0.2   Declarations of local variables
!
LOGICAL :: GFOUND
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT
INTEGER, DIMENSION(0) :: IDIMIDS
 CHARACTER(LEN=12) :: YRECFM    ! Name of the article to be written
INTEGER :: IVAR_ID, JRET, JWRK
INTEGER :: JLEN
INTEGER,DIMENSION(4) :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFT0_NC',0,zhook_handle)
!
kresp=0
!
yatt_title(1) = "comment"
yatt(1) = hcomment
!
 CALL io_buff(hrec,'W',gfound)
IF (gfound .AND. lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFT0_NC',1,zhook_handle)
IF (gfound) RETURN
!
DO jwrk=1,4
  !
  IF (jwrk == 1) THEN 
    yrecfm = trim(hrec)//'-YEAR'
  ELSEIF (jwrk == 2) THEN
    yrecfm = trim(hrec)//'-MONTH'
  ELSEIF (jwrk == 3) THEN
    yrecfm = trim(hrec)//'-DAY'
  ELSEIF (jwrk == 4) THEN
    yrecfm=trim(hrec)//'-TIME'
  ENDIF
  ! 0. find filename
  ! -----------------
  !
  IF (nid_nc /= 0) THEN
    !
    !
    IF (jwrk==1) THEN
      IF (ldef) THEN
        CALL def_var_netcdf(hselect, nid_nc, yrecfm, yrecfm, idimids, yatt_title, yatt, ivar_id,nf90_int)
      ELSE
        jret = nf90_inq_varid(nid_nc,yrecfm,ivar_id)
        iret(jwrk)=nf90_put_var(nid_nc,ivar_id,kyear)
      ENDIF
    ELSEIF (jwrk==2) THEN
      IF (ldef) THEN    
        CALL def_var_netcdf(hselect, nid_nc, yrecfm, yrecfm, idimids, yatt_title, yatt, ivar_id,nf90_int)
      ELSE
        jret = nf90_inq_varid(nid_nc,yrecfm,ivar_id)        
        iret(jwrk)=nf90_put_var(nid_nc,ivar_id,kmonth)
      ENDIF        
    ELSEIF (jwrk==3) THEN
      IF (ldef) THEN    
        CALL def_var_netcdf(hselect, nid_nc, yrecfm, yrecfm, idimids, yatt_title, yatt, ivar_id,nf90_int)
      ELSE
        jret = nf90_inq_varid(nid_nc,yrecfm,ivar_id)        
        iret(jwrk)=nf90_put_var(nid_nc,ivar_id,kday)
      ENDIF        
    ELSEIF (jwrk==4) THEN
      IF (ldef) THEN    
        CALL def_var_netcdf(hselect, nid_nc, yrecfm, yrecfm, idimids, yatt_title, yatt, ivar_id,nf90_double)
      ELSE
        jret = nf90_inq_varid(nid_nc,yrecfm,ivar_id)        
        iret(jwrk)=nf90_put_var(nid_nc,ivar_id,ptime)
      ENDIF        
    ENDIF
  ENDIF
ENDDO
!
! 3. Check for errors
!--------------------
DO jret=1,4
  IF (nid_nc==0.OR.iret(jret).NE.nf90_noerr) kresp=1
ENDDO
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFT0_NC',1,zhook_handle)
!
END SUBROUTINE write_surft0_nc
!
!     #############################################################
      SUBROUTINE    write_surft1_nc ( HSELECT, HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *WRITET0* - routine to read a NETCDF  date_time scalar
!
USE modd_io_surf_nc, ONLY : nid_nc, lmask, nmask, nmask_ign
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),  INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:), INTENT(IN)  :: KYEAR    ! year
INTEGER, DIMENSION(:), INTENT(IN)  :: KMONTH   ! month
INTEGER, DIMENSION(:), INTENT(IN)  :: KDAY     ! day
REAL, DIMENSION(:), INTENT(IN)  :: PTIME    ! time
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(IN)  :: HCOMMENT
!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=100)    :: YNAME
 CHARACTER(LEN=12) :: YRECFM    ! Name of the article to be written
INTEGER :: JRET, JWRK, IDIMID
INTEGER,DIMENSION(4) :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFT1_NC',0,zhook_handle)
!
kresp=0
!
DO jwrk=1,4
  !
  IF (jwrk == 1) THEN 
    yrecfm = trim(hrec)//'-YEAR'
  ELSEIF (jwrk == 2) THEN
    yrecfm = trim(hrec)//'-MONTH'
  ELSEIF (jwrk == 3) THEN
    yrecfm = trim(hrec)//'-DAY'
  ELSEIF (jwrk == 4) THEN
    yrecfm=trim(hrec)//'-TIME'
  ENDIF
  !
  jret = nf90_inq_dimid(nid_nc,'Number_of_dates ',idimid)
  !
  IF (jret==0) THEN
    IF (jwrk==1) THEN
      CALL write_surfn1_nc(hselect, yrecfm,kyear,iret(jwrk),hcomment,'-','Number_of_dates ')
    ELSEIF (jwrk==2) THEN
      CALL write_surfn1_nc(hselect, yrecfm,kmonth,iret(jwrk),hcomment,'-','Number_of_dates ')
    ELSEIF (jwrk==3) THEN
      CALL write_surfn1_nc(hselect, yrecfm,kday,iret(jwrk),hcomment,'-','Number_of_dates ')
    ELSEIF (jwrk==4) THEN
      CALL write_surfx1_nc(hselect, yrecfm,ptime,iret(jwrk),hcomment,'-','Number_of_dates ')
    ENDIF
  ELSE
    IF (jwrk==1) THEN
      CALL write_surfn1_nc(hselect, yrecfm,kyear,iret(jwrk),hcomment,'-')
    ELSEIF (jwrk==2) THEN
      CALL write_surfn1_nc(hselect, yrecfm,kmonth,iret(jwrk),hcomment,'-')
    ELSEIF (jwrk==3) THEN
      CALL write_surfn1_nc(hselect, yrecfm,kday,iret(jwrk),hcomment,'-')
    ELSEIF (jwrk==4) THEN
      CALL write_surfx1_nc(hselect, yrecfm,ptime,iret(jwrk),hcomment,'-')
    ENDIF
  ENDIF    
  !
ENDDO
!
! 3. Check for errors
!--------------------
DO jret=1,4
  IF (nid_nc==0.OR.iret(jret).NE.nf90_noerr) kresp=1
ENDDO
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFT1_NC',1,zhook_handle)
!
END SUBROUTINE write_surft1_nc
!
!     #############################################################
      SUBROUTINE    write_surft2_nc ( HSELECT, HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *WRITET0* - routine to read a NETCDF  date_time scalar
!
USE modd_io_surf_nc, ONLY : nid_nc, lmask, nmask, nmask_ign
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT
!
 CHARACTER(LEN=12),  INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:,:), INTENT(IN)  :: KYEAR    ! year
INTEGER, DIMENSION(:,:), INTENT(IN)  :: KMONTH   ! month
INTEGER, DIMENSION(:,:), INTENT(IN)  :: KDAY     ! day
REAL, DIMENSION(:,:),    INTENT(IN)  :: PTIME    ! time
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(IN)  :: HCOMMENT
!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=100)    :: YNAME
 CHARACTER(LEN=12) :: YRECFM    ! Name of the article to be written
INTEGER :: JRET, JWRK, IDIMID
INTEGER,DIMENSION(4) :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFT2_NC',0,zhook_handle)
!
kresp=0
!
DO jwrk=1,4
  !
  IF (jwrk == 1) THEN 
    yrecfm = trim(hrec)//'-YEAR'
  ELSEIF (jwrk == 2) THEN
    yrecfm = trim(hrec)//'-MONTH'
  ELSEIF (jwrk == 3) THEN
    yrecfm = trim(hrec)//'-DAY'
  ELSEIF (jwrk == 4) THEN
    yrecfm=trim(hrec)//'-TIME'
  ENDIF
  !
  jret = nf90_inq_dimid(nid_nc,'Number_of_dates ',idimid)
  !
  IF (jret==0) THEN
    IF (jwrk==1) THEN
      CALL write_surfn2_nc(hselect, yrecfm,kyear,iret(jwrk),hcomment,'-','Number_of_dates ')
    ELSEIF (jwrk==2) THEN
      CALL write_surfn2_nc(hselect, yrecfm,kmonth,iret(jwrk),hcomment,'-','Number_of_dates ')
    ELSEIF (jwrk==3) THEN
      CALL write_surfn2_nc(hselect, yrecfm,kday,iret(jwrk),hcomment,'-','Number_of_dates ')
    ELSEIF (jwrk==4) THEN
      CALL write_surfx2_nc(hselect, yrecfm,ptime,iret(jwrk),hcomment,'-','Number_of_dates ')
    ENDIF
  ELSE
    IF (jwrk==1) THEN
      CALL write_surfn2_nc(hselect, yrecfm,kyear,iret(jwrk),hcomment,'-')
    ELSEIF (jwrk==2) THEN
      CALL write_surfn2_nc(hselect, yrecfm,kmonth,iret(jwrk),hcomment,'-')
    ELSEIF (jwrk==3) THEN
      CALL write_surfn2_nc(hselect, yrecfm,kday,iret(jwrk),hcomment,'-')
    ELSEIF (jwrk==4) THEN
      CALL write_surfx2_nc(hselect, yrecfm,ptime,iret(jwrk),hcomment,'-')
    ENDIF
  ENDIF          
  !
ENDDO
!
! 3. Check for errors
!--------------------
DO jret=1,4
  IF (nid_nc==0.OR.iret(jret).NE.nf90_noerr) kresp=1
ENDDO
!
IF (lhook) CALL dr_hook('MODE_WRITE_SURF_NC:WRITE_SURFT2_NC',1,zhook_handle)
!
END SUBROUTINE write_surft2_nc
!
END MODULE mode_write_surf_nc