lfineg.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfineg_fort               &
&                     (lfi, knivau )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        CE SOUS-PROGRAMME SE CHARGE DE METTRE LE NIVEAU GLOBAL D'ERREUR
!     FATALE (*LFI%NERFAG*) A LA VALEUR KNIVAU . PAR  DEFAUT, LFI%NERFAG VAUT 1.
!**
!        ARGUMENT : KNIVAU (ENTREE) ==> NIVEAU GLOBAL D'ERREUR FATALE.
!                                       VALEURS POSSIBLES
!
!     0 : RENDRE FATALE TOUTE ERREUR DETECTEE, MEME SI ELLE CORRESPOND
!         A UN FICHIER OUVERT AVEC L'OPTION "PAS D'ERREUR FATALE".
!     1 : NE REND FATALES QUE CERTAINES ERREURS "GLOBALES", C'EST-A-DIRE
!         NON RELIABLES A UN FICHIER OUVERT, ET LES ERREURS SUR LES  FI-
!         CHIERS OUVERTS AVEC L'OPTION "ERREUR FATALE" (MODE PAR DEFAUT)
!     2 : PASSER OUTRE TOUTE ERREUR DETECTEE, MEME SI ELLE CORRESPOND
!         A UN FICHIER OUVERT AVEC L'OPTION "ERREUR FATALE".
!         NEANMOINS, LE CODE-REPONSE EVENTUEL NE SERA PAS ZERO.
!
!
TYPE(lficom) :: LFI
INTEGER (KIND=JPLIKB) KNIVAU, INIMES, IREP, INUMER
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFINEG_FORT',0,zhook_handle)
clacti=''
IF (lfi%LFINEG_LLPREA) THEN
  CALL lfiini_fort                 &
&                 (lfi, 2_jplikb )
  lfi%LFINEG_LLPREA=.false.
ENDIF
!
IF (knivau.GE.0.AND.knivau.LE.2) THEN
  lfi%NERFAG=knivau
  irep=0
ELSE
  irep=-2
ENDIF
!
llfata=irep.NE.0.AND.lfi%NERFAG.NE.2
!
IF (llfata) THEN
  inimes=2
ELSEIF (irep.NE.0) THEN
  inimes=0
ELSEIF (lfi%NIMESG.EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFINEG_FORT',1,zhook_handle)
  RETURN
ENDIF
!
inumer=lfi%JPNIL
clnspr='LFINEG'
!
IF (max(inimes,lfi%NIMESG).EQ.2) THEN
!
  IF (lfi%LFRANC) THEN
    WRITE (unit=clmess,                              &
&           fmt='(''KNIVAU='',I5,'', CODE INTERNE='', &
&           I4)') knivau,irep
  ELSE
    WRITE (unit=clmess,                               &
&           fmt='(''KNIVAU='',I5,'', INTERNAL CODE='', &
&           I4)') knivau,irep
  ENDIF
!
  IF (inimes.NE.2) CALL lfiems_fort                              &
&                                  (lfi, inumer,lfi%NIMESG,irep, &
&                                   .false.,clmess,              &
&                                   clnspr,clacti)
ENDIF
!
CALL lfiems_fort                                 &
&               (lfi, inumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFINEG_FORT',1,zhook_handle)
END SUBROUTINE lfineg_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfineg64           &
&           (knivau)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KNIVAU                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfineg_fort            &
&           (lfi, knivau)

END SUBROUTINE lfineg64

SUBROUTINE lfineg             &
&           (knivau)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KNIVAU                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfineg_mt             &
&           (lfi, knivau)

END SUBROUTINE lfineg

SUBROUTINE lfineg_mt             &
&           (lfi, knivau)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KNIVAU                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  INIVAU                                 ! IN   
! Convert arguments

inivau     = int(    knivau, jplikb)

CALL lfineg_fort            &
&           (lfi, inivau)


END SUBROUTINE lfineg_mt

!INTF KNIVAU        IN