latlonmask_lonlatval.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ##################################
      SUBROUTINE latlonmask_lonlatval(KGRID_PAR,PGRID_PAR,OLATLONMASK)
!     ##################################
!
!!**** *LATLONMASK* builds the latitude and longitude mask including the grid
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!
!!    A simple method is used :
!!
!!   XMIN, XMAX, YMIN, YMAX are calculated for the grid 
!!   This domain is extended to account for deformation between lambert and lat lon.
!!   All lat lon values in this extended domains are set to true in the mask.
!!   
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!      E. Martin       Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!      
!!      Original        10/2007  
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_lonlatval
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                       INTENT(IN)  :: KGRID_PAR   ! size of PGRID_PAR
REAL,    DIMENSION(KGRID_PAR), INTENT(IN)  :: PGRID_PAR   ! parameters defining this grid
LOGICAL, DIMENSION(720,360),   INTENT(OUT) :: OLATLONMASK ! mask where data are to be read
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
REAL                              :: ZXMIN    ! minimum of X for domain
REAL                              :: ZXMAX    ! maximum of X for domain
REAL                              :: ZLON0
REAL                              :: ZYMIN    ! minimum of Y for domain
REAL                              :: ZYMAX    ! maximum of Y for domain
REAL, DIMENSION(720,360)          :: ZX_MASK  ! mask points X value
REAL, DIMENSION(720,360)          :: ZY_MASK  ! mask points Y value
REAL, DIMENSION(720,360)          :: ZLON_MASK! mask points longitudes
REAL, DIMENSION(720,360)          :: ZLAT_MASK! mask points latitudes
REAL, DIMENSION(:), ALLOCATABLE   :: ZX       ! X Lambert   coordinate
REAL, DIMENSION(:), ALLOCATABLE   :: ZY       ! Y Lambert   coordinate
REAL, DIMENSION(:), ALLOCATABLE   :: ZDX      ! Grid dimension in X 
REAL, DIMENSION(:), ALLOCATABLE   :: ZDY      ! Grid dimension in Y 
!
INTEGER                           :: IL       ! Number og grid points
INTEGER                           :: JLAT, JLON
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('LATLONMASK_LONLATVAL',0,zhook_handle)
olatlonmask(:,:) = .false.
!
!-------------------------------------------------------------------------------
!
!*      1.   Limits of the domain in lonlatval coordinates 
!            ------------------------------------------------
!
     CALL get_gridtype_lonlatval(pgrid_par,kl=il)
!
     ALLOCATE(zx(il))
     ALLOCATE(zy(il))
     ALLOCATE(zdx(il))
     ALLOCATE(zdy(il))
!
     CALL get_gridtype_lonlatval(pgrid_par,px=zx,py=zy,pdx=zdx,pdy=zdy)
!
!*    2.     Limits of grid meshes in x and y
!            --------------------------------
!
     zxmin = minval(zx(:)-zdx(:)/2.)
     zxmax = maxval(zx(:)+zdx(:)/2.)
     zymin = minval(zy(:)-zdy(:)/2.)
     zymax = maxval(zy(:)+zdy(:)/2.)
     DEALLOCATE(zx )
     DEALLOCATE(zy )
     DEALLOCATE(zdx)
     DEALLOCATE(zdy)
!
!-------------------------------------------------------------------------------
!
!*      2.   Definition of the coordinates at center of the mask meshes
!            ----------------------------------------------------------
!
!
zlon_mask(:,:)= spread( (/ (  jlon     /2. - 0.25 , jlon=1,720 ) /) , dim=2, ncopies=360 )
zlat_mask(:,:)= spread( (/ ( (jlat-180)/2. - 0.25 , jlat=1,360 ) /) , dim=1, ncopies=720 )
!
!*      3.   Longitude correction (-180 /+180 )
!            --------------------------------
!
zlon0 = 0.5 * (zxmin+zxmax)
zlon_mask(:,:)=zlon_mask(:,:)+nint((zlon0-zlon_mask(:,:))/360.)*360.
!
!*      5.   Are the points in the domain?
!            ----------------------------
!
WHERE ((zlon_mask(:,:) >= zxmin .AND. zlon_mask(:,:) <= zxmax &
          .OR. zlon_mask(:,:) <= zxmin .AND. zlon_mask(:,:)+0.25 >= zxmin &
          .OR. zlon_mask(:,:) >= zxmax .AND. zlon_mask(:,:)-0.25 <= zxmax &
          .OR. zlon_mask(:,:)-0.25 <=zxmin .AND. zlon_mask(:,:)+0.25 >= zxmax) .AND. &
         (zlat_mask(:,:) >= zymin .AND. zlat_mask(:,:) <= zymax &
          .OR. zlat_mask(:,:) <= zymin .AND. zlat_mask(:,:)+0.25 >= zymin &
          .OR. zlat_mask(:,:) >= zymax .AND. zlat_mask(:,:)-0.25 <= zymax &
          .OR. zlat_mask(:,:)-0.25 <=zymin .AND. zlat_mask(:,:)+0.25 >= zymax))  
  olatlonmask(:,:) = .true.
END WHERE
IF (lhook) CALL dr_hook('LATLONMASK_LONLATVAL',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE latlonmask_lonlatval