mode_read_surf_asc.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
MODULE mode_read_surf_asc
!!
!!    PURPOSE
!!    -------
!
!       The purpose of READ_SURF_ASC is
!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!     
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!
!!      S.Malardel      *METEO-FRANCE*
!!
!!    MODIFICATIONS
!!    -------------
!!
!!      original                                                     01/08/03
!!      J.Escobar      10/06/2013: replace DOUBLE PRECISION by REAL to handle problem for promotion of real on IBM SP
!----------------------------------------------------------------------------
!
INTERFACE read_surf0_asc
        MODULE PROCEDURE read_surfx0_asc
        MODULE PROCEDURE read_surfn0_asc
        MODULE PROCEDURE read_surfl0_asc
        MODULE PROCEDURE read_surfc0_asc
END INTERFACE
INTERFACE read_surfn_asc
        MODULE PROCEDURE read_surfx1_asc
        MODULE PROCEDURE read_surfn1_asc
        MODULE PROCEDURE read_surfl1_asc
        MODULE PROCEDURE read_surfx2_asc
END INTERFACE
INTERFACE read_surft_asc
        MODULE PROCEDURE read_surft0_asc
        MODULE PROCEDURE read_surft1_asc
        MODULE PROCEDURE read_surft2_asc
END INTERFACE
!
CONTAINS
!
!     #############################################################
      SUBROUTINE read_surfx0_asc (&
                                  HREC,PFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!
USE modd_io_surf_asc, ONLY : nunit, nluout, cmask
!
USE mode_pos_surf
!
USE modi_io_buff
USE modi_error_read_surf_asc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=*), INTENT(IN)  :: HREC     ! name of the article to be read
REAL,              INTENT(OUT) :: PFIELD   ! the real scalar to be read
INTEGER,           INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),INTENT(OUT) :: HCOMMENT ! comment
!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=50):: YCOMMENT
 CHARACTER(LEN=6) :: YMASK
LOGICAL          :: GFOUND
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFX0_ASC',0,zhook_handle)
!
kresp=0
!
ymask=cmask
 CALL io_buff(&
                hrec,'R',gfound)
IF (gfound) ymask='FULL  '
!
 CALL posnam(nunit,ymask//' '//hrec,gfound,nluout)
IF (.NOT. gfound) CALL posnam(nunit,'FULL  '//' '//hrec,gfound,nluout) ! used for auxilliary files
!
READ(nunit,fmt=*,end=100)
READ(nunit,fmt='(A50)') ycomment
READ(nunit,fmt=*,err=100) pfield
!
hcomment = ycomment
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFX0_ASC',1,zhook_handle)
RETURN
!
100 CONTINUE
 CALL error_read_surf_asc(hrec,kresp)
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFX0_ASC',1,zhook_handle)
!
END SUBROUTINE read_surfx0_asc
!
!     #############################################################
      SUBROUTINE read_surfx1_asc (&
                                  HREC,PFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READX1* - routine to fill a real 1D array for the externalised surface 
!
!
USE modd_surfex_mpi, ONLY : nrank, nproc, ncomm, npio, xtime_npio_read, xtime_comm_read, nreq
!
USE modd_io_surf_asc,  ONLY : nunit, nluout, nmask, nfull, cmask
!
USE mode_pos_surf
!
USE modi_pack_same_rank
USE modi_io_buff
USE modi_error_read_surf_asc
USE modi_read_and_send_mpi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=*),   INTENT(IN)  :: HREC     ! name of the article to be read
REAL, DIMENSION(:), INTENT(OUT)  :: PFIELD   ! array containing the data field
INTEGER,             INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),  INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),    INTENT(IN)  :: HDIR     ! type of field :
                                             ! 'H' : field with
                                             !       horizontal spatial dim.
                                             ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=6)  :: YMASK
INTEGER           :: IL1, INFOMPI
LOGICAL :: GFOUND
!
REAL, DIMENSION(:), ALLOCATABLE :: ZWORK
REAL   :: XTIME0
#ifdef SFX_MPI
INTEGER, DIMENSION(MPI_STATUS_SIZE,NPROC-1) :: ISTATUS
#endif
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFX1_ASC',0,zhook_handle)
!
il1 = SIZE(pfield)
!
kresp=0
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (hdir=='-') THEN
  ALLOCATE(zwork(il1))
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (hdir=='A') THEN
    ALLOCATE(zwork(il1))
  ELSEIF (hdir/='-') THEN
    ALLOCATE(zwork(nfull))
  END IF
  !
  IF (hdir=='A' .OR. hdir=='-' .OR. hdir=='E') THEN
    CALL posnam(nunit,cmask//' '//hrec,gfound,nluout)
    IF (.NOT. gfound) CALL posnam(nunit,'FULL  '//' '//hrec,gfound,nluout)
  ELSE
    ymask=cmask
    CALL io_buff(&
                hrec,'R',gfound)
    IF (gfound) ymask='FULL  '
    CALL posnam(nunit,ymask//' '//hrec,gfound,nluout)
  ENDIF
  !
  READ(nunit,fmt=*,iostat=kresp)
  READ(nunit,fmt='(A50)',iostat=kresp) hcomment
  READ(nunit,fmt=*,iostat=kresp) zwork
  !
ELSEIF (hdir/='-') THEN
  ALLOCATE(zwork(0))
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (kresp/=0) CALL error_read_surf_asc(hrec,kresp)
!
IF (hdir=='E') THEN
  IF ( nrank==npio ) THEN
    CALL pack_same_rank(nmask,zwork(:),pfield(:))
  ENDIF
ELSEIF (hdir=='A') THEN  ! no distribution on other tasks
  IF ( nrank==npio ) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
#endif
    pfield(:) = zwork(1:il1)
#ifdef SFX_MPI
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
ELSEIF (hdir=='-') THEN ! distribution of the total field on other tasks
#ifdef SFX_MPI
  IF (nproc>1) THEN
    xtime0 = mpi_wtime()
    CALL mpi_bcast(zwork,il1*kind(zwork)/4,mpi_real,npio,ncomm,infompi)   
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
  ENDIF
#endif
  pfield(:) = zwork(1:il1)
ELSE
  CALL read_and_send_mpi(zwork,pfield,nmask)
  !IF (NRANK==NPIO) THEN
  !  CALL MPI_WAITALL(NPROC-1,NREQ,ISTATUS,INFOMPI)
  !ENDIF  
ENDIF
!
DEALLOCATE(zwork)
!  
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFX1_ASC',1,zhook_handle)
!
END SUBROUTINE read_surfx1_asc
!
!     #############################################################
      SUBROUTINE read_surfx2_asc (&
                                  HREC,PFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READX2* - routine to fill a real 2D array for the externalised surface 
!
USE modd_surfex_mpi, ONLY : nrank, nproc, ncomm, npio, xtime_npio_read, xtime_comm_read, nreq
!
USE modd_io_surf_asc,        ONLY : nunit, nluout, nmask, nfull, cmask
!
USE mode_pos_surf
!
USE modi_pack_same_rank
USE modi_io_buff
USE modi_error_read_surf_asc
USE modi_read_and_send_mpi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=*),        INTENT(IN)  :: HREC     ! name of the article to be read
REAL, DIMENSION(:,:),     INTENT(OUT) :: PFIELD   ! array containing the data field
INTEGER,                  INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),       INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),         INTENT(IN)  :: HDIR     ! type of field :
                                                  ! 'H' : field with
                                                  !       horizontal spatial dim.
                                                  ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
! 
LOGICAL :: GFOUND
 CHARACTER(LEN=6)  :: YMASK
INTEGER           :: IL1, IL2, INFOMPI
!
REAL, DIMENSION(:,:), ALLOCATABLE :: ZWORK2
REAL   :: XTIME0
#ifdef SFX_MPI
INTEGER, DIMENSION(MPI_STATUS_SIZE,NPROC-1) :: ISTATUS
#endif
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFX2_ASC',0,zhook_handle)
!
il1 = SIZE(pfield,1)
il2 = SIZE(pfield,2)
!
kresp=0
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (hdir=='-') THEN
  ALLOCATE(zwork2(il1,il2))
ENDIF
!
IF (nrank==npio) THEN
  !
  IF (hdir=='A') THEN
    ALLOCATE(zwork2(il1,il2))
  ELSEIF (hdir/='-') THEN
    ALLOCATE(zwork2(nfull,il2))
  END IF                 
  !
  IF (hdir=='A' .OR. hdir=='-'.OR.hdir=='E') THEN
    CALL posnam(nunit,cmask//' '//hrec,gfound,nluout)
    IF (.NOT. gfound) CALL posnam(nunit,'FULL  '//' '//hrec,gfound,nluout)
  ELSE
    ymask=cmask
    CALL io_buff(&
                hrec,'R',gfound)
    IF (gfound) ymask='FULL  '
    CALL posnam(nunit,ymask//' '//hrec,gfound,nluout)
  ENDIF
  !
  READ(nunit,fmt=*,iostat=kresp)
  READ(nunit,fmt='(A50)',iostat=kresp) hcomment
  READ(nunit,fmt=*,iostat=kresp) zwork2
  !
ELSEIF (hdir/='-') THEN
  ALLOCATE(zwork2(0,0))
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (kresp/=0) CALL error_read_surf_asc(hrec,kresp)
!
IF (hdir=='E') THEN
  IF ( nrank==npio ) THEN
    CALL pack_same_rank(nmask,zwork2(:,:),pfield(:,:))
  ENDIF
ELSEIF (hdir=='A') THEN
  IF ( nrank==npio ) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
#endif
    pfield(:,:) = zwork2(1:il1,:)
#ifdef SFX_MPI
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
ELSEIF (hdir=='-') THEN
#ifdef SFX_MPI
  IF (nproc>1) THEN
    xtime0 = mpi_wtime()
    CALL mpi_bcast(zwork2,il1*il2*kind(zwork2)/4,mpi_real,npio,ncomm,infompi)   
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
  ENDIF
#endif
  IF (nrank==npio) pfield(:,:) = zwork2(1:il1,:)
ELSE
  CALL read_and_send_mpi(zwork2,pfield,nmask)
  !IF (NRANK==NPIO) THEN
  !  CALL MPI_WAITALL(NPROC-1,NREQ,ISTATUS,INFOMPI)
  !ENDIF  
ENDIF
!
DEALLOCATE(zwork2)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFX2_ASC',1,zhook_handle)
!
END SUBROUTINE read_surfx2_asc
!
!     #############################################################
      SUBROUTINE read_surfn0_asc (&
                                  HREC,KFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READN0* - routine to read an integer
!
!
USE modd_io_surf_asc,        ONLY : nunit, nluout, nmask, cmask
!
USE mode_pos_surf
!
USE modi_io_buff
USE modi_error_read_surf_asc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER,            INTENT(OUT) :: KFIELD   ! the integer to be read
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment
!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=50) :: YCOMMENT
 CHARACTER(LEN=6)  :: YMASK
LOGICAL           :: GFOUND
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFN0_ASC',0,zhook_handle)
!
kresp=0
!
ymask=cmask
 CALL io_buff(&
                hrec,'R',gfound)
IF (gfound) ymask='FULL  '
!
 CALL posnam(nunit,ymask//' '//hrec,gfound,nluout)
IF (.NOT. gfound) CALL posnam(nunit,'FULL  '//' '//hrec,gfound,nluout) ! used for auxilliary files
!
READ(nunit,fmt=*,end=100)
READ(nunit,fmt='(A50)') ycomment
READ(nunit,fmt=*,err=100) kfield
!
hcomment = ycomment
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFN0_ASC',1,zhook_handle)
RETURN
!
100 CONTINUE
 CALL error_read_surf_asc(hrec,kresp)
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFN0_ASC',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE read_surfn0_asc
!
!     #############################################################
      SUBROUTINE read_surfn1_asc (&
                                  HREC,KFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READN0* - routine to read an integer
!
!
!
!
USE modd_surfex_mpi, ONLY : nrank, nproc, ncomm, npio, xtime_npio_read, xtime_comm_read
!
USE modd_io_surf_asc,        ONLY : nunit, nluout, nmask, nfull, cmask
!
USE mode_pos_surf
!
USE modi_io_buff
USE modi_error_read_surf_asc
USE modi_read_and_send_mpi
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=*),      INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:),  INTENT(OUT) :: KFIELD   ! the integer to be read
INTEGER,                INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),     INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),       INTENT(IN)  :: HDIR     ! type of field :
                                                ! 'H' : field with
                                                !       horizontal spatial dim.
                                                ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=6)  :: YMASK
INTEGER           :: IL1, INFOMPI
!
INTEGER, DIMENSION(:), ALLOCATABLE :: IWORK
#ifdef SFX_MPI
INTEGER, DIMENSION(MPI_STATUS_SIZE) :: ISTATUS
#endif
REAL   :: XTIME0
LOGICAL :: GFOUND
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFN1_ASC',0,zhook_handle)
!  
il1 = SIZE(kfield)
!
kresp = 0
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (hdir=='-') THEN
  ALLOCATE(iwork(il1))
ENDIF
!
IF (nrank==npio) THEN
  !
  !
  IF (hdir=='A') THEN
    ALLOCATE(iwork(il1))
  ELSEIF (hdir/='-') THEN
    ALLOCATE(iwork(nfull))
  END IF            
  !
  IF (hdir=='A' .OR. hdir=='-') THEN
    CALL posnam(nunit,cmask//' '//hrec,gfound,nluout)
    IF (.NOT. gfound) CALL posnam(nunit,'FULL  '//' '//hrec,gfound,nluout)
  ELSE
    ymask=cmask
    CALL io_buff(&
                hrec,'R',gfound)
    IF (gfound) ymask='FULL  '
    CALL posnam(nunit,ymask//' '//hrec,gfound,nluout)
  ENDIF
  !
  READ(nunit,fmt=*,iostat=kresp)
  READ(nunit,fmt='(A50)',iostat=kresp) hcomment
  READ(nunit,fmt=*,iostat=kresp) iwork
  !
  !
ELSEIF (hdir/='-') THEN
  ALLOCATE(iwork(0))
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (kresp/=0) CALL error_read_surf_asc(hrec,kresp)
!
IF (hdir=='A') THEN
  IF ( nrank==npio ) THEN
#ifdef SFX_MPI
    xtime0 = mpi_wtime()
#endif
    kfield(:) = iwork(1:il1)
#ifdef SFX_MPI
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
#endif
  ENDIF
ELSEIF (hdir=='-') THEN
#ifdef SFX_MPI
  IF (nproc>1) THEN
    xtime0 = mpi_wtime()
    CALL mpi_bcast(iwork,il1*kind(iwork)/4,mpi_integer,npio,ncomm,infompi)   
    xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
  ENDIF
#endif
  kfield(:) = iwork(1:il1)
ELSE
  CALL read_and_send_mpi(iwork,kfield,nmask)
ENDIF
!
DEALLOCATE(iwork)
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFN1_ASC',1,zhook_handle)
!
END SUBROUTINE read_surfn1_asc
!
!     #############################################################
      SUBROUTINE read_surfc0_asc (&
                                  HREC,HFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READC0* - routine to read a character
!
USE modd_io_surf_asc,        ONLY : nunit, nluout, cmask
!
USE mode_pos_surf
!
USE modi_io_buff
USE modi_error_read_surf_asc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC      ! name of the article to be read
 CHARACTER(LEN=40),  INTENT(OUT) :: HFIELD    ! the integer to be read
INTEGER,            INTENT(OUT) :: KRESP     ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT  ! comment
!
!*      0.2   Declarations of local variables
!
INTEGER :: IRESP
 CHARACTER(LEN=50):: YCOMMENT
 CHARACTER(LEN=6) :: YMASK
LOGICAL          :: GFOUND
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFC0_ASC',0,zhook_handle)
!
kresp=0
!
ymask=cmask
 CALL io_buff(&
                hrec,'R',gfound)
IF (gfound) ymask='FULL  '
!
 CALL posnam(nunit,ymask//' '//hrec,gfound,nluout)
IF (.NOT. gfound) CALL posnam(nunit,'FULL  '//' '//hrec,gfound,nluout) ! used for auxilliary files
!
READ(nunit,fmt=*,iostat=iresp)
READ(nunit,fmt='(A50)',iostat=iresp) ycomment
READ(nunit,fmt='(A40)',iostat=iresp) hfield
!
IF (iresp/=0) CALL error_read_surf_asc(hrec,kresp)

hcomment = ycomment
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFC0_ASC',1,zhook_handle)
!
END SUBROUTINE read_surfc0_asc
!
!     #############################################################
      SUBROUTINE read_surfl0_asc (&
                                  HREC,OFIELD,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READL0* - routine to read a logical
!
USE modd_io_surf_asc,        ONLY : nunit, nluout, cmask
!
USE mode_pos_surf
!
USE modi_io_buff
USE modi_error_read_surf_asc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
LOGICAL,            INTENT(OUT) :: OFIELD   ! array containing the data field
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment
!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=50) :: YCOMMENT
 CHARACTER(LEN=6)  :: YMASK
LOGICAL           :: GFOUND
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFL0_ASC',0,zhook_handle)
kresp=0
!
ymask=cmask
 CALL io_buff(&
                hrec,'R',gfound)
IF (gfound) ymask='FULL  '
!
 CALL posnam(nunit,ymask//' '//hrec,gfound,nluout)
IF (.NOT. gfound) CALL posnam(nunit,'FULL  '//' '//hrec,gfound,nluout) ! used for auxilliary files
!
READ(nunit,fmt=*,end=100)
READ(nunit,fmt='(A50)') ycomment
READ(nunit,fmt=*,err=100) ofield
!
hcomment = ycomment
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFL0_ASC',1,zhook_handle)
RETURN
!
100 CONTINUE
 CALL error_read_surf_asc(hrec,kresp)
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFL0_ASC',1,zhook_handle)
!
END SUBROUTINE read_surfl0_asc
!
!     #############################################################
      SUBROUTINE read_surfl1_asc (&
                                  HREC,OFIELD,KRESP,HCOMMENT,HDIR)
!     #############################################################
!
!!****  *READL1* - routine to read a logical array
!
USE modd_surfex_mpi, ONLY : nrank, nproc, ncomm, npio, xtime_npio_read, xtime_comm_read
!
USE modd_io_surf_asc,        ONLY : nunit, nluout, cmask
!
USE mode_pos_surf
!
USE modi_io_buff
USE modi_error_read_surf_asc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=*),      INTENT(IN)  :: HREC     ! name of the article to be read
LOGICAL, DIMENSION(:),  INTENT(OUT) :: OFIELD   ! array containing the data field
INTEGER,                INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100),     INTENT(OUT) :: HCOMMENT ! comment
 CHARACTER(LEN=1),       INTENT(IN)  :: HDIR     ! type of field :
                                                ! 'H' : field with
                                                !       horizontal spatial dim.
                                                ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=6) :: YMASK
INTEGER          :: INFOMPI, IL1
REAL :: XTIME0
LOGICAL :: GFOUND
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFL1_ASC',0,zhook_handle)
!
il1 = SIZE(ofield)
!
kresp = 0
!
!
#ifdef SFX_MPI
xtime0 = mpi_wtime()
#endif
!
IF (nrank==npio) THEN
  !
  ! 
  ymask=cmask
  CALL io_buff(&
                hrec,'R',gfound)
  IF (gfound) ymask='FULL  '
  !
  CALL posnam(nunit,ymask//' '//hrec,gfound,nluout)
  IF (.NOT. gfound) CALL posnam(nunit,'FULL  '//' '//hrec,gfound,nluout) ! used for auxilliary files
  !
  READ(nunit,fmt=*,iostat=kresp)
  READ(nunit,fmt='(A50)',iostat=kresp) hcomment
  READ(nunit,fmt=*,iostat=kresp) ofield
  !
  !
ENDIF
!
#ifdef SFX_MPI
xtime_npio_read = xtime_npio_read + (mpi_wtime() - xtime0)
#endif
!
IF (kresp/=0) CALL error_read_surf_asc(hrec,kresp)
!
#ifdef SFX_MPI
IF (nproc>1 .AND. hdir/='A') THEN
  xtime0 = mpi_wtime()
  CALL mpi_bcast(ofield,il1,mpi_logical,npio,ncomm,infompi)
  xtime_comm_read = xtime_comm_read + (mpi_wtime() - xtime0)
ENDIF
#endif
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFL1_ASC',1,zhook_handle)
!
END SUBROUTINE read_surfl1_asc
!
!
!     #############################################################
      SUBROUTINE read_surft0_asc (&
                                  HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READT0* - routine to read a date
!
!
!
!
USE modd_surfex_mpi, ONLY : nrank
!
USE modd_io_surf_asc,        ONLY : nunit, nluout, cmask
!
USE mode_pos_surf
!
USE modi_io_buff
USE modi_error_read_surf_asc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER,            INTENT(OUT) :: KYEAR    ! year
INTEGER,            INTENT(OUT) :: KMONTH   ! month
INTEGER,            INTENT(OUT) :: KDAY     ! day
REAL,               INTENT(OUT) :: PTIME    ! year
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment

!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=50) :: YCOMMENT
 CHARACTER(LEN=6)  :: YMASK
LOGICAL           :: GFOUND
INTEGER, DIMENSION(3) :: ITDATE
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFT0_ASC',0,zhook_handle)
kresp=0
!
ymask=cmask
 CALL io_buff(&
                hrec,'R',gfound)
IF (gfound) ymask='FULL  '
!
 CALL posnam(nunit,ymask//' '//trim(hrec)//'%TDATE',gfound,nluout)
!IF (.NOT. GFOUND) CALL POSNAM(NUNIT,'FULL  '//' '//HREC,GFOUND,NLUOUT) ! used for auxilliary files
!
READ(nunit,fmt=*,end=100)
READ(nunit,fmt='(A50)') ycomment
READ(nunit,fmt=*,err=100) itdate(:)
!
kyear  = itdate(1)
kmonth = itdate(2)
kday   = itdate(3)
!
 CALL posnam(nunit,ymask//' '//trim(hrec)//'%TIME',gfound,nluout)
IF (.NOT. gfound) CALL posnam(nunit,'FULL  '//' '//hrec,gfound,nluout) ! used for auxilliary files
!
READ(nunit,fmt=*,end=100)
READ(nunit,fmt='(A50)') ycomment
READ(nunit,fmt=*,err=100) ptime
!
hcomment = ycomment
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFT0_ASC',1,zhook_handle)
RETURN
!
100 CONTINUE
 CALL error_read_surf_asc(hrec,kresp)
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFT0_ASC',1,zhook_handle)
!
END SUBROUTINE read_surft0_asc
!
!     #############################################################
      SUBROUTINE read_surft1_asc (&
                                  HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READT2* - routine to read a date
!
!
!
!
USE modd_surfex_mpi, ONLY : nrank
!
USE modd_io_surf_asc,        ONLY : nunit, nluout, cmask
!
USE mode_pos_surf
!
USE modi_io_buff
USE modi_error_read_surf_asc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=*),     INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:), INTENT(OUT) :: KYEAR    ! year
INTEGER, DIMENSION(:), INTENT(OUT) :: KMONTH   ! month
INTEGER, DIMENSION(:), INTENT(OUT) :: KDAY     ! day
REAL,    DIMENSION(:), INTENT(OUT) :: PTIME    ! year
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment
!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=50) :: YCOMMENT
 CHARACTER(LEN=6)  :: YMASK
LOGICAL           :: GFOUND
INTEGER, DIMENSION(3,SIZE(KYEAR)) :: ITDATE
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFT1_ASC',0,zhook_handle)
!
kresp=0
!
ymask=cmask
 CALL io_buff(&
                hrec,'R',gfound)
IF (gfound) ymask='FULL  '
!
 CALL posnam(nunit,ymask//' '//trim(hrec)//'%TDATE',gfound,nluout)
!
READ(nunit,fmt=*,end=100)
READ(nunit,fmt='(A50)') ycomment
READ(nunit,fmt=*,err=100) itdate(:,:)
!
kyear(:) = itdate(1,:)
kmonth(:) = itdate(2,:)
kday(:) = itdate(3,:)
!
 CALL posnam(nunit,cmask//' '//trim(hrec)//'%TIME',gfound,nluout)
!
READ(nunit,fmt=*,end=100)
READ(nunit,fmt='(A50)') ycomment
READ(nunit,fmt=*,err=100) ptime
!
hcomment = ycomment
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFT1_ASC',1,zhook_handle)
RETURN
!
100 CONTINUE
 CALL error_read_surf_asc(hrec,kresp)
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFT1_ASC',1,zhook_handle)
!
END SUBROUTINE read_surft1_asc
!
!     #############################################################
      SUBROUTINE read_surft2_asc (&
                                  HREC,KYEAR,KMONTH,KDAY,PTIME,KRESP,HCOMMENT)
!     #############################################################
!
!!****  *READT2* - routine to read a date
!
!
USE modd_io_surf_asc,        ONLY : nunit, nluout, cmask
!
USE mode_pos_surf
!
USE modi_io_buff
USE modi_error_read_surf_asc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=*),  INTENT(IN)  :: HREC     ! name of the article to be read
INTEGER, DIMENSION(:,:), INTENT(OUT) :: KYEAR    ! year
INTEGER, DIMENSION(:,:), INTENT(OUT) :: KMONTH   ! month
INTEGER, DIMENSION(:,:), INTENT(OUT) :: KDAY     ! day
REAL,    DIMENSION(:,:), INTENT(OUT) :: PTIME    ! year
INTEGER,            INTENT(OUT) :: KRESP    ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=100), INTENT(OUT) :: HCOMMENT ! comment

!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=50) :: YCOMMENT
 CHARACTER(LEN=6)  :: YMASK
LOGICAL           :: GFOUND
INTEGER, DIMENSION(3,SIZE(KYEAR,1),SIZE(KYEAR,2)) :: ITDATE
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFT2_ASC',0,zhook_handle)
!
kresp=0
!
ymask=cmask
 CALL io_buff(&
                hrec,'R',gfound)
IF (gfound) ymask='FULL  '
!
 CALL posnam(nunit,ymask//' '//trim(hrec)//'%TDATE',gfound,nluout)
!
READ(nunit,fmt=*,end=100)
READ(nunit,fmt='(A50)') ycomment
READ(nunit,fmt=*,err=100) itdate(:,:,:)
!
kyear(:,:) = itdate(1,:,:)
kmonth(:,:) = itdate(2,:,:)
kday(:,:) = itdate(3,:,:)
!
 CALL posnam(nunit,ymask//' '//trim(hrec)//'%TIME',gfound,nluout)

READ(nunit,fmt=*,end=100)
READ(nunit,fmt='(A50)') ycomment
READ(nunit,fmt=*,err=100) ptime
!
hcomment = ycomment
!
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFT2_ASC',1,zhook_handle)
RETURN
!
100 CONTINUE
 CALL error_read_surf_asc(hrec,kresp)
IF (lhook) CALL dr_hook('MODE_READ_SURF_ASC:READ_SURFT2_ASC',1,zhook_handle)
!
END SUBROUTINE read_surft2_asc
!
END MODULE mode_read_surf_asc