lfioeg.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfioeg_fort               &
&                     (lfi, knivau )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Ce sous-programme permet d'obtenir la valeur courante du NIVEAU
!      GLOBAL de traitement des ERREURS detectees par le logiciel LFI.
!**
!        ARGUMENT : KNIVAU (Sortie) ==> Niveau global de traitement des
!                                       erreurs detectees.
!
!     Valeurs possibles (par defaut, 1):
!
!     0 : Dans ce cas, toute erreur detectee sera fatale, meme si
!         l'erreur joue sur un fichier dont l'option individuelle de
!         traitement des erreurs est a .FALSE. .
!
!     1 : Seules les erreurs "globales" (c'est-a-dire non reliables a un
!         fichier deja ouvert) et les erreurs reliees a un fichier dont
!         l'option individuelle de traitement est .TRUE. seront fatales.
!
!     2 : Passer outre toute erreur detectee, meme si elle correspond
!         a un fichier dont l'option individuelle de traitement est
!         .TRUE. ; noter que dans ce dernier cas le code-reponse ne
!         sera pas nul. Par ailleurs, le code-reponse (-16) echappe a
!         ce mode de controle et est toujours fatal.
!
!
TYPE(lficom) :: LFI
INTEGER (KIND=JPLIKB) KNIVAU, INIMES, IREP, INUMER
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI

!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFIOEG_FORT',0,zhook_handle)
clacti=''
IF (lfi%LFIOEG_LLPREA) THEN
  CALL lfiini_fort                 &
&                 (lfi, 2_jplikb )
  lfi%LFIOEG_LLPREA=.false.
ENDIF
!
knivau=lfi%NERFAG
inimes=lfi%NIMESG
!
IF (inimes.EQ.2) THEN
  irep=0
  inumer=lfi%JPNIL
  clnspr='LFIOEG'
  WRITE (unit=clmess,fmt='(''KNIVAU='',I2)') knivau
  CALL lfiems_fort                                  &
&                 (lfi, inumer,inimes,irep,.false., &
&                  clmess,clnspr,clacti)
ENDIF
!
IF (lhook) CALL dr_hook('LFIOEG_FORT',1,zhook_handle)
END SUBROUTINE lfioeg_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfioeg64           &
&           (knivau)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KNIVAU                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfioeg_fort            &
&           (lfi, knivau)

END SUBROUTINE lfioeg64

SUBROUTINE lfioeg             &
&           (knivau)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KNIVAU                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfioeg_mt             &
&           (lfi, knivau)

END SUBROUTINE lfioeg

SUBROUTINE lfioeg_mt             &
&           (lfi, knivau)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KNIVAU                                 !   OUT
! Local integers
INTEGER (KIND=JPLIKB)  INIVAU                                 !   OUT
! Convert arguments


CALL lfioeg_fort            &
&           (lfi, inivau)

knivau     = int(    inivau, jplikm)

END SUBROUTINE lfioeg_mt

!INTF KNIVAU          OUT