latlonmask_lonlat_rot.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ##################################
      SUBROUTINE latlonmask_lonlat_rot(KGRID_PAR,PGRID_PAR,OLATLONMASK)
!     ##################################
!
!!**** *LATLONMASK* builds the latiude and longitude mask including the grid
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!
!!    Two tests are performed:
!!
!!   1) test if the points of the mask are in the domain
!!
!!   2) fills the mask points corresponding to points scanning
!!   
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!      P. Samuelsson   SMHI
!!
!!    MODIFICATION
!!    ------------
!!      
!!      Original        12/2012
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_lonlat_rot
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                       INTENT(IN)  :: KGRID_PAR   ! size of PGRID_PAR
REAL,    DIMENSION(KGRID_PAR), INTENT(IN)  :: PGRID_PAR   ! parameters defining this grid
LOGICAL, DIMENSION(720,360),   INTENT(OUT) :: OLATLONMASK ! mask where data are to be read
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
!
REAL    :: ZDLON   ! Longitudal grid spacing  (degrees)
REAL    :: ZDLAT   ! Latitudal grid spacing  (degrees)
!
REAL    :: ZLON0
REAL    :: ZLONMIN
REAL    :: ZLONMAX
REAL    :: ZLATMIN
REAL    :: ZLATMAX
REAL, DIMENSION(:), ALLOCATABLE    :: ZLON
REAL, DIMENSION(:), ALLOCATABLE    :: ZLAT
!
INTEGER :: JLAT
INTEGER :: JLON
INTEGER :: ZKL
!
REAL, DIMENSION(720,360) :: ZLON_MASK! mask points longitudes
REAL, DIMENSION(720,360) :: ZLAT_MASK! mask points latitudes
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('LATLONMASK_LONLAT_ROT',0,zhook_handle)
!
 CALL get_gridtype_lonlat_rot(pgrid_par,pdlon=zdlon,pdlat=zdlat,kl=zkl)
!
ALLOCATE(zlon(zkl))
ALLOCATE(zlat(zkl))
!
 CALL get_gridtype_lonlat_rot(pgrid_par,plon=zlon,plat=zlat)
!
zlonmin = minval(zlon) - zdlon
zlonmax = maxval(zlon) + zdlon
zlatmin = minval(zlat) - zdlat
zlatmax = maxval(zlat) + zdlat
!
!-------------------------------------------------------------------------------
!
olatlonmask(:,:) = .false.
!
!-------------------------------------------------------------------------------
!
!*      2.   Definition of the coordinates at center of the mask meshes
!            ----------------------------------------------------------
!
!
zlon_mask(:,:)= spread( (/ (  jlon     /2. - 0.25 , jlon=1,720 ) /) , dim=2, ncopies=360 )
zlat_mask(:,:)= spread( (/ ( (jlat-180)/2. - 0.25 , jlat=1,360 ) /) , dim=1, ncopies=720 )
!
!-------------------------------------------------------------------------------
!
!*      3.   Set definition of longitudes according to grid 
!            ----------------------------------------------
!
zlon0 = 0.5*(zlonmin + zlonmax)
zlon_mask(:,:)=zlon_mask(:,:)+nint((zlon0-zlon_mask(:,:))/360.)*360.
!
!-------------------------------------------------------------------------------
!
DO jlat=1,360
  DO jlon=1,720
    IF (      zlon_mask(jlon,jlat) + 0.25 >= zlonmin &
          .AND. zlon_mask(jlon,jlat) - 0.25 <= zlonmax &
          .AND. zlat_mask(jlon,jlat) + 0.25 >= zlatmin &
          .AND. zlat_mask(jlon,jlat) - 0.25 <= zlatmax ) olatlonmask(jlon,jlat) = .true.  
  END DO
END DO
IF (lhook) CALL dr_hook('LATLONMASK_LONLAT_ROT',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE latlonmask_lonlat_rot