mode_read_surf_lfi.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
MODULE mode_read_surf_lfi
!
#ifdef SFX_LFI
!
!!    PURPOSE
!!    -------
!
!       The purpose of READ_SURF_LFI is
!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!     
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!
!!      S.Malardel      *METEO-FRANCE*
!!
!!    MODIFICATIONS
!!    -------------
!!
!!      original                                                     01/08/03
!----------------------------------------------------------------------------
!
INTERFACE read_surf0_lfi
        MODULE PROCEDURE read_surfx0_lfi
        MODULE PROCEDURE read_surfn0_lfi
        MODULE PROCEDURE read_surfl0_lfi
        MODULE PROCEDURE read_surfc0_lfi
END INTERFACE
INTERFACE read_surfn_lfi
        MODULE PROCEDURE read_surfx1_lfi
        MODULE PROCEDURE read_surfn1_lfi
        MODULE PROCEDURE read_surfl1_lfi
        MODULE PROCEDURE read_surfx2_lfi
END INTERFACE
INTERFACE read_surft_lfi
        MODULE PROCEDURE read_surft0_lfi
        MODULE PROCEDURE read_surft1_lfi
        MODULE PROCEDURE read_surft2_lfi
END INTERFACE
!
CONTAINS
!
!     #############################################################
      SUBROUTINE read_surfx0_lfi(HREC,PFIELD,KRESP,HCOMMENT)
!     #############################################################
!
USE modd_io_surf_lfi,        ONLY : cfile_lfi, cluout_lfi
!
USE modi_fmread
USE modi_error_read_surf_lfi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*), INTENT(IN)  :: HREC     ! name of the article to be read
REAL,              INTENT(OUT) :: PFIELD   ! the real scalar to be read
INTEGER,           INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),INTENT(OUT) :: HCOMMENT ! comment
!
!*      0.2   Declarations of local variables
!
INTEGER          :: IGRID   ! position of data on grid
INTEGER          :: ILENCH  ! length of comment string
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX0_LFI',0,zhook_handle)
!
kresp=0
!
 CALL fmreadx0(cfile_lfi,hrec,cluout_lfi,1,pfield,igrid,ilench,hcomment,kresp)
!
 CALL error_read_surf_lfi(hrec,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX0_LFI',1,zhook_handle)
!
END SUBROUTINE read_surfx0_lfi
!
!     #############################################################
      SUBROUTINE read_surfx1_lfi(HREC,PFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READX1* - routine to fill a real 1D array for the externalised surface 
!
USE modd_surfex_mpi, ONLY : nrank, nproc, ncomm, npio, xtime_npio_read, xtime_comm_read, nreq
!
USE modd_io_surf_lfi, ONLY : cfile_lfi, cluout_lfi, nmask, nfull, &
                             lmnh_compatible  
!
USE modi_pack_same_rank
USE modi_fmread
USE modi_error_read_surf_lfi
USE modi_read_and_send_mpi
USE modi_get_surf_undef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),   INTENT(IN)  :: HREC     ! name of the article to be read
REAL, DIMENSION(:),  INTENT(OUT) :: PFIELD   ! array containing the data field
INTEGER,             INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),  INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),    INTENT(IN)  :: HDIR     ! type of field :
                                             ! 'H' : field with
                                             !       horizontal spatial dim.
                                             ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=18) :: YREC
REAL              :: ZUNDEF  ! default value
INTEGER           :: IGRID   ! position of data on grid
INTEGER           :: ILENCH  ! length of comment string
INTEGER           :: IVERSION, IBUGFIX
INTEGER           :: IL1, INFOMPI, JJ
!
REAL, DIMENSION(:), ALLOCATABLE :: ZWORK
#ifdef SFX_MPI
INTEGER, DIMENSION(MPI_STATUS_SIZE) :: ISTATUS
#endif
DOUBLE PRECISION   :: XTIME0
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI',0,zhook_handle)
!
il1 = SIZE(pfield)
!
kresp=0
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (hdir=='-') THEN
  ALLOCATE(zwork(il1))
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (hdir=='A') THEN
    ALLOCATE(zwork(il1))
  ELSEIF (hdir/='-') THEN
    ALLOCATE(zwork(nfull))
  ENDIF
  !
  yrec = hrec
  !
  !---------------------------------------------------------------------------
  !* patch to read some test files done before version 3.5
  !  this should be removed once all tests with reading lfi files done with 923
  !  configuration (with these early versions) are finished.
  !
  IF (hrec(1:2)=='D_') THEN
    CALL fmreadn0(cfile_lfi,'VERSION',cluout_lfi,1,iversion,igrid,ilench,hcomment,kresp)
    CALL fmreadn0(cfile_lfi,'BUG',cluout_lfi,1,ibugfix,igrid,ilench,hcomment,kresp)
    IF (iversion<=2 .OR. (iversion==3 .AND. ibugfix<=5)) yrec = 'DATA_'//hrec(3:12)
  END IF
  !---------------------------------------------------------------------------
  !
  IF (hdir=='H' .OR. hdir=='A' .OR. hdir=='E' .OR. &
      hrec=='XX' .OR. hrec=='YY'.OR. hrec=='DX' .OR. hrec=='DY') THEN  
    IF (.NOT. lmnh_compatible) THEN
      CALL fmreadx1(cfile_lfi,yrec,cluout_lfi,nfull,zwork,igrid,ilench,hcomment,kresp)
    ELSE
      CALL read_in_lfi_x1_for_mnh(yrec,zwork,kresp,hcomment,hdir)
    END IF
  ELSE
    CALL fmreadx1(cfile_lfi,yrec,cluout_lfi,il1,zwork,igrid,ilench,hcomment,kresp)
  END IF
  CALL error_read_surf_lfi(yrec,kresp)
  !
ELSEIF (hdir/='-') THEN
  ALLOCATE(zwork(0))
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (hdir=='E') THEN
  IF ( nrank==npio ) THEN
    CALL pack_same_rank(nmask,zwork(:),pfield(:))
  ENDIF
ELSEIF (hdir=='A') THEN  ! no distribution on other tasks
  IF ( nrank==npio ) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
#endif
    pfield(:) = zwork(1:il1)
#ifdef SFX_MPI
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
ELSEIF (hdir=='-') THEN ! distribution of the total field on other tasks
  IF (nproc>1) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
    CALL mpi_bcast(zwork,il1*kind(zwork)/4,mpi_real,npio,ncomm,infompi)
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
  pfield(:) = zwork(:)
ELSE
  CALL read_and_send_mpi(zwork,pfield,nmask)
  !IF (NRANK==NPIO) THEN
  !  CALL MPI_WAITALL(NPROC-1,NREQ,ISTATUS,INFOMPI)
  !ENDIF  
ENDIF
!
DEALLOCATE(zwork)
!
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI',1,zhook_handle)
!
CONTAINS
!
!     #############################################################
      SUBROUTINE read_in_lfi_x1_for_mnh(HREC,PFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  * - routine to fill a read 2D array for the externalised surface 
!
USE modd_io_surf_lfi,        ONLY : cfile_lfi, cluout_lfi, &
                                    niu, nib, nie, nju, njb, nje
!
USE modi_fmread
USE modi_error_read_surf_lfi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),        INTENT(IN) :: HREC     ! name of the article to be read
REAL, DIMENSION(:),     INTENT(OUT):: PFIELD   ! array containing the data field
INTEGER,                  INTENT(OUT):: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT):: HCOMMENT ! comment string
 CHARACTER(LEN=1),         INTENT(IN) :: HDIR     ! type of field :
                                                 ! 'H' : field with
                                                 !       horizontal spatial dim.
                                                 ! '-' : no horizontal dim.
!
!*      0.2   Declarations of local variables
! 
 CHARACTER(LEN=4)   :: YREC1D
INTEGER :: JI, JJ
INTEGER :: ILEN
INTEGER :: IGRID, ILENCH
REAL :: ZVAL
REAL, DIMENSION(:),   ALLOCATABLE :: ZWORK1D! 1D work array read in the file
REAL, DIMENSION(NIU,NJU) :: ZWORK2D ! work array read in a MNH file
REAL(KIND=JPRB) :: ZHOOK_HANDLE, ZHOOK_HANDLE_OMP
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_1',0,zhook_handle)
!
zwork2d(:,:) = 999.
!
IF (hrec=='XX                 ' .OR. hrec=='DX                 ') THEN
  ALLOCATE(zwork1d(niu))
  yrec1d = 'XHAT'
  ilen   = niu
ELSEIF (hrec=='YY                 ' .OR. hrec=='DY                 ') THEN
  ALLOCATE(zwork1d(nju))
  yrec1d = 'YHAT'
  ilen   = nju
ELSEIF (njb==nje) THEN
  ALLOCATE(zwork1d(niu))
  zwork1d(:) = 999.
ELSEIF (nib==nie) THEN
  ALLOCATE(zwork1d(nju))
  zwork1d(:) = 999. 
ENDIF
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_1',1,zhook_handle)
!
IF (hrec=='XX' .OR. hrec=='YY'.OR. hrec=='DX' .OR. hrec=='DY') THEN
  !
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_2',0,zhook_handle)
  CALL fmreadx1(cfile_lfi,yrec1d,cluout_lfi,ilen,zwork1d,igrid,ilench,hcomment,kresp)
  CALL error_read_surf_lfi(yrec1d,kresp)
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_2',1,zhook_handle)
  !
  SELECT CASE(hrec)
    CASE('XX                  ')
!$OMP PARALLEL PRIVATE(ZHOOK_HANDLE_OMP) 
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_31',0,zhook_handle_omp)
!$OMP DO PRIVATE(JI)    
      DO ji = nib,nie
        zwork2d(ji,:) = 0.5 * zwork1d(ji) + 0.5 * zwork1d(ji+1)
      ENDDO
!$OMP END DO
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_31',1,zhook_handle_omp)
!$OMP END PARALLEL
    CASE('DX                  ')
!$OMP PARALLEL PRIVATE(ZHOOK_HANDLE_OMP)
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_32',0,zhook_handle_omp)
!$OMP DO PRIVATE(JI)   
      DO ji = nib,nie
        zwork2d(ji,:) = - zwork1d(ji) + zwork1d(ji+1)
      ENDDO
!$OMP END DO 
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_32',1,zhook_handle_omp)
!$OMP END PARALLEL
    CASE('YY                  ')
!$OMP PARALLEL PRIVATE(ZHOOK_HANDLE_OMP) 
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_33',0,zhook_handle_omp)
!$OMP DO PRIVATE(JI)       
      DO jj = njb,nje
        zwork2d(:,jj) = 0.5 * zwork1d(jj) + 0.5 * zwork1d(jj+1)
      ENDDO
!$OMP END DO
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_33',1,zhook_handle_omp)
!$OMP END PARALLEL
    CASE('DY                  ')
!$OMP PARALLEL PRIVATE(ZHOOK_HANDLE_OMP) 
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_34',0,zhook_handle_omp)
!$OMP DO PRIVATE(JI)   
      DO jj = njb,nje
        zwork2d(:,jj) = - zwork1d(jj) + zwork1d(jj+1)
      ENDDO
!$OMP END DO 
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_34',1,zhook_handle_omp)
!$OMP END PARALLEL
  END SELECT
!
  DEALLOCATE(zwork1d)
!
ELSEIF (njb==nje) THEN
  !
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_41',0,zhook_handle)
  CALL fmreadx1(cfile_lfi,yrec,cluout_lfi,SIZE(zwork1d),zwork1d,igrid,ilench,hcomment,kresp)
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_41',1,zhook_handle)
  !
!$OMP PARALLEL PRIVATE(ZHOOK_HANDLE_OMP) 
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_42',0,zhook_handle_omp)
!$OMP DO PRIVATE(JI)  
  DO jj = 1,SIZE(zwork2d,2)
    zwork2d(nib:nie,jj) = zwork1d(nib:nie)
  END DO
!$OMP END DO
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_42',1,zhook_handle_omp)
!$OMP END PARALLEL
  !
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_43',0,zhook_handle)
  DEALLOCATE(zwork1d) 
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_43',1,zhook_handle)
  !
ELSEIF (nib==nie) THEN
  !
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_51',0,zhook_handle)
  CALL fmreadx1(cfile_lfi,yrec,cluout_lfi,SIZE(zwork1d),zwork1d,igrid,ilench,hcomment,kresp) 
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_51',1,zhook_handle)
  !
!$OMP PARALLEL PRIVATE(ZHOOK_HANDLE_OMP)
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_52',0,zhook_handle_omp)
!$OMP DO PRIVATE(JI)  
  DO ji = 1,SIZE(zwork2d,1)
    zwork2d(ji,njb:nje) = zwork1d(njb:nje)
  END DO
!$OMP END DO
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_52',1,zhook_handle_omp)
!$OMP END PARALLEL
!
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_53',0,zhook_handle)
  DEALLOCATE(zwork1d)
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_53',1,zhook_handle)
!
ELSE
  !
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_6',0,zhook_handle)
  CALL fmreadx2(cfile_lfi,hrec,cluout_lfi,SIZE(zwork2d),zwork2d,igrid,ilench,hcomment,kresp)
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_6',1,zhook_handle)
  !
ENDIF
!
!$OMP PARALLEL PRIVATE(ZHOOK_HANDLE_OMP) 
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_7',0,zhook_handle_omp)
!$OMP DO PRIVATE(JJ,JI)
DO jj=1,nje-njb+1
  DO ji=1,nie-nib+1
    pfield(ji+(nie-nib+1)*(jj-1)) = zwork2d(nib+ji-1,njb+jj-1) 
  END DO
END DO
!$OMP END DO
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_7',1,zhook_handle_omp)
!$OMP END PARALLEL
!  
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_8',0,zhook_handle)
 CALL error_read_surf_lfi(hrec,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX1_LFI:READ_IN_LFI_X1_FOR_MNH_8',1,zhook_handle)
!
END SUBROUTINE read_in_lfi_x1_for_mnh
!
END SUBROUTINE read_surfx1_lfi
!
!     #############################################################
      SUBROUTINE read_surfx2_lfi(HREC,PFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READX2* - routine to fill a real 2D array for the externalised surface 
!
USE modd_surfex_mpi, ONLY : nrank, nproc, ncomm, npio, xtime_npio_read, xtime_comm_read, nreq
!
USE modd_io_surf_lfi, ONLY : cfile_lfi, cluout_lfi, nmask, nfull, &
                             lmnh_compatible  
!
USE modi_pack_same_rank
USE modi_fmread
USE modi_error_read_surf_lfi
USE modi_read_and_send_mpi
USE modi_get_surf_undef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
REAL, DIMENSION(:,:),     INTENT(OUT) :: PFIELD   ! array containing the data field
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),         INTENT(IN)  :: HDIR     ! type of field :
                                                  ! 'H' : field with
                                                  !       horizontal spatial dim.
                                                  ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
! 
 CHARACTER(LEN=16) :: YREC
REAL              :: ZUNDEF  ! default value
INTEGER           :: IGRID   ! position of data on grid
INTEGER           :: ILENCH  ! length of comment string
INTEGER           :: IVERSION, IBUGFIX
INTEGER           :: IL1, IL2, INFOMPI, JJ
!
REAL, DIMENSION(:,:), ALLOCATABLE :: ZWORK2
#ifdef SFX_MPI
INTEGER, DIMENSION(MPI_STATUS_SIZE,NPROC-1) :: ISTATUS
#endif
DOUBLE PRECISION   :: XTIME0
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI',0,zhook_handle)
!
!
il1 = SIZE(pfield,1)
il2 = SIZE(pfield,2)
!
kresp=0
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (hdir=='-') THEN
  ALLOCATE(zwork2(il1,il2))
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (hdir=='A') THEN
    ALLOCATE(zwork2(il1,il2))
  ELSEIF (hdir/='-') THEN
    ALLOCATE(zwork2(nfull,il2))
  ENDIF
  !
  yrec = hrec
  !
  !---------------------------------------------------------------------------
  !* patch to read some test files done before version 3.5
  !  this should be removed once all tests with reading lfi files done with 923
  !  configuration (with these early versions) are finished.
  !
  IF (hrec(1:2)=='D_') THEN
    CALL fmreadn0(cfile_lfi,'VERSION',cluout_lfi,1,iversion,igrid,ilench,hcomment,kresp)
    CALL fmreadn0(cfile_lfi,'BUG',cluout_lfi,1,ibugfix,igrid,ilench,hcomment,kresp)
    IF (iversion<=2 .OR. (iversion==3 .AND. ibugfix<=5)) yrec = 'DATA_'//hrec(3:12)
    IF (yrec(13:15)=='SOI') yrec=yrec(1:15)//'L'
    IF (yrec(12:14)=='SOI') yrec=yrec(1:14)//'L'
  END IF
  !---------------------------------------------------------------------------
  !
  IF (hdir=='H' .OR. hdir=='A' .OR. hdir=='E') THEN
    IF (.NOT. lmnh_compatible) THEN
      CALL fmreadx2(cfile_lfi,yrec,cluout_lfi,SIZE(zwork2),zwork2(:,:),igrid,ilench,hcomment,kresp)
     ELSE
      CALL read_in_lfi_x2_for_mnh(yrec,zwork2,kresp,hcomment,hdir)
    END IF
  ELSE
    CALL fmreadx2(cfile_lfi,yrec,cluout_lfi,il1*il2,zwork2(:,:),igrid,ilench,hcomment,kresp)
  END IF
  CALL error_read_surf_lfi(yrec,kresp)
  !
ELSEIF (hdir/='-') THEN
  ALLOCATE(zwork2(0,0))
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (hdir=='E') THEN
  IF ( nrank==npio ) THEN
    CALL pack_same_rank(nmask,zwork2(:,:),pfield(:,:))
  ENDIF
ELSEIF (hdir=='A') THEN  ! no distribution on other tasks
  IF ( nrank==npio ) THEN    
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
#endif
    pfield(:,:) = zwork2(1:il1,:)
#ifdef SFX_MPI
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
ELSEIF (hdir=='-') THEN ! distribution of the total field on other tasks
  IF (nproc>1) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
    CALL mpi_bcast(zwork2,il1*il2*kind(zwork2)/4,mpi_real,npio,ncomm,infompi)
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
  pfield(:,:) = zwork2(1:il1,:)  
ELSE
  CALL read_and_send_mpi(zwork2,pfield,nmask)
  !IF (NRANK==NPIO) THEN
  !  CALL MPI_WAITALL(NPROC-1,NREQ,ISTATUS,INFOMPI)
  !ENDIF  
ENDIF
!
DEALLOCATE(zwork2)
!
IF (hdir=='H' .OR. hdir=='A') THEN
  CALL get_surf_undef(zundef)
  WHERE(pfield==999.) pfield=zundef
ENDIF
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI',1,zhook_handle)
!
CONTAINS
!
!     #############################################################
      SUBROUTINE read_in_lfi_x2_for_mnh(HREC,PFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  * - routine to fill a read 2D array for the externalised surface 
!
USE modd_io_surf_lfi,        ONLY : cfile_lfi, cluout_lfi, &
                                    niu, nib, nie, nju, njb, nje
!
USE modi_fmread
USE modi_error_read_surf_lfi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),        INTENT(IN) :: HREC     ! name of the article to be read
REAL, DIMENSION(:,:), INTENT(OUT):: PFIELD   ! array containing the data field
INTEGER,                  INTENT(OUT):: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT):: HCOMMENT ! comment string
 CHARACTER(LEN=1),         INTENT(IN) :: HDIR     ! type of field :
                                                 ! 'H' : field with
                                                 !       horizontal spatial dim.
                                                 ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
! 
INTEGER :: JI, JJ
INTEGER :: IGRID, ILENCH
REAL, DIMENSION(NIU,NJU,SIZE(PFIELD,2)):: ZWORK3D ! work array read in a MNH file
REAL, DIMENSION(:,:), ALLOCATABLE :: ZWORK2D
REAL(KIND=JPRB) :: ZHOOK_HANDLE, ZHOOK_HANDLE_OMP
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_1',0,zhook_handle)
!
zwork3d(:,:,:) = 999.
!
IF (njb==nje) THEN
  ALLOCATE(zwork2d(niu,SIZE(pfield,2)))
  zwork2d(:,:) = 999.
ELSEIF (nib==nie) THEN
  ALLOCATE(zwork2d(nju,SIZE(pfield,2)))
  zwork2d(:,:) = 999. 
ENDIF
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_1',1,zhook_handle)
!
IF (njb==nje) THEN
  !
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_21',0,zhook_handle)
  CALL fmreadx2(cfile_lfi,yrec,cluout_lfi,SIZE(zwork2d),zwork2d,igrid,ilench,hcomment,kresp)
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_21',1,zhook_handle)
  !
!$OMP PARALLEL PRIVATE(ZHOOK_HANDLE_OMP)
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_22',0,zhook_handle_omp)
!$OMP DO PRIVATE(JJ)  
  DO jj = 1,SIZE(zwork3d,2)
    zwork3d(nib:nie,jj,:) = zwork2d(nib:nie,:)
  END DO
!$OMP END DO
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_22',1,zhook_handle_omp)
!$OMP END PARALLEL
  !
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_23',0,zhook_handle)
  DEALLOCATE(zwork2d) 
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_23',1,zhook_handle)
  !
ELSEIF (nib==nie) THEN
  !
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_31',0,zhook_handle)
  CALL fmreadx2(cfile_lfi,yrec,cluout_lfi,SIZE(zwork2d),zwork2d,igrid,ilench,hcomment,kresp)
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_31',1,zhook_handle)
  !
!$OMP PARALLEL PRIVATE(ZHOOK_HANDLE_OMP)
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_32',0,zhook_handle_omp)
!$OMP DO PRIVATE(JI)  
  DO ji = 1,SIZE(zwork3d,1)
    zwork3d(ji,njb:nje,:) = zwork2d(njb:nje,:)
  END DO
!$OMP END DO  
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_32',1,zhook_handle_omp)
!$OMP END PARALLEL
  !
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_33',0,zhook_handle)
  DEALLOCATE(zwork2d)
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_33',1,zhook_handle)
!
ELSE
  !
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_4',0,zhook_handle)
  CALL fmreadx3(cfile_lfi,hrec,cluout_lfi,SIZE(zwork3d),zwork3d,igrid,ilench,hcomment,kresp)
  IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_4',1,zhook_handle)
  !
ENDIF
!
!$OMP PARALLEL PRIVATE(ZHOOK_HANDLE_OMP)
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_5',0,zhook_handle_omp)
!$OMP DO PRIVATE(JJ,JI)
DO jj=1,nje-njb+1
  DO ji=1,nie-nib+1
    pfield(ji+(nie-nib+1)*(jj-1),:) = zwork3d(nib+ji-1,njb+jj-1,:) 
  END DO
END DO
!$OMP END DO
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_5',1,zhook_handle_omp)
!$OMP END PARALLEL
!  
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_6',0,zhook_handle)
 CALL error_read_surf_lfi(hrec,kresp)
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFX2_LFI:READ_IN_LFI_X2_FOR_MNH_6',1,zhook_handle)
!
END SUBROUTINE read_in_lfi_x2_for_mnh
!
END SUBROUTINE read_surfx2_lfi
!
!     #############################################################
      SUBROUTINE read_surfn0_lfi(HREC,KFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READN0* - routine to read an integer
!!      B. Decharme 07/2011 : Grdid dimension only read in pgd file
!
USE modd_io_surf_lfi, ONLY : cfile_lfi, cluout_lfi, cfilepgd_lfi, &
                             lmnh_compatible, niu, nib, nie, nju, njb, nje
!
USE modi_fmread
USE modi_error_read_surf_lfi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER,            INTENT(OUT) :: KFIELD   ! the integer to be read
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment
!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=40) :: YGRID
INTEGER           :: IGRID   ! position of data on grid
INTEGER           :: ILENCH  ! length of comment string
INTEGER           :: IIMAX, IJMAX
INTEGER           :: INB ! number of articles in the file
INTEGER           :: IRESP
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFN0_LFI',0,zhook_handle)
!
kresp=0
!
 CALL fmreadn0(cfile_lfi,hrec,cluout_lfi,1,kfield,igrid,ilench,hcomment,kresp)
!
 CALL error_read_surf_lfi(hrec,kresp)
!
!* tests compatibility with MesoNH files
!
IF (hrec/='DIM_FULL' .AND. lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFN0_LFI',1,zhook_handle)
IF (hrec/='DIM_FULL') RETURN
!
!-----------------------------------------------------------------------------------------------------
! READ PGD FILE
!-----------------------------------------------------------------------------------------------------
!
!IF (CFILE_LFI/=CFILEPGD_LFI) THEN
!  CALL FMOPEN(CFILEPGD_LFI,'OLD',CLUOUT_LFI,0,1,1,INB,IRESP)
!ENDIF
!
 CALL fmreadc0(cfile_lfi,'GRID_TYPE ',cluout_lfi,1,ygrid,igrid,ilench,hcomment,kresp)
 CALL error_read_surf_lfi('GRID_TYPE ',kresp)
lmnh_compatible = (ygrid=="CARTESIAN " .OR. ygrid=="CONF PROJ ")
!
IF (lmnh_compatible) THEN
  CALL fmreadn0(cfile_lfi,'IMAX',cluout_lfi,1,iimax,igrid,ilench,hcomment,kresp)
  CALL error_read_surf_lfi('IMAX',kresp)
  niu = iimax+2
  nib = 2
  nie = iimax+1
  CALL fmreadn0(cfile_lfi,'JMAX',cluout_lfi,1,ijmax,igrid,ilench,hcomment,kresp)
  CALL error_read_surf_lfi('JMAX',kresp)
  nju = ijmax+2
  njb = 2
  nje = ijmax+1
END IF
!
!IF(CFILE_LFI/=CFILEPGD_LFI)THEN
!  CALL FMCLOS(CFILEPGD_LFI,'KEEP',CLUOUT_LFI,IRESP)
!ENDIF
!
!-----------------------------------------------------------------------------------------------------
! END READ PGD FILE
!-----------------------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFN0_LFI',1,zhook_handle)
!
END SUBROUTINE read_surfn0_lfi
!
!     #############################################################
      SUBROUTINE read_surfn1_lfi(HREC,KFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READN0* - routine to read an integer
!
USE modd_surfex_mpi, ONLY : nrank, nproc, ncomm, npio, xtime_npio_read, xtime_comm_read, nreq
!
USE modd_io_surf_lfi,        ONLY : cfile_lfi, cluout_lfi, nmask, nfull
!
USE modi_fmread
USE modi_error_read_surf_lfi
USE modi_read_and_send_mpi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),      INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:),  INTENT(OUT) :: KFIELD   ! the integer to be read
INTEGER,                INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),     INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),       INTENT(IN)  :: HDIR     ! type of field :
                                                ! 'H' : field with
                                                !       horizontal spatial dim.
                                                ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
INTEGER          :: IGRID   ! position of data on grid
INTEGER          :: ILENCH  ! length of comment string
INTEGER          :: IL1, INFOMPI, JJ
!
INTEGER, DIMENSION(:), ALLOCATABLE :: IWORK
#ifdef SFX_MPI
INTEGER, DIMENSION(MPI_STATUS_SIZE,NPROC-1) :: ISTATUS
#endif
DOUBLE PRECISION   :: XTIME0
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFN1_LFI',0,zhook_handle)
!
il1 = SIZE(kfield)
!
kresp=0
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (hdir=='-') THEN
  ALLOCATE(iwork(il1))
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (hdir=='A') THEN
    ALLOCATE(iwork(il1))
  ELSEIF (hdir/='-') THEN
    ALLOCATE(iwork(nfull))
  ENDIF 
  !  
  IF (hdir=='H')  THEN
    CALL fmreadn1(cfile_lfi,hrec,cluout_lfi,nfull,iwork,igrid,ilench,hcomment,kresp)
  ELSE
    CALL fmreadn1(cfile_lfi,hrec,cluout_lfi,il1,iwork(:),igrid,ilench,hcomment,kresp)
  END IF
  !
  CALL error_read_surf_lfi(hrec,kresp)
  !
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (hdir=='A') THEN  ! no distribution on other tasks
  IF ( nrank==npio ) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
#endif
    kfield(:) = iwork(1:il1)
#ifdef SFX_MPI
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
ELSEIF (hdir=='-') THEN ! distribution of the total field on other tasks
  IF (nproc>1) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
    CALL mpi_bcast(iwork,il1*kind(iwork)/4,mpi_integer,npio,ncomm,infompi)
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
  kfield(:) = iwork(1:il1)   
ELSE
  CALL read_and_send_mpi(iwork,kfield,nmask)
  !IF (NRANK==NPIO) THEN
  !  CALL MPI_WAITALL(NPROC-1,NREQ,ISTATUS,INFOMPI)
  !ENDIF  
ENDIF
!
DEALLOCATE(iwork)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFN1_LFI',1,zhook_handle)
!
END SUBROUTINE read_surfn1_lfi
!
!     #############################################################
      SUBROUTINE read_surfc0_lfi(HREC,HFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READC0* - routine to read a character
!
USE modd_io_surf_lfi,        ONLY : cfile_lfi, cluout_lfi
!
USE modi_fmread
USE modi_error_read_surf_lfi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC      ! name of the article to be read
 CHARACTER(LEN=40),  INTENT(OUT) :: HFIELD    ! the integer to be read
INTEGER,            INTENT(OUT) :: KRESP     ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT  ! comment
!
!*      0.2   Declarations of local variables
!
INTEGER          :: IGRID   ! position of data on grid
INTEGER          :: ILENCH  ! length of comment string
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFC0_LFI',0,zhook_handle)
!
kresp=0
!
 CALL fmreadc0(cfile_lfi,hrec,cluout_lfi,1,hfield,igrid,ilench,hcomment,kresp)
!
 CALL error_read_surf_lfi(hrec,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFC0_LFI',1,zhook_handle)
!
END SUBROUTINE read_surfc0_lfi
!
!     #############################################################
      SUBROUTINE read_surfl0_lfi(HREC,OFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READL0* - routine to read a logical
!
USE modd_io_surf_lfi,        ONLY : cfile_lfi, cluout_lfi
!
USE modi_fmread
USE modi_error_read_surf_lfi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
LOGICAL,            INTENT(OUT) :: OFIELD   ! array containing the data field
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment
!
!*      0.2   Declarations of local variables
!
INTEGER          :: IGRID   ! position of data on grid
INTEGER          :: ILENCH  ! length of comment string
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFL0_LFI',0,zhook_handle)
!
kresp=0
!
 CALL fmreadl0(cfile_lfi,hrec,cluout_lfi,1,ofield,igrid,ilench,hcomment,kresp)
!
 CALL error_read_surf_lfi(hrec,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFL0_LFI',1,zhook_handle)
!
END SUBROUTINE read_surfl0_lfi
!
!     #############################################################
      SUBROUTINE read_surfl1_lfi(HREC,OFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READL1* - routine to read a logical array
!
USE modd_surfex_mpi, ONLY : nrank, nproc, ncomm, npio, xtime_npio_read, xtime_comm_read
!
USE modd_io_surf_lfi,        ONLY : cfile_lfi, cluout_lfi
!
USE modi_fmread
USE modi_error_read_surf_lfi
USE modi_abor1_sfx
USE modi_get_luout
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),      INTENT(IN)  :: HREC     ! name of the article to be read
LOGICAL, DIMENSION(:), INTENT(OUT) :: OFIELD   ! array containing the data field
INTEGER,                INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),     INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),       INTENT(IN)  :: HDIR     ! type of field :
                                                ! 'H' : field with
                                                !       horizontal spatial dim.
                                                ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
INTEGER :: ILUOUT
INTEGER :: IGRID   ! position of data on grid
INTEGER :: ILENCH  ! length of comment string
INTEGER :: IL1, INFOMPI
DOUBLE PRECISION   :: XTIME0
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFL1_LFI',0,zhook_handle)
!
il1 = SIZE(ofield)
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
kresp=0
!
IF (nrank==npio) THEN
  !
  IF (hdir=='H') THEN
    CALL get_luout('LFI   ',iluout)
    WRITE(iluout,*) 'Error: 1D logical vector for reading on an horizontal grid:'
    WRITE(iluout,*) 'this option is not coded in READ_SURFL1_LFI'
    CALL abor1_sfx('MODE_READ_SURF_LFI: 1D LOGICAL VECTOR FOR READING NOT CODED IN READ_SURFL1_LFI')
  END IF
  !
  CALL fmreadl1(cfile_lfi,hrec,cluout_lfi,il1,ofield,igrid,ilench,hcomment,kresp)
  !
  CALL error_read_surf_lfi(hrec,kresp)
  !
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (nproc>1 .AND. hdir/='A') THEN
#ifdef SFX_MPI
  xtime0 = mpi_wtime()
  CALL mpi_bcast(ofield,il1,mpi_logical,npio,ncomm,infompi)
  xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0) 
#endif
ENDIF
!
ofield = ofield  
! 
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFL1_LFI',1,zhook_handle)
!
END SUBROUTINE read_surfl1_lfi
!
!     #############################################################
      SUBROUTINE read_surft0_lfi(HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READT0* - routine to read a date
!
USE modd_io_surf_lfi,  ONLY : cfile_lfi, cluout_lfi  
!
USE modi_fmread
USE modi_error_read_surf_lfi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER,            INTENT(OUT) :: KYEAR    ! year
INTEGER,            INTENT(OUT) :: KMONTH   ! month
INTEGER,            INTENT(OUT) :: KDAY     ! day
REAL,               INTENT(OUT) :: PTIME    ! year
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment

!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=12)     :: YREC     ! Name of the article to be read
INTEGER, DIMENSION(3) :: ITDATE
!
INTEGER          :: IGRID   ! position of data on grid
INTEGER          :: ILENCH  ! length of comment string
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFT0_LFI',0,zhook_handle)
!
kresp=0
!
yrec=trim(hrec)//'%TDATE'
 CALL fmreadn1(cfile_lfi,yrec,cluout_lfi,3,itdate,igrid,ilench,hcomment,kresp)
 CALL error_read_surf_lfi(hrec,kresp)
!
yrec=trim(hrec)//'%TIME'
 CALL fmreadx0(cfile_lfi,yrec,cluout_lfi,1,ptime,igrid,ilench,hcomment,kresp)
 CALL error_read_surf_lfi(hrec,kresp)
!
kyear  = itdate(1)
kmonth = itdate(2)
kday   = itdate(3)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFT0_LFI',1,zhook_handle)
!
END SUBROUTINE read_surft0_lfi
!
!     #############################################################
      SUBROUTINE read_surft1_lfi(HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READT0* - routine to read a date
!
USE modd_io_surf_lfi,        ONLY : cfile_lfi, cluout_lfi  
!
USE modi_fmread
USE modi_error_read_surf_lfi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),     INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:), INTENT(OUT) :: KYEAR    ! year
INTEGER, DIMENSION(:), INTENT(OUT) :: KMONTH   ! month
INTEGER, DIMENSION(:), INTENT(OUT) :: KDAY     ! day
REAL,    DIMENSION(:), INTENT(OUT) :: PTIME    ! year
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment

!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=12)     :: YREC     ! Name of the article to be read
INTEGER          :: ILUOUT
INTEGER          :: IGRID   ! position of data on grid
INTEGER          :: ILENCH  ! length of comment string
INTEGER, DIMENSION(3,SIZE(KYEAR)) :: ITDATE
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFT1_LFI',0,zhook_handle)
!
kresp=0
!
yrec=trim(hrec)//'%TDATE'
 CALL fmreadn2(cfile_lfi,yrec,cluout_lfi,SIZE(itdate),itdate,igrid,ilench,hcomment,kresp)
 CALL error_read_surf_lfi(hrec,kresp)
!
yrec=trim(hrec)//'%TIME'
 CALL fmreadx1(cfile_lfi,yrec,cluout_lfi,SIZE(ptime),ptime,igrid,ilench,hcomment,kresp)
 CALL error_read_surf_lfi(hrec,kresp)
!
kyear(:) = itdate(1,:)
kmonth(:) = itdate(2,:)
kday(:) = itdate(3,:)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFT1_LFI',1,zhook_handle)
!
END SUBROUTINE read_surft1_lfi
!
!     #############################################################
      SUBROUTINE read_surft2_lfi(HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READT0* - routine to read a date
!
USE modd_io_surf_lfi,        ONLY : cfile_lfi, cluout_lfi  
!
USE modi_fmread
USE modi_error_read_surf_lfi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
 CHARACTER(LEN=*),     INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:,:), INTENT(OUT) :: KYEAR    ! year
INTEGER, DIMENSION(:,:), INTENT(OUT) :: KMONTH   ! month
INTEGER, DIMENSION(:,:), INTENT(OUT) :: KDAY     ! day
REAL,    DIMENSION(:,:), INTENT(OUT) :: PTIME    ! year
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment

!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=12)     :: YREC     ! Name of the article to be read
INTEGER          :: ILUOUT
INTEGER          :: IGRID   ! position of data on grid
INTEGER          :: ILENCH  ! length of comment string
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFT2_LFI',0,zhook_handle)
!
kresp=0
!
yrec=trim(hrec)//'%YEAR'
 CALL fmreadn2(cfile_lfi,yrec,cluout_lfi,SIZE(kyear),kyear,igrid,ilench,hcomment,kresp)
 CALL error_read_surf_lfi(hrec,kresp)
!
yrec=trim(hrec)//'%MONTH'
 CALL fmreadn2(cfile_lfi,yrec,cluout_lfi,SIZE(kmonth),kmonth,igrid,ilench,hcomment,kresp)
 CALL error_read_surf_lfi(hrec,kresp)
!
yrec=trim(hrec)//'%DAY'
 CALL fmreadn2(cfile_lfi,yrec,cluout_lfi,SIZE(kday),kday,igrid,ilench,hcomment,kresp)
 CALL error_read_surf_lfi(hrec,kresp)
!
yrec=trim(hrec)//'%TIME'
 CALL fmreadx2(cfile_lfi,yrec,cluout_lfi,SIZE(ptime),ptime,igrid,ilench,hcomment,kresp)
 CALL error_read_surf_lfi(hrec,kresp)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_LFI:READ_SURFT2_LFI',1,zhook_handle)
!
END SUBROUTINE read_surft2_lfi
!
#endif
!
END MODULE mode_read_surf_lfi