mode_read_surf_nc.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
MODULE mode_read_surf_nc
!
!!    PURPOSE
!!    -------
!
!       The purpose of READ_SURF_NC is
!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!     
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!
!!      F. Habets      *METEO-FRANCE*
!!
!!    MODIFICATIONS
!!    -------------
!!
!!      original                                                     01/08/03
!----------------------------------------------------------------------------
!
INTERFACE read_surf0_nc
      SUBROUTINE read_surfx0_nc(HREC,PFIELD,KRESP,HCOMMENT)
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
REAL,               INTENT(OUT) :: PFIELD   ! the real scalar to be read
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment
END SUBROUTINE read_surfx0_nc
      SUBROUTINE read_surfn0_nc(HREC,KFIELD,KRESP,HCOMMENT)
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER,            INTENT(OUT) :: KFIELD   ! the integer scalar to be read
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment
END SUBROUTINE read_surfn0_nc
      SUBROUTINE read_surfc0_nc(HREC,HFIELD,KRESP,HCOMMENT)
 CHARACTER(LEN=*),   INTENT(IN)  :: HREC     ! name of the article to be read
 CHARACTER(LEN=40),   INTENT(OUT) :: HFIELD   ! the integer scalar to be read
INTEGER,             INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),  INTENT(OUT) :: HCOMMENT ! comment
END SUBROUTINE read_surfc0_nc
      SUBROUTINE read_surfl0_nc(HREC,OFIELD,KRESP,HCOMMENT)
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
LOGICAL,                  INTENT(OUT) :: OFIELD   ! array containing the data field
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment
END SUBROUTINE read_surfl0_nc
END INTERFACE
INTERFACE read_surfn_nc
      SUBROUTINE read_surfx1_nc(HREC,PFIELD,KRESP,HCOMMENT,HDIR)
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
REAL, DIMENSION(:), INTENT(OUT) :: PFIELD   ! array containing the data field
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),   INTENT(IN)  :: HDIR     ! type of field :
END SUBROUTINE read_surfx1_nc
      SUBROUTINE read_surfx2_nc(HREC,PFIELD,KRESP,HCOMMENT,HDIR)
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
REAL, DIMENSION(:,:),     INTENT(OUT) :: PFIELD   ! array containing the data field
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),         INTENT(IN)  :: HDIR     ! type of field :
END SUBROUTINE read_surfx2_nc
      SUBROUTINE read_surfn1_nc(HREC,KFIELD,KRESP,HCOMMENT,HDIR)
 CHARACTER(LEN=*),      INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:), INTENT(OUT) :: KFIELD   ! the integer scalar to be read
INTEGER,                INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),     INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),       INTENT(IN)  :: HDIR     ! type of field :
END SUBROUTINE read_surfn1_nc
      SUBROUTINE read_surfn2_nc(HREC,KFIELD,KRESP,HCOMMENT,HDIR)
 CHARACTER(LEN=*),      INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:,:), INTENT(OUT) :: KFIELD   ! the integer scalar to be read
INTEGER,                INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),     INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),       INTENT(IN)  :: HDIR     ! type of field :
END SUBROUTINE read_surfn2_nc
      SUBROUTINE read_surfl1_nc(HREC,OFIELD,KRESP,HCOMMENT,HDIR)
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
LOGICAL, DIMENSION(:),   INTENT(OUT) :: OFIELD   ! array containing the data field
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),         INTENT(IN)  :: HDIR     ! type of field :
END SUBROUTINE read_surfl1_nc
END INTERFACE
INTERFACE read_surft_nc
      SUBROUTINE read_surft0_nc(HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER,                  INTENT(OUT) :: KYEAR    ! year
INTEGER,                  INTENT(OUT) :: KMONTH   ! month
INTEGER,                  INTENT(OUT) :: KDAY     ! day
REAL,                     INTENT(OUT) :: PTIME    ! time
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment
END SUBROUTINE read_surft0_nc
      SUBROUTINE read_surft1_nc(HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:),    INTENT(OUT) :: KYEAR    ! year
INTEGER, DIMENSION(:),    INTENT(OUT) :: KMONTH   ! month
INTEGER, DIMENSION(:),    INTENT(OUT) :: KDAY     ! day
REAL, DIMENSION(:),       INTENT(OUT) :: PTIME    ! time
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment
END SUBROUTINE read_surft1_nc
      SUBROUTINE read_surft2_nc(HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:,:),  INTENT(OUT) :: KYEAR    ! year
INTEGER, DIMENSION(:,:),  INTENT(OUT) :: KMONTH   ! month
INTEGER, DIMENSION(:,:),  INTENT(OUT) :: KDAY     ! day
REAL, DIMENSION(:,:),     INTENT(OUT) :: PTIME    ! time
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment
END SUBROUTINE read_surft2_nc

END INTERFACE
!
END MODULE mode_read_surf_nc
!
!     #############################################################
      SUBROUTINE read_surfx0_nc(HREC,PFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READX0* - routine to read a real scalar
!
USE modd_surf_par,   ONLY: xundef
!
USE modd_io_surf_nc, ONLY : nid_nc
!
USE modi_error_read_surf_nc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
REAL,               INTENT(OUT) :: PFIELD   ! the real scalar to be read
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment
!
!*      0.2   Declarations of local variables
!
REAL*4 :: ZFIELD
 CHARACTER(LEN=100) :: YFILE          ! filename
INTEGER            :: IVAR_ID,JRET,IVAL,ITYPE,INDIMS
INTEGER,DIMENSION(4) :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFX0_NC',0,zhook_handle)
!
kresp=0
hcomment = " "
!
IF (nid_nc.NE.0) THEN
  !       
  ! 1. Find id of the variable
  !----------------------------
  iret(1)=nf90_inq_varid(nid_nc,hrec,ivar_id)
  iret(1)=nf90_inquire_variable(nid_nc,ivar_id,xtype=itype)
  iret(1)=nf90_inquire_variable(nid_nc,ivar_id,ndims=indims)
  !  
  ! 2. Get variable
  !----------------------------
  IF (itype==nf90_double) THEN
    iret(2)=nf90_get_var(nid_nc,ivar_id,pfield)
  ELSEIF (itype==nf90_float) THEN
    iret(2)=nf90_get_var(nid_nc,ivar_id,zfield)
    pfield = zfield
  ENDIF
  !
  iret(3) = nf90_get_att(nid_nc,ivar_id,"comment",hcomment)
  !
ENDIF
!
! 3. Check for errors
!--------------------
DO jret=1,3
  IF ((pfield==xundef).OR.(nid_nc==0).OR.iret(jret).NE.nf90_noerr) THEN 
    pfield=xundef
    kresp=1
  ENDIF
ENDDO
!     
IF (kresp /=0) CALL error_read_surf_nc(hrec,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFX0_NC',1,zhook_handle)
!
END SUBROUTINE read_surfx0_nc
!
!     #############################################################
      SUBROUTINE read_surfx1_nc(HREC,PFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READX1* - routine to fill a real 1D array for the externalised surface 
!
USE modd_surfex_mpi, ONLY : nrank, npio, xtime_npio_read, nproc, ncomm, &
                                 xtime_npio_read, xtime_comm_read, nreq
!
USE modd_io_surf_nc, ONLY: lmask,nmask,nid_nc
!
USE modd_surf_par,   ONLY: xundef
!
USE modi_pack_same_rank
USE modi_error_read_surf_nc
USE modi_read_and_send_mpi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
REAL, DIMENSION(:), INTENT(OUT) :: PFIELD   ! array containing the data field
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),   INTENT(IN)  :: HDIR     ! type of field :
                                            ! 'H' : field with
                                            !       horizontal spatial dim.
                                            ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
#ifdef SFX_MPI
INTEGER, DIMENSION(MPI_STATUS_SIZE,NPROC-1) :: ISTATUS
#endif
 CHARACTER(LEN=100) :: YFILE,YOUT          ! Filename
 CHARACTER(LEN=100)    :: YNAME
INTEGER :: IL1, IVAR_ID,JRET,JDIM,INDIMS, ITYPE, INFOMPI
INTEGER, DIMENSION(2) :: ISTART, ICOUNT
INTEGER,DIMENSION(4) :: IDIMIDS,IDIMLEN
INTEGER,DIMENSION(4) :: IRET
!
REAL, DIMENSION(:), ALLOCATABLE :: ZWORK
REAL*4, DIMENSION(:), ALLOCATABLE :: ZTAB_1D4
DOUBLE PRECISION   :: XTIME0
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFX1_NC',0,zhook_handle)
!
il1 = SIZE(pfield)
!
kresp=0
hcomment = " "
!
hcomment = " "
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (hdir=='-') THEN
  ALLOCATE(zwork(il1))
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (nid_nc.NE.0) THEN
    !  
    ! 1. Find id of the variable
    !----------------------------
    iret(1)=nf90_inq_varid(nid_nc,hrec,ivar_id)
    iret(2)=nf90_inquire_variable(nid_nc,ivar_id,xtype=itype)
    !
    iret(3)=nf90_inquire_variable(nid_nc,ivar_id,ndims=indims)
    !
    IF ( indims>0 ) THEN
      !
      iret(4)=nf90_inquire_variable(nid_nc,ivar_id,dimids=idimids(1:indims))
      !
      idimlen(:) = 1.
      DO jdim=1,indims
        jret=nf90_inquire_dimension(nid_nc,idimids(jdim),len=idimlen(jdim))
      ENDDO
      iret(4)=nf90_inquire_dimension(nid_nc,idimids(1),name=yname)
      !
      IF (hdir/='-') THEN
        IF (trim(yname).NE.'Number_of_points') THEN
          ALLOCATE(zwork(idimlen(1)*idimlen(2)))
        ELSE
          ALLOCATE(zwork(idimlen(1)))
        ENDIF
      ENDIF
      !
      icount(1:indims) = idimlen(1:indims)
      !
    ELSE
      !
      ALLOCATE(zwork(1))
      icount(1) = 1
      !
    ENDIF
    !
    ! 2. Get variable
    !----------------------------
    istart(:) = 1
    IF (itype==nf90_double) THEN
      iret(1)=nf90_get_var(nid_nc,ivar_id,zwork,istart,icount)
    ELSEIF (itype==nf90_float) THEN
      ALLOCATE(ztab_1d4(SIZE(zwork)))
      iret(2)=nf90_get_var(nid_nc,ivar_id,ztab_1d4,istart,icount)
      zwork(:) = ztab_1d4(:)
      DEALLOCATE(ztab_1d4)
    ENDIF
    !
    iret(3) = nf90_get_att(nid_nc,ivar_id,"comment",hcomment)   
    !
  ENDIF
  !
  ! 3. Check for errors
  !--------------------
  DO jret=1,1
    IF ((nid_nc==0).OR.iret(jret).NE.nf90_noerr) THEN 
      zwork = xundef
      kresp=1
    ENDIF
  ENDDO
  !
  IF (kresp /=0) CALL error_read_surf_nc(hrec,kresp)
  !
ELSEIF (hdir/='-') THEN
  ALLOCATE(zwork(0))
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (hdir=='E') THEN
  IF ( nrank==npio ) THEN
    CALL pack_same_rank(nmask,zwork(:),pfield(:))
  ENDIF
ELSEIF (hdir=='A') THEN  ! no distribution on other tasks
  IF ( nrank==npio ) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
#endif
    pfield(:) = zwork(1:SIZE(pfield))
#ifdef SFX_MPI
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
ELSEIF (hdir=='-') THEN ! distribution of the total field on other tasks
#ifdef SFX_MPI
  IF (nproc>1) THEN
    xtime0 = mpi_wtime()
    CALL mpi_bcast(zwork,SIZE(zwork)*kind(zwork)/4,mpi_real,npio,ncomm,infompi)   
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
  ENDIF
#endif
  pfield(:) = zwork(1:SIZE(pfield))
ELSE
  IF (lmask) THEN
    CALL read_and_send_mpi(zwork,pfield,nmask)
  ELSE 
    CALL read_and_send_mpi(zwork,pfield)
  END IF
  !IF (NRANK==NPIO) THEN
  !  CALL MPI_WAITALL(NPROC-1,NREQ,ISTATUS,INFOMPI)
  !ENDIF  
ENDIF
!
DEALLOCATE(zwork)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFX1_NC',1,zhook_handle)
!
END SUBROUTINE read_surfx1_nc
!
!     #############################################################
      SUBROUTINE read_surfx2_nc(HREC,PFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READX2* - routine to fill a real 2D array for the externalised surface 
!
USE modd_surfex_mpi, ONLY: nrank, nproc, ncomm, npio, xtime_npio_read, xtime_comm_read, nreq
!
USE modd_io_surf_nc, ONLY: lmask,nmask,nid_nc
!
USE modd_surf_par,   ONLY: xundef
!
USE modi_error_read_surf_nc
USE modi_read_and_send_mpi
USE modi_pack_same_rank
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
REAL, DIMENSION(:,:),     INTENT(OUT) :: PFIELD   ! array containing the data field
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),         INTENT(IN)  :: HDIR     ! type of field :
                                                  ! 'H' : field with
                                                  !       horizontal spatial dim.
                                                  ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
#ifdef SFX_MPI
INTEGER, DIMENSION(MPI_STATUS_SIZE,NPROC-1) :: ISTATUS
#endif
 CHARACTER(LEN=100) :: YFILE,YOUT          ! filename
 CHARACTER(LEN=100)    :: YNAME 
INTEGER            :: IL1, IL2
INTEGER            :: IVAR_ID,JRET,JDIM, INDIMS,ITYPE, INFOMPI
INTEGER,DIMENSION(4) :: IDIMIDS,IDIMLEN
INTEGER, DIMENSION(3) :: ISTART, ICOUNT
INTEGER,DIMENSION(4) :: IRET
REAL, DIMENSION(:,:), ALLOCATABLE :: ZWORK2
REAL*4, DIMENSION(:,:), ALLOCATABLE :: ZTAB_2D4
DOUBLE PRECISION   :: XTIME0
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFX2_NC',0,zhook_handle)
!
il1 = SIZE(pfield,1)
il2 = SIZE(pfield,2)
!
kresp=0
hcomment = " "
!
hcomment = " "
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (hdir=='-') THEN
  ALLOCATE(zwork2(il1,il2))
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (nid_nc.NE.0) THEN
    !
    ! 1. Find id of the variable
    !----------------------------
    iret(1)=nf90_inq_varid(nid_nc,hrec,ivar_id)
    iret(2)=nf90_inquire_variable(nid_nc,ivar_id,xtype=itype)
    !
    iret(3)=nf90_inquire_variable(nid_nc,ivar_id,ndims=indims)
    iret(4)=nf90_inquire_variable(nid_nc,ivar_id,dimids=idimids(1:indims))
    idimlen(:) = 1.
    DO jdim=1,indims
      jret=nf90_inquire_dimension(nid_nc,idimids(jdim),len=idimlen(jdim))
    ENDDO
    !
    iret(4)=nf90_inquire_dimension(nid_nc,idimids(1),name=yname)    
    !
    IF (hdir/='-') THEN
      IF (trim(yname).NE.'Number_of_points') THEN
        ALLOCATE(zwork2(idimlen(1)*idimlen(2),idimlen(3)))
      ELSE
        ALLOCATE(zwork2(idimlen(1),idimlen(2)))
      ENDIF
    ENDIF
    !
    ! 2. Get variable
    !----------------------------
    !
    istart(:) = 1
    icount(:) = idimlen(1:3)    
    IF (itype==nf90_double) THEN
      iret(2)=nf90_get_var(nid_nc,ivar_id,zwork2,istart,icount)
    ELSEIF (itype==nf90_float) THEN
      ALLOCATE(ztab_2d4(SIZE(zwork2,1),SIZE(zwork2,2)))
      iret(2)=nf90_get_var(nid_nc,ivar_id,ztab_2d4,istart,icount)
      zwork2(:,:) = ztab_2d4(:,:)
      DEALLOCATE(ztab_2d4)
    ENDIF      
    !
    iret(3) = nf90_get_att(nid_nc,ivar_id,"comment",hcomment)  
    !
  ENDIF

  ! 3. Check for errors
  !--------------------
  DO jret=1,2
    IF ((nid_nc==0).OR.iret(jret).NE.nf90_noerr) THEN 
      zwork2 = xundef
      kresp=1
    ENDIF
  ENDDO
  !
  IF (kresp /=0) CALL error_read_surf_nc(hrec,kresp)
  !
ELSEIF (hdir/='-') THEN
  ALLOCATE(zwork2(1,SIZE(pfield,2)))
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (hdir=='E') THEN
  IF ( nrank==npio ) THEN
    CALL pack_same_rank(nmask,zwork2(:,:),pfield(:,:))
  ENDIF
ELSEIF (hdir=='A') THEN  ! no distribution on other tasks
  IF ( nrank==npio ) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
#endif
    pfield(:,:) = zwork2(:,1:SIZE(pfield,2))
#ifdef SFX_MPI
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
ELSEIF (hdir=='-') THEN ! distribution of the total field on other tasks
#ifdef SFX_MPI
  IF (nproc>1) THEN
    xtime0 = mpi_wtime()
    CALL mpi_bcast(zwork2,SIZE(zwork2)*kind(zwork2)/4,mpi_real,npio,ncomm,infompi)   
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
  ENDIF
#endif
  pfield(:,:) = zwork2(:,1:SIZE(pfield,2))
ELSE
  IF (lmask) THEN
    CALL read_and_send_mpi(zwork2(:,1:SIZE(pfield,2)),pfield,nmask)
  ELSE 
    CALL read_and_send_mpi(zwork2(:,1:SIZE(pfield,2)),pfield)
  END IF
  !IF (NRANK==NPIO) THEN
  !  CALL MPI_WAITALL(NPROC-1,NREQ,ISTATUS,INFOMPI)
  !ENDIF    
ENDIF
!
DEALLOCATE(zwork2)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFX2_NC',1,zhook_handle)
!
END SUBROUTINE read_surfx2_nc
!
!     #############################################################
      SUBROUTINE read_surfn0_nc(HREC,KFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READN0* - routine to read an integer
!
USE modd_surf_par,   ONLY: nundef
!
USE modd_io_surf_nc, ONLY : nid_nc
!
USE modi_error_read_surf_nc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER,            INTENT(OUT) :: KFIELD   ! the integer scalar to be read
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment
!
!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=100):: YFILE          ! filename
INTEGER :: IVAR_ID,JRET,JDIM,INDIMS
INTEGER,DIMENSION(4) :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFN0_NC',0,zhook_handle)
!
kresp=0
hcomment = " "
!
IF (nid_nc.NE.0) THEN
  !        
  ! 1. Find id of the variable
  !----------------------------
  iret(1)=nf90_inq_varid(nid_nc,hrec,ivar_id)
  !  
  ! 2. Get variable
  !----------------------------
  iret(2)=nf90_get_var(nid_nc,ivar_id,kfield)
  !
  iret(3)=nf90_get_att(nid_nc,ivar_id,"comment",hcomment)
  !
ENDIF
!
! 3. Check for errors
!--------------------
DO jret=1,2
  IF ((kfield==nundef).OR.(nid_nc==0).OR.iret(jret).NE.nf90_noerr) THEN 
    kfield=nundef
    kresp=1
  ENDIF
ENDDO
!
IF (kresp /=0)  CALL error_read_surf_nc(hrec,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFN0_NC',1,zhook_handle)
!
END SUBROUTINE read_surfn0_nc
!
!     #############################################################
      SUBROUTINE read_surfn1_nc(HREC,KFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READN0* - routine to read an integer
!
USE modd_surfex_mpi, ONLY : nrank, npio, xtime_npio_read, nproc, ncomm, &
                                 xtime_npio_read, xtime_comm_read
!
USE modd_io_surf_nc, ONLY: lmask,nmask,nid_nc
!
USE modd_surf_par,   ONLY: nundef
!
USE modi_error_read_surf_nc
USE modi_read_and_send_mpi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),      INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:), INTENT(OUT) :: KFIELD   ! the integer scalar to be read
INTEGER,                INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),     INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),       INTENT(IN)  :: HDIR     ! type of field :
                                                ! 'H' : field with
                                                !       horizontal spatial dim.
                                                ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
INTEGER, DIMENSION(:), ALLOCATABLE :: IWORK
 CHARACTER(LEN=100) :: YFILE,YOUT          ! Filename
 CHARACTER(LEN=100)    :: YNAME
INTEGER :: IL1, IVAR_ID,JRET,JDIM,INDIMS, ITYPE, INFOMPI
INTEGER,DIMENSION(4) :: IDIMIDS,IDIMLEN
INTEGER,DIMENSION(4) :: IRET
!
DOUBLE PRECISION   :: XTIME0
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFX1_NC',0,zhook_handle)
!
il1 = SIZE(kfield)
!
kresp=0
hcomment = " "
!
hcomment = " "
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (hdir=='-') THEN
  ALLOCATE(iwork(il1))
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (nid_nc.NE.0) THEN
    !  
    ! 1. Find id of the variable
    !----------------------------
    iret(1)=nf90_inq_varid(nid_nc,hrec,ivar_id)
    iret(2)=nf90_inquire_variable(nid_nc,ivar_id,xtype=itype)
    !
    IF (hdir=='A') THEN
      !
      ALLOCATE(iwork(il1))
      !
    ELSEIF (hdir/='-') THEN
      !    
      iret(3)=nf90_inquire_variable(nid_nc,ivar_id,ndims=indims)
      !
      IF ( indims>0 ) THEN
        !
        iret(4)=nf90_inquire_variable(nid_nc,ivar_id,dimids=idimids(1:indims))
        idimlen(:) = 1.
        DO jdim=1,indims
          jret=nf90_inquire_dimension(nid_nc,idimids(jdim),len=idimlen(jdim))
        ENDDO
        !
        iret(4)=nf90_inquire_dimension(nid_nc,idimids(1),name=yname)
        !
        IF (trim(yname).NE.'Number_of_points') THEN
          ALLOCATE(iwork(idimlen(1)*idimlen(2)))
        ELSE
          ALLOCATE(iwork(idimlen(1)))
        ENDIF
      ELSE
        !
        ALLOCATE(iwork(1))
        !
      ENDIF
      !
    ENDIF
    !
    ! 2. Get variable
    !----------------------------
    IF (itype==nf90_int) THEN
      iret(1)=nf90_get_var(nid_nc,ivar_id,iwork)
    ENDIF
    !  
    iret(2) = nf90_get_att(nid_nc,ivar_id,"comment",hcomment)
    !
  ENDIF
  !
  ! 3. Check for errors
  !--------------------
  DO jret=1,1
    IF ((nid_nc==0).OR.iret(jret).NE.nf90_noerr) THEN 
      iwork = nundef
      kresp=1
    ENDIF
  ENDDO
  !
  IF (kresp /=0) CALL error_read_surf_nc(hrec,kresp)
  !
ELSEIF (hdir/='-') THEN
  ALLOCATE(iwork(0))
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (hdir=='A') THEN  ! no distribution on other tasks
  IF ( nrank==npio ) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
#endif
    kfield(:) = iwork(1:SIZE(kfield))
#ifdef SFX_MPI
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
ELSEIF (hdir=='-') THEN ! distribution of the total field on other tasks
#ifdef SFX_MPI
  IF (nproc>1) THEN
    xtime0 = mpi_wtime()
    CALL mpi_bcast(iwork,SIZE(iwork)*kind(iwork)/4,mpi_integer,npio,ncomm,infompi)   
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
  ENDIF
#endif
  kfield(:) = iwork(1:SIZE(kfield))
ELSE
  IF (lmask) THEN
    CALL read_and_send_mpi(iwork,kfield,nmask)
  ELSE 
    CALL read_and_send_mpi(iwork,kfield)
  END IF
ENDIF
!
DEALLOCATE(iwork)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFN1_NC',1,zhook_handle)
!
END SUBROUTINE read_surfn1_nc
!
!     #############################################################
      SUBROUTINE read_surfn2_nc(HREC,KFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READN0* - routine to read an integer
!
USE modd_surfex_mpi, ONLY: nrank, nproc, ncomm, npio, xtime_npio_read, xtime_comm_read
!
USE modd_io_surf_nc, ONLY: lmask,nmask,nid_nc
!
USE modd_surf_par,   ONLY: nundef
!
USE modi_error_read_surf_nc
USE modi_read_and_send_mpi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),      INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:,:), INTENT(OUT) :: KFIELD   ! the integer scalar to be read
INTEGER,                INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),     INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),       INTENT(IN)  :: HDIR     ! type of field :
                                                ! 'H' : field with
                                                !       horizontal spatial dim.
                                                ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=100) :: YFILE,YOUT          ! filename
 CHARACTER(LEN=100)    :: YNAME 
INTEGER            ::  IL1, IL2, IVAR_ID,JRET,JDIM,INDIMS,ITYPE, INFOMPI
INTEGER,DIMENSION(4) :: IDIMIDS,IDIMLEN
INTEGER,DIMENSION(4) :: IRET
INTEGER, DIMENSION(:,:), ALLOCATABLE :: IWORK2
DOUBLE PRECISION   :: XTIME0
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFN2_NC',0,zhook_handle)
!
il1 = SIZE(kfield,1)
il2 = SIZE(kfield,2)
!
kresp=0
hcomment = " "
!
hcomment = " "
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (hdir=='-') THEN
  ALLOCATE(iwork2(il1,il2))
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (nid_nc.NE.0) THEN
    !   
    ! 1. Find id of the variable
    !----------------------------
    iret(1)=nf90_inq_varid(nid_nc,hrec,ivar_id)
    iret(2)=nf90_inquire_variable(nid_nc,ivar_id,xtype=itype)
    iret(3)=nf90_inquire_variable(nid_nc,ivar_id,ndims=indims)
    iret(4)=nf90_inquire_variable(nid_nc,ivar_id,dimids=idimids(1:indims))
    idimlen(:) = 1.
    DO jdim=1,indims
      jret=nf90_inquire_dimension(nid_nc,idimids(jdim),len=idimlen(jdim))
    ENDDO
    !
    iret(4)=nf90_inquire_dimension(nid_nc,idimids(1),name=yname)    
    ! 
    ! 2. Get variable
    !----------------------------
    IF (trim(yname).NE.'Number_of_points') THEN
      ALLOCATE(iwork2(idimlen(1)*idimlen(2),idimlen(3)))
    ELSE
      ALLOCATE(iwork2(idimlen(1),idimlen(2)))
    ENDIF
    !
    IF (itype==nf90_int) THEN
      iret(2)=nf90_get_var(nid_nc,ivar_id,iwork2)
    ENDIF      
    !
    iret(3) = nf90_get_att(nid_nc,ivar_id,"comment",hcomment)
  ENDIF

  ! 3. Check for errors
  !--------------------
  DO jret=1,2
    IF ((nid_nc==0).OR.iret(jret).NE.nf90_noerr) THEN 
      iwork2 = nundef
      kresp=1
    ENDIF
  ENDDO
  !
  !
  IF (kresp /=0) CALL error_read_surf_nc(hrec,kresp)
  !
ELSEIF (hdir/='-') THEN
  ALLOCATE(iwork2(0,0))
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (hdir=='A') THEN  ! no distribution on other tasks
  IF ( nrank==npio ) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
#endif
    kfield(:,:) = iwork2(:,:)
#ifdef SFX_MPI
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
ELSEIF (hdir=='-') THEN ! distribution of the total field on other tasks
#ifdef SFX_MPI
  IF (nproc>1) THEN
    xtime0 = mpi_wtime()
    CALL mpi_bcast(iwork2,SIZE(iwork2)*kind(iwork2)/4,mpi_integer,npio,ncomm,infompi)   
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
  ENDIF
#endif
  kfield(:,:) = iwork2(:,:)
ELSE
  IF (lmask) THEN
    CALL read_and_send_mpi(iwork2,kfield,nmask)
  ELSE 
    CALL read_and_send_mpi(iwork2,kfield)
  END IF
ENDIF
!
DEALLOCATE(iwork2) 
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFN2_NC',1,zhook_handle)
!
END SUBROUTINE read_surfn2_nc
!
!     #############################################################
      SUBROUTINE read_surfc0_nc(HREC,HFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READC0* - routine to read a STRING
!
USE modd_surf_par,   ONLY: xundef
!
USE modd_io_surf_nc, ONLY : nid_nc
!
USE modi_error_read_surf_nc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),   INTENT(IN)  :: HREC     ! name of the article to be read
 CHARACTER(LEN=40),   INTENT(OUT) :: HFIELD   ! the integer scalar to be read
INTEGER,             INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),  INTENT(OUT) :: HCOMMENT ! comment
!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=100):: YFILE          ! filename
 CHARACTER(LEN=40):: YFIELD   
INTEGER :: IVAR_ID,JRET,JDIM,INDIMS
INTEGER,DIMENSION(4) :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFC0_NC',0,zhook_handle)
!
kresp=0
hcomment = " "
!
IF (nid_nc.NE.0) THEN
  !       
  ! 1. Find id of the variable
  !----------------------------
  iret(1)=nf90_inq_varid(nid_nc,hrec,ivar_id)
  !  
  ! 2. Get variable
  !----------------------------
  iret(2)=nf90_get_var(nid_nc,ivar_id,yfield)
  hfield=yfield(:len_trim(yfield))
  !
  iret(3) = nf90_get_att(nid_nc,ivar_id,"comment",hcomment)
  !
ENDIF

! 3. Check for errors
!--------------------
DO jret=1,2
  IF ((nid_nc==0).OR.iret(jret).NE.nf90_noerr) THEN 
    kresp=1
  ENDIF
ENDDO  
!
IF (kresp /=0) CALL error_read_surf_nc(hrec,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFC0_NC',1,zhook_handle)
!
END SUBROUTINE read_surfc0_nc
!
!     #############################################################
      SUBROUTINE read_surfl0_nc(HREC,OFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READL0* - routine to read a logical
!    
USE modd_io_surf_nc, ONLY : nid_nc
!
USE modi_error_read_surf_nc
!
USE modd_surf_par,   ONLY: xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
LOGICAL,                  INTENT(OUT) :: OFIELD   ! array containing the data field
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment
!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=1)  :: YFIELD   ! work array read in the file
 CHARACTER(LEN=100) :: YFILE    ! Filename
INTEGER :: IVAR_ID,JRET
INTEGER,DIMENSION(3) :: IRET
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFL0_NC',0,zhook_handle)
!
kresp=0
hcomment = " "
!
IF (nid_nc.NE.0) THEN
  !       
  ! 1. Find id of the variable
  !----------------------------
  iret(1)=nf90_inq_varid(nid_nc,hrec,ivar_id)
  !  
  ! 2. Get variable
  !----------------------------
  iret(2)=nf90_get_var(nid_nc,ivar_id,yfield)
  !
  iret(3) = nf90_get_att(nid_nc,ivar_id,"comment",hcomment)
  !  
ENDIF
!  
IF (yfield =="T") ofield=.true.
IF (yfield =="F") ofield=.false.
!
! 3. Check for errors
!--------------------
IF ((nid_nc==0).OR.iret(1).NE.nf90_noerr) THEN 
  kresp=1
ENDIF
!
IF (kresp /=0)  CALL error_read_surf_nc(hrec,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFL0_NC',1,zhook_handle)
!
END SUBROUTINE read_surfl0_nc
!
!     #############################################################
      SUBROUTINE read_surfl1_nc(HREC,OFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READL1* - routine to read a logical array
!    
USE modd_surfex_mpi, ONLY : nrank, nproc, ncomm, npio, xtime_npio_read, xtime_comm_read
!
USE modd_io_surf_nc, ONLY : nid_nc
!
USE modi_error_read_surf_nc
!
USE modd_surf_par,   ONLY: xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
LOGICAL, DIMENSION(:),   INTENT(OUT) :: OFIELD   ! array containing the data field
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),         INTENT(IN)  :: HDIR     ! type of field :
                                                  ! 'H' : field with
                                                  !       horizontal spatial dim.
                                                  ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=100) :: YFILE          ! Filename
 CHARACTER(LEN=1), DIMENSION(:), ALLOCATABLE :: YTAB_1D  ! work array read in the file
!
INTEGER :: IVAR_ID,JRET,JDIM,INDIMS
INTEGER :: INFOMPI
INTEGER,DIMENSION(1) :: IDIMIDS,IDIMLEN,ISTART,ICOUNT
INTEGER,DIMENSION(2) :: IRET
INTEGER, DIMENSION(:),    POINTER     :: IMASK    ! 1D mask to read only interesting
DOUBLE PRECISION   :: XTIME0
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFL1_NC',0,zhook_handle)
!
!
kresp=0
hcomment = " "
!
hcomment = " "
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (nrank==npio) THEN
  !
  IF (nid_nc.NE.0) THEN
    !   
    ! 1. Find id of the variable
    !----------------------------
    iret(1)=nf90_inq_varid(nid_nc,hrec,ivar_id)
    iret(1)=nf90_inquire_variable(nid_nc,ivar_id,ndims=indims)
    iret(1)=nf90_inquire_variable(nid_nc,ivar_id,dimids=idimids)
    DO jdim=1,indims
      jret=nf90_inquire_dimension(nid_nc,idimids(jdim),len=idimlen(jdim))
    ENDDO
    IF ( indims>0 ) THEN
      ALLOCATE(ytab_1d(idimlen(1)))
      icount(1) = idimlen(1)
    ELSE
      ALLOCATE(ytab_1d(1))
      icount(1) = 1
    ENDIF
    !  
    ! 2. Get variable
    !----------------------------
    istart(1) = 1
    iret(1)=nf90_get_var(nid_nc,ivar_id,ytab_1d,istart,icount)
    !
    DO jret=1,min(SIZE(ofield),SIZE(ytab_1d))
      IF (ytab_1d(jret) =="T") ofield(jret)=.true.
      IF (ytab_1d(jret) =="F") ofield(jret)=.false.
    ENDDO
    !
    iret(2) = nf90_get_att(nid_nc,ivar_id,"comment",hcomment)
    !
  ENDIF
  !
  ! 3. Check for errors
  !--------------------
  DO jret=1,1
    IF ((nid_nc==0).OR.iret(jret).NE.nf90_noerr) THEN 
      kresp=1
    ENDIF
  ENDDO
  !
  DEALLOCATE(ytab_1d)
  !
  IF (kresp /=0) CALL error_read_surf_nc(hrec,kresp)
  !
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (nproc>1 .AND. hdir/='A') THEN
#ifdef SFX_MPI
  xtime0 = mpi_wtime()
  CALL mpi_bcast(ofield,SIZE(ofield),mpi_logical,npio,ncomm,infompi)
  xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
ENDIF
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFL1_NC',1,zhook_handle)
!
END SUBROUTINE read_surfl1_nc
!
!
!     #############################################################
      SUBROUTINE read_surft0_nc(HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READT0* - routine to read a NETCDF  date_time scalar
!
USE modd_io_surf_nc, ONLY : nid_nc
!
USE modi_error_read_surf_nc
!
USE modd_surf_par,   ONLY: xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER,                  INTENT(OUT) :: KYEAR    ! year
INTEGER,                  INTENT(OUT) :: KMONTH   ! month
INTEGER,                  INTENT(OUT) :: KDAY     ! day
REAL,                     INTENT(OUT) :: PTIME    ! time
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment

!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=18)  :: YRECFM    ! Name of the article to be written
 CHARACTER(LEN=100) :: YFILE          ! Filename
INTEGER :: IVAR_ID,JRET,JDIM,INDIMS,JWRK
INTEGER, DIMENSION(1) :: IDIMIDS,IDIMLEN
INTEGER, DIMENSION(5) :: IRET
INTEGER, DIMENSION(:), POINTER :: IMASK    ! 1D mask to read only interesting
REAL:: ZTIME
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFT0_NC',0,zhook_handle)
!
kresp=0
hcomment = " "
!
DO jwrk=1,4
  !
  IF (jwrk == 1) THEN 
    yrecfm=trim(hrec)//'-YEAR'
  ELSEIF (jwrk == 2) THEN
    yrecfm = trim(hrec)//'-MONTH'
  ELSEIF (jwrk == 3) THEN
    yrecfm = trim(hrec)//'-DAY'
  ELSEIF (jwrk == 4) THEN    
    yrecfm=trim(hrec)//'-TIME'
  ENDIF
! 0. find filename
  !
  IF (nid_nc.NE.0) THEN
    !   
    ! 1. Find id of the variable
    !----------------------------
    jret=nf90_inq_varid(nid_nc,yrecfm,ivar_id)
    !
    ! 2. Get variable
    !----------------------------
    IF (jwrk == 1) THEN 
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,kyear)
    ELSEIF (jwrk==2) THEN
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,kmonth)
    ELSEIF (jwrk==3) THEN
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,kday)
    ELSEIF (jwrk==4) THEN     
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,ptime)
    ENDIF
    !
    iret(5) = nf90_get_att(nid_nc,ivar_id,"comment",hcomment)
    !
  ENDIF
ENDDO
!
! 3. Check for errors
!--------------------
DO jret=1,4
  IF ((nid_nc==0).OR.iret(jret).NE.nf90_noerr) THEN 
    kresp=1
  ENDIF
ENDDO
IF (kresp /=0) CALL error_read_surf_nc(yrecfm,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFT0_NC',1,zhook_handle)
!
END SUBROUTINE read_surft0_nc
!
!     #############################################################
      SUBROUTINE read_surft1_nc(HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READT0* - routine to read a NETCDF  date_time scalar
!
USE modd_io_surf_nc, ONLY : nid_nc
!
USE modi_error_read_surf_nc
!
USE modd_surf_par,   ONLY: xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:),    INTENT(OUT) :: KYEAR    ! year
INTEGER, DIMENSION(:),    INTENT(OUT) :: KMONTH   ! month
INTEGER, DIMENSION(:),    INTENT(OUT) :: KDAY     ! day
REAL, DIMENSION(:),       INTENT(OUT) :: PTIME    ! time
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment

!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=18)  :: YRECFM    ! Name of the article to be written
 CHARACTER(LEN=100) :: YFILE          ! Filename
INTEGER :: IVAR_ID,JRET,JDIM,INDIMS,JWRK
INTEGER, DIMENSION(1) :: IDIMIDS,IDIMLEN
INTEGER, DIMENSION(5) :: IRET
INTEGER, DIMENSION(:), POINTER :: IMASK    ! 1D mask to read only interesting
REAL:: ZTIME
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFT1_NC',0,zhook_handle)
!
kresp=0
hcomment = " "
!
DO jwrk=1,4
  !
  IF (jwrk == 1) THEN 
    yrecfm=trim(hrec)//'-YEAR'
  ELSEIF (jwrk == 2) THEN
    yrecfm = trim(hrec)//'-MONTH'
  ELSEIF (jwrk == 3) THEN
    yrecfm = trim(hrec)//'-DAY'
  ELSEIF (jwrk == 4) THEN    
    yrecfm=trim(hrec)//'-TIME'
  ENDIF
! 0. find filename
  !
  IF (nid_nc.NE.0) THEN
    !   
    ! 1. Find id of the variable
    !----------------------------
    jret=nf90_inq_varid(nid_nc,yrecfm,ivar_id)
    !
    ! 2. Get variable
    !----------------------------
    IF (jwrk == 1) THEN 
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,kyear)
    ELSEIF (jwrk==2) THEN
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,kmonth)
    ELSEIF (jwrk==3) THEN
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,kday)
    ELSEIF (jwrk==4) THEN      
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,ptime)
    ENDIF
    !
    iret(5) = nf90_get_att(nid_nc,ivar_id,"comment",hcomment)
    !
  ENDIF
ENDDO
!
! 3. Check for errors
!--------------------
DO jret=1,4
  IF ((nid_nc==0).OR.iret(jret).NE.nf90_noerr) THEN 
    kresp=1
  ENDIF
ENDDO
IF (kresp /=0) CALL error_read_surf_nc(yrecfm,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFT1_NC',1,zhook_handle)
!
END SUBROUTINE read_surft1_nc
!
!     #############################################################
      SUBROUTINE read_surft2_nc(HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READT0* - routine to read a NETCDF  date_time scalar
!
USE modd_io_surf_nc, ONLY : nid_nc
!
USE modi_error_read_surf_nc
!
USE modd_surf_par,   ONLY: xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:,:),  INTENT(OUT) :: KYEAR    ! year
INTEGER, DIMENSION(:,:),  INTENT(OUT) :: KMONTH   ! month
INTEGER, DIMENSION(:,:),  INTENT(OUT) :: KDAY     ! day
REAL, DIMENSION(:,:),     INTENT(OUT) :: PTIME    ! time
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment

!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=18)  :: YRECFM    ! Name of the article to be written
 CHARACTER(LEN=100) :: YFILE          ! Filename
INTEGER :: IVAR_ID,JRET,JDIM,INDIMS,JWRK
INTEGER, DIMENSION(1) :: IDIMIDS,IDIMLEN
INTEGER, DIMENSION(5) :: IRET
INTEGER, DIMENSION(:), POINTER :: IMASK    ! 1D mask to read only interesting
REAL:: ZTIME
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFT2_NC',0,zhook_handle)
!
kresp=0
hcomment = " "
!
DO jwrk=1,4
  !
  IF (jwrk == 1) THEN 
    yrecfm=trim(hrec)//'-YEAR'
  ELSEIF (jwrk == 2) THEN
    yrecfm = trim(hrec)//'-MONTH'
  ELSEIF (jwrk == 3) THEN
    yrecfm = trim(hrec)//'-DAY'
  ELSEIF (jwrk == 4) THEN    
    yrecfm=trim(hrec)//'-TIME'
  ENDIF
! 0. find filename
  !
  IF (nid_nc.NE.0) THEN
    !   
    ! 1. Find id of the variable
    !----------------------------
    jret=nf90_inq_varid(nid_nc,yrecfm,ivar_id)
    !
    ! 2. Get variable
    !----------------------------
    IF (jwrk == 1) THEN 
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,kyear)
    ELSEIF (jwrk==2) THEN
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,kmonth)
    ELSEIF (jwrk==3) THEN
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,kday)
    ELSEIF (jwrk==4) THEN      
      iret(jwrk)=nf90_get_var(nid_nc,ivar_id,ptime)
    ENDIF
    !
    iret(5) = nf90_get_att(nid_nc,ivar_id,"comment",hcomment)
    !
  ENDIF
ENDDO
!
! 3. Check for errors
!--------------------
DO jret=1,4
  IF ((nid_nc==0).OR.iret(jret).NE.nf90_noerr) THEN 
    kresp=1
  ENDIF
ENDDO
IF (kresp /=0) CALL error_read_surf_nc(yrecfm,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_NC:READ_SURFT2_NC',1,zhook_handle)
!
END SUBROUTINE read_surft2_nc
!