lfinmg.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI
! R. El Khatib 30-Mar-2012 KULOUT

SUBROUTINE lfinmg_fort                       &
&                     (lfi, knivau, kulout )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        CE SOUS-PROGRAMME SE CHARGE DE METTRE LE NIVEAU GLOBAL
!     D'IMPRESSION DES MESSAGES (*LFI%NIMESG*) A LA VALEUR KNIVAU .
!**
!        ARGUMENT : KNIVAU (ENTREE) ==> NIVEAU GLOBAL D'IMPRESSION
!                                       DES MESSAGES .
!                                       VALEURS POSSIBLES
!
!     0 : N'EMETTRE QUE LES MESSAGES D'ERREURS REELLEMENT IMPORTANTS .
!     1 : N'EMETTRE QU'UN MINIMUM DE MESSAGES "GLOBAUX", ET LES MESSAGES
!         LIES A UN FICHIER OUVERT QUI SONT DE NIVEAU AU PLUS EGAL AU
!         NIVEAU DE LA MESSAGERIE POUR CE FICHIER (MODE PAR DEFAUT) .
!     2 : EMETTRE TOUS LES MESSAGES POSSIBLES, MEME S'ILS NE CORRESPON-
!         DENT PAS A UN FICHIER OUVERT AVEC LE NIVEAU DE MESSAGERIE 2 .
!
!                   KULOUT : logical unit number for printing
!
!
TYPE(lficom) :: LFI
INTEGER (KIND=JPLIKB) KNIVAU, INIMES, IREP, INUMER
INTEGER (KIND=JPLIKB) KULOUT
INTEGER (KIND=JPLIKB) IOLD_NULOUT
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFINMG_FORT',0,zhook_handle)
clacti=''
IF (lfi%LFINMG_LLPREA) THEN
  CALL lfiini_fort                 &
&                 (lfi, 2_jplikb )
  lfi%LFINMG_LLPREA=.false.
ENDIF
!
IF (kulout .GE. 0) THEN
  iold_nulout=lfi%NULOUT
  lfi%NULOUT=kulout
  IF (iold_nulout /= lfi%NULOUT) THEN
    CALL flush(int(iold_nulout))
    WRITE(lfi%NULOUT,                                &
&    '('' NOTICE : LFI%NULOUT WAS CHANGED FROM '',I3, &
&    '' TO '',I3)') iold_nulout,lfi%NULOUT
  ENDIF
ENDIF
!
IF (knivau.GE.0.AND.knivau.LE.2) THEN
  inimes=max(lfi%NIMESG,knivau)
  lfi%NIMESG=knivau
  irep=0
ELSE
  inimes=lfi%NIMESG
  irep=-2
ENDIF
!
llfata=irep.NE.0.AND.lfi%NERFAG.NE.2
!
IF (llfata) THEN
  inimes=2
ELSEIF (irep.NE.0) THEN
  inimes=0
ELSEIF (inimes.EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFINMG_FORT',1,zhook_handle)
  RETURN
ENDIF
!
inumer=lfi%JPNIL
clnspr='LFINMG'
!
IF (max(inimes,lfi%NIMESG).EQ.2) THEN
!
  IF (lfi%LFRANC) THEN
    WRITE (unit=clmess,                              &
&           fmt='(''KNIVAU='',I5,'', CODE INTERNE='', &
&           I4)') knivau,irep
  ELSE
    WRITE (unit=clmess,                               &
&           fmt='(''KNIVAU='',I5,'', INTERNAL CODE='', &
&           I4)') knivau,irep
  ENDIF
!
  IF (inimes.NE.2) CALL lfiems_fort                              &
&                                  (lfi, inumer,lfi%NIMESG,irep, &
&                                   .false.,clmess,              &
&                                   clnspr,clacti)
ENDIF
!
CALL lfiems_fort                                 &
&               (lfi, inumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFINMG_FORT',1,zhook_handle)
END SUBROUTINE lfinmg_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfinmg64           &
&           (knivau, kulout)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KNIVAU                                 ! IN   
INTEGER (KIND=JPLIKB)  KULOUT                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfinmg_fort                 &
&           (lfi, knivau, kulout)

END SUBROUTINE lfinmg64

SUBROUTINE lfinmg             &
&           (knivau, kulout)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KNIVAU                                 ! IN   
INTEGER (KIND=JPLIKM)  KULOUT                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfinmg_mt                  &
&           (lfi, knivau, kulout)

END SUBROUTINE lfinmg

SUBROUTINE lfinmg_mt             &
&           (lfi, knivau, kulout)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KNIVAU                                 ! IN   
INTEGER (KIND=JPLIKM)  KULOUT                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  INIVAU                                 ! IN   
INTEGER (KIND=JPLIKB)  IULOUT                                 ! IN   
! Convert arguments

inivau     = int(    knivau, jplikb)
iulout     = int(    kulout, jplikb)

CALL lfinmg_fort                 &
&           (lfi, inivau, iulout)


END SUBROUTINE lfinmg_mt

!INTF KNIVAU        IN    
!INTF KULOUT        IN